Das Haus vom Nikolaus Konsolenanwendung

[Luckie]

Mit einem Fenster ist es wesentlich einfacher:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
begin
  case Button1.Tag of
    0: begin
         Canvas.MoveTo(50,600);
         Canvas.LineTo(300,600);
       end;
    1: begin
         Canvas.LineTo(300, 350);
       end;
    2: begin
         Canvas.LineTo(50, 350);
       end;
    3: begin
         Canvas.LineTo(175, 200);
       end;
    4: begin
         Canvas.LineTo(300, 350);
       end;
    5: begin
         Canvas.LineTo(50,600);
       end;
    6: begin
         Canvas.LineTo(50, 350);
       end;
    7: begin
         Canvas.LineTo(300,600);
       end;
  end;
  Button1.Tag := Button1.Tag + 1;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1.Tag := 0;
end;

Die Lösung ist nicht optimiert, sondern nur mal so schnell in zwei Minuten hingetippt.

[Namenloser]

Luckie, er hat eingangs geschrieben, dass er es als Konsolenanwendung umsetzen muss, das nützt ihm also nix. Informatiklehrer machen teilweise recht seltsame Vorgaben...

[ehX]

Höhö.....

Delphi-Quellcode:

program DasHausVomNikolaus;

{$APPTYPE CONSOLE}

var
  i : Integer ;
  haus : array[0..42] of string = (
'______________X',
'_____________X_X',
'____________X___X',
'___________X_____X',
'__________X_______X',
'_________X_________X',
'________X___________X',
'_______X_____________X',
'______X_______________X',
'_____X_________________X',
'____X___________________X',
'___X_____________________X',
'__X_______________________X',
'_X_________________________X',
'XXXXXXXXXXXXXXXXXXXXXXXXXXXXX',
'XX_________________________XX',
'X_X_______________________X_X',
'X__X_____________________X__X',
'X___X___________________X___X',
'X____X_________________X____X',
'X_____X_______________X_____X',
'X______X_____________X______X',
'X_______X___________X_______X',
'X________X_________X________X',
'X_________X_______X_________X',
'X__________X_____X__________X',
'X___________X___X___________X',
'X____________X_X____________X',
'X_____________X_____________X',
'X____________X_X____________X',
'X___________X___X___________X',
'X__________X_____X__________X',
'X_________X_______X_________X',
'X________X_________X________X',
'X_______X___________X_______X',
'X______X_____________X______X',
'X_____X_______________X_____X',
'X____X_________________X____X',
'X___X___________________X___X',
'X__X_____________________X__X',
'X_X_______________________X_X',
'XX_________________________XX',
'XXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
);



begin

for i := 0 to High(Haus) do
    Writeln(Haus[i]);

readln; // Wenn man unbedingt nen Stop braucht...
end.

Vielleicht nicht ganz....im Sinn der Informatiklehrers....aber eine Lösung
(Unterstriche evtl noch durch Leerzeichen ersetzen, die Leerzeichen hatte es mir hier beim Posten zerschossen )

P.S: Ja, ich weiss, es geht auch anders, indem man es "wirklich" programmiert..aber ich würde meinem Infolehrer bei so einer doofen Aufgabe (CMD-Programm...) genau das vorsetzen

[Medium]

Danke Fin! Ich hatte bei der Eingangsfrage schon exakt die selbe Idee, du hast mir dankenswerterweise die Ausformulierung abgenommen .

Sobald die Diagonalen dazu kommen, wird es eh sonst ... echt doof? Aber weil's so schön blöd ist:

Delphi-Quellcode:

var
  i, k, m, p: Integer;

begin
  k := 13;
  m := 11;
  for i := 0 to 42 do
  begin
    if i<=13 then
    begin
      for p := 0 to k do
        Write(' ');
      Write('x');
      for p := 0 to m-k do
        Write(' ');
      if i>0 then
        Write('x');
      dec(k);
      inc(m);
    end
    else
    if (i=14) or (i=42) then
    begin
      for p := 0 to 28 do
        Write('x');
      k := 0;
      m := 24;
    end
    else
    begin
      Write('x');
      for p := 0 to k-1 do
        Write(' ');
      Write('x');
      for p := 0 to m-k do
        Write(' ');
      if i<>28 then
        Write('x');
      for p := 0 to 23-m do
        Write(' ');
      Write('x');
      if i<28 then
      begin
        inc(k);
        dec(m);
      end
      else
      begin
        dec(k);
        inc(m);
      end;
    end;
    Writeln;
  end;
  Readln;
end.

Ich übe mich ja in Zurückhaltung was Web-Slang angeht, aber WTF?

Edit: Okay, 2 Schleifen und die Waagerechten dazwischen wären sinniger, hatte mit einem case angefangen. Dann fiel mir ein, dass das vermutlich noch nicht dran war, und davon ist das noch ein Rest. Aber bei der Aufgabe verbietet sich eh jeder ernsthafte Gedanke. Nicht weil so leicht, sondern weil (auch didaktisch) echt daneben.

[himitsu]

Wer hat alles in Mathematik aufgepasst?

Gegeben ist ein Koordinatensystem, bzw. eine gezackte Gerade.
und gegeben sind 8 Geraden, bzw. 6 Geraden mit Überlauf.

Liegt nun ein Pinkt des Koordinatensystems auf einer der Linien?
Wenn ja, dann zeichne dort ein X.



Zwei Schleifen im Koordinatensystem:

Delphi-Quellcode:

// ___1___
// __a_b__
// _a___b_
// 2ccccc3
// fd___eg
// f_d_e_g
// f__x__g
// f_e_d_g
// fe___dg
// 4hhhhh5

var
  x, y: Integer;
begin
  for y := 0 to 42 do begin
    for x := 0 to 28 do
      if (y + 14 = x) {b: diagonal}
          or (y + 14 = 28 - x]) {a: diagonal}
          or (y + 42 = x) {d: diagonal}
          or (y + 42 = 28 - x) {e: diagonal}
          or ((y > 13) and (x = 0)) {f: senkrecht}
          or ((y > 13) and (x = 28)) {g: senkrecht}
          or (y = 14) {c: quer}
          or (y = 42) {h: quer} then
        Write('X')
      else
        Write(' '); // Write('_'); für Debugmodus
    WriteLn;
  end;
  ReadLn;
end.

Zwei Schleifen im Koordinatensystem (die Berechnung 'nen bissl optimiert/zusammengefaßt):

Delphi-Quellcode:

var
  x, y: Integer;
begin
  for y := 0 to 42 do begin
    for x := 0 to 28 do
      if (((y + 14) mod 28) in [x, 28 - x]) {diagonal}
          or ((y > 13) and (x in [0, 28])) {senkrecht}
          or (y in [14, 42]) {quer} then
        Write('X')
      else
        Write(' ');  // Write('_'); für Debugmodus
    WriteLn;
  end;
  ReadLn;
end.

Eine Schleife mit Koordinatensystem:

Delphi-Quellcode:

var
  x, y: Integer;
begin
  x := 0;
  y := 0;
  while y < 43 do begin
    if (((y + 14) mod 28) in [x, 28 - x]) {diagonal}
        or ((y > 13) and (x in [0, 28])) {senkrecht}
        or (y in [14, 42]) {quer} then
      Write('X')
    else
      Write(' ');  // Write('_'); für Debugmodus
    Inc(x);
    if x > 28 then begin
      WriteLn;
      x := 0;
      Inc(y);
    end;
  end;
  ReadLn;
end.

Eine Schleife auf 'ner Geraden.

Delphi-Quellcode:

var
  i: Integer;
begin
  for i := 0 to 1246 do begin
    if (((i div 29 + 14) mod 28) in [i mod 29, 28 - i mod 29]) {diagonal}
        or ((i > 407) and (i mod 29 in [0, 28])) {senkrecht}
        or (i div 29 in [14, 42]) {quer} then
      Write('X')
    else
      Write(' ');  // Write('_'); für Debugmodus
    if i mod 29 = 28 then
      WriteLn;
  end;
  ReadLn;
end.

PS: Wer die Linien alle einzeln berechnen/einfügen möchte, der nehme eine StringListe oder ein String-Array, zum Zwischenspeichern.
Fülle erstmal alle Zeilen mit Leerzeichen und tauschen dann, Stück für Stück, die einelnen Punkte/Chars aus, bevor alles ausgegeben wird.

Hier hat man also ein Koordinatensystem / eine Fläche in den Strings.
Gehe nun nur noch die bekannten Geraden durch und zeichne deren Punkte ein.

[hotkey]

Naja , das mit der Diagonale.. Das wird uns unser Lehrer noch erklären , ich bin jetzt soweit , dass das so aussieht :


x
x
x
x
x
x
x
x
x
x x x x x x x

Jetzt fehlt nur noch die parallele zur der Senkrechten und dann noch die Parallele zu der Horizontalen..

[himitsu]

Die Horizontalen ist natürlich ganz leicht ... genauso wie die Vorhandene, einfach in einer "anderen" Zeile.

Und die Senkrechte ... ein paar Leerzeichen hinter der Vorhandenen und dann die Neue anhängen.