Drucker liefert unterschiedliche Fontgrößen

[p80286]

Ggf hilft Dir canvas.FontUpdate weiter.

Delphi-Quellcode:

SetMapMode(Handle, MM_LOMETRIC);
        canvas.Font.Name := 'Times New Roman';
        canvas.Font.Size := round(10.0 * fs *(25.4/GetDeviceCaps(printer.handle, LOGPIXELSX)));;
        canvas.Font.Style := [fsBold];
        canvas.FontUpdate;

Gruß
K-H

[DeddyH]

Wo kommt das her? Ich finde nirgends eine solche Methode

[Bummi]

Da ich immer gerne au Dinge zurückgreife die ich schon länger nutze, vielleicht lässt sich hieraus was machen.

Die Idee ist direkt mit Millimetern zu arbeiten ....

den GetPageinfo-Teil habe ich von hathor übernommen ....

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs,Printers,Math, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
Type
  TPageInfo = record
    width, height: Integer; { physical width and height, in dots }
    offsetX, offsetY: Integer;{ nonprintable margin, in dots }
    resX, resY: Integer; { logical resolution, dots per inch }
  End;

Procedure GetPageinfo( Var info: TPageInfo; index: Integer = -1 );
  Begin
    If index > -1 Then
      Printer.PrinterIndex := index;
    With Printer Do Begin
      info.resX := GetDeviceCaps( handle, LOGPIXELSX );
      info.resY := GetDeviceCaps( handle, LOGPIXELSY );
      info.offsetX := GetDeviceCaps( handle, PHYSICALOFFSETX );
      info.offsetY := GetDeviceCaps( handle, PHYSICALOFFSETY );
      info.width := GetDeviceCaps( handle, PHYSICALWIDTH );
      info.height := GetDeviceCaps( handle, PHYSICALHEIGHT );
    End; { With }
  End;




Procedure SetCanvasZoomAndRotation(ACanvas:TCanvas;Zoom:Double;Angle:Double;CenterpointX,CenterpointY:Double);
var
    form : tagXFORM;
    Winkel:Double;

begin
      Winkel := DegtoRad(Angle);
      SetGraphicsMode(ACanvas.Handle, GM_ADVANCED);
      SetMapMode(ACanvas.Handle,MM_ANISOTROPIC);
      form.eM11 := Zoom * cos( Winkel);
      form.eM12 := Zoom *Sin( Winkel)  ;
      form.eM21 := Zoom * (-sin( Winkel));
      form.eM22 := Zoom * cos( Winkel) ;
      form.eDx := CenterpointX;
      form.eDy := CenterpointY;
      SetWorldTransform(ACanvas.Handle,form);
end;

Procedure ResetCanvas(ACanvas:TCanvas);
begin
   SetCanvasZoomAndRotation(ACanvas , 1, 0, 0,0);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
info: TPageInfo;
begin
  GetPageinfo(info);
  Printer.BeginDoc;
  SetCanvasZoomAndRotation(Printer.Canvas, info.height / 297,0,0,0);
  Printer.Canvas.Rectangle(10,10,30,20);
  Printer.Canvas.Font.Height := 10;
  Printer.Canvas.TextOut(10,10,'Test');
  Printer.EndDoc;
end;

end.

[p80286]

@Deddyh
hab ich mich so vertan? ich mein ich hätte eben soetwas gesehen.

Mist, ist Freitag:

Delphi-Quellcode:

procedure TPrinterCanvas.UpdateFont;
var
  FontSize: Integer;
begin
  if GetDeviceCaps(Printer.DC, LOGPIXELSY) <> Font.PixelsPerInch then
  begin
    FontSize := Font.Size;
    Font.PixelsPerInch := GetDeviceCaps(Printer.DC, LOGPIXELSY);
    Font.Size := FontSize;
  end;

end;

Gruß
K-H

[marcibaer]

Ich hab's jetzt folgendermassen gemacht:

Zu Beginn setze ich die folgenden Werte bzw. den folgenden Mode:

Delphi-Quellcode:

      GesamtHoehe := GetDeviceCaps(Handle, VERTSIZE)*10;
      Gesamtbreite := GetDeviceCaps(Handle, HORZSIZE)*10;
      SetMapMode(Handle, MM_TEXT);

Die Angaben, die ich den Druckroutinen übergebe, sind in 0.1mm angrgeben, umgerechnet werden sie dann in Pixel:

Delphi-Quellcode:

FUNCTION XPosition(const x:Integer):Integer;
BEGIN
  Result := Trunc(x * Printer.PageWidth / Gesamtbreite);
END;

FUNCTION YPosition(const y:Integer):Integer;
BEGIN
  Result := Trunc(y * Printer.PageHeight / Gesamthoehe);
END;

FUNCTION XWidth(const x:Integer):Integer;
BEGIN
  Result := Trunc(x / (Printer.PageWidth / Gesamtbreite));
END;

FUNCTION YHeight(const y:Integer):Integer;
BEGIN
  Result := Trunc(y / (Printer.PageHeight / Gesamthoehe));
END;

Scheint soweit zu funktionieren.