Servus
Ich hab da mal ne Frage:

Gibt es eine Möglichkeit herauszufinden, ob ein Fenster bzw. ob ein Teil eines Fensters überhaupt sichtbar ist oder ob das Fenster komplett von einem anderen Fenster (nicht auf ein Programm beschrenkt) verdeckt wird? Ich suche nicht die Funktion IsWindowVisible.

Hintergrund:
Für meine Desktop Widget Engine verwende ich die Funktion UpdateLayeredWindow. Bevor diese Funktion jedoch ausgeführt wird, muss das Window-Bitmap erst erstellt werden - dies kann ziemlich viel Resourcen fressen. Nun wollt ich CPU-Resourcen sparen und erstmal schauen, ob das Update überhaupt für den User sichtbar ist. Daher bräuchte ich eine Funktion, die mir sagt, ob das Fenster überhaupt sichtbar ist.

Grüße
Dave

Hallo, dafür eignet sich die GetClipBox API.

zusammenfalten · markieren

Delphi-Quellcode:

type
  TVisibleStatus = (vsHidden, vsVisible, vsPartVisible);

function TForm1.GetVisibleStatus(wnd: HWND): TVisibleStatus;
var
  Clip: Integer;
  hDC: THandle;
  ClipRect, ClientRect: TRect;
begin
  hDC := GetDC(wnd);
  Clip := GetClipBox(hDC, ClipRect);
  case Clip of
    NULLREGION: Result := vsHidden; // Fenster ist komplett versteckt
    SIMPLEREGION:
      begin
        ClientRect := GetClientRect;
        if EqualRect(ClipRect, ClientRect) then // vollständig sichtbar
          Result := vsVisible //ClientRect ist sichtbar
        else //teils sichtbar
          Result := vsPartVisible; //ClientRect ist sichtbar
      end;
    COMPLEXREGION: // Region besteht aus mehr als einem Rechteck, Fenster ist teils sichtbar
      Result := vsPartVisible;
  end;
  ReleaseDC(Handle, hDC);
end;

Danke für den Code - der Funktioniert an sich sehr gut, nur leider nicht bei meinem Problem .

Meine Fenster sind vom Style her WS_EX_LAYERED. Ich hab nach GetClipRgn + WS_EX_LAYERED gesucht und hab in einem C++Forum gefunden, dass diese Kombination nicht funktioniert - schade.

Hast du sonst noch ne Idee, wie ich das hinkriegen könnte?

Ich benutze diese Funktion schon seit längerer Zeit und habe sie heute aus der Hauptform raus in eine neue Unit umgezogen. Leider funktioniert die Funktion dann nicht mehr, da eine Windows-Funktion statt der Funktion in Forms.pas verwendet wird:

ClientRect := GetClientRect; Ein Forms.GetClientRect; oder Forms.TCustomForm.GetClientRect; funktioniert leider nicht. Was muss man hier schreiben, damit die Forms.pas-Funktion verwendet wird?

Das war schon richtig: Nur der vollständige Name der Unit aus welcher du das nehmen möchtest ist Vcl.Forms , nicht Forms . Es würde dementsprechend heißen Vcl.Forms.TCustomForm.GetClientRect() .

Konjunktiv, da GetClientRect() an eine TCustomForm -Instanz gebunden ist und keine statische Methode ist die man einfach so aufrufen kann: Du brauchst eine Form dafür, also z.B. meinRect := meineForm.GetClientRect() Das meineForm wirst du deiner Methode ja irgendwie übergeben, oder?
Kannst du vlt. die Unit mit der Methode wie du es momentan hast posten?

Du rufst ja die Methode einer TCustomForm-Instanz auf, also musst Du auch diese Instanz mit angeben.
ClientRect := FormInstanz.GetClientRect;

Meine aktuelle Funktion sieht momentan so aus. Ich habe nur die markierte Stelle geändert aber leider habe ich keinen Zugriff auf GetClientRect.

zusammenfalten · markieren

Delphi-Quellcode:

function GetVisibleStatus(const PForm: TForm): TVisibleStatus;
var
 Clip: Integer;
 hDC: THandle;
 ClipRect, ClientRect: TRect;
begin
 hDC := GetDC(PForm.Handle);
 Clip := GetClipBox(hDC, ClipRect);

 case Clip of
  NULLREGION:
   Result := vsHidden; // Fenster ist komplett versteckt
  SIMPLEREGION:
   begin
    ClientRect := PForm.GetClientRect; // nur das hier habe ich geändert

    if EqualRect(ClipRect, ClientRect) then // vollständig sichtbar
     Result := vsVisible // ClientRect ist sichtbar
    else // teils sichtbar
     Result := vsPartVisible; // ClientRect ist sichtbar
   end;
  COMPLEXREGION: // Region besteht aus mehr als einem Rechteck, Fenster ist teils sichtbar
   Result := vsPartVisible;
 end;

 ReleaseDC(Handle, hDC);
end;

Die letzte Zeile verstehe ich auch nicht. Müsste da nicht eigentlich PForm.Handle stehen und nicht Handle?

Wie ist es so (ungetestet)?

zusammenfalten · markieren

Delphi-Quellcode:

function GetVisibleStatus(const PForm: TForm): TVisibleStatus;
var
 Clip: Integer;
 hDC: THandle;
 ClipRect, ClientRect: TRect;
begin
  Assert(Assigned(PForm), 'Keine TCustomForm-Instanz übergeben');
  hDC := GetDC(PForm.Handle);
  if hDC <> 0 then
    try
      Clip := GetClipBox(hDC, ClipRect);
      
      case Clip of
        NULLREGION:
          Result := vsHidden; // Fenster ist komplett versteckt
        SIMPLEREGION:
          begin
            ClientRect := PForm.ClientRect; // Property statt protected Getter
            
            if EqualRect(ClipRect, ClientRect) then // vollständig sichtbar
              Result := vsVisible // ClientRect ist sichtbar
            else // teils sichtbar
              Result := vsPartVisible; // ClientRect ist sichtbar
          end;
        COMPLEXREGION: // Region besteht aus mehr als einem Rechteck, Fenster ist teils sichtbar
          Result := vsPartVisible;
      end;
    finally
      ReleaseDC(PForm.Handle, hDC);
    end;
end;

Das funktioniert jetzt glücklicherweise. Zwar nicht mit dem Hauptformular, aber da brauche ich die Funktion eh nicht.

Ist ein Fenster komplett sichtbar, kommt trotzdem vsPart zurück.
Ich rufe die Funktion eine Hand voll mal auf und vergleiche immer auf <> TVisibleStatus.vsHidden. Von daher ist es egal, ob vsVisible oder vsPart.

Schöne Sache, habe ich mir mal beiseite gelegt, kann ich bestimmt mal brauchen.

Die Frage sollte allerdings mal als "erledigt" gekennzeichnet werden.