Access Violations nach Update auf XE3

[Nersgatt]

So, das Problem ist umzingelt.
Das Problem tritt beim TStringField innerhalb des TClientDataSet auf. Aber nur in dem Fall, wenn TStringField.Size kleiner ist, als das Feld in der Datenbank.
Beispiel: ich habe in der Datenbank ein Feld VarChar(30) und das TStringField, worein die Daten solle hat nur die Size von 20. Dann kracht es.

Nun ist die Frage: ist das ein Fehler in der DB.Data.pas, oder sind wir selbst schuld? Delphi 2010 hatte das noch problemlos geschluckt, wenn das Feld zu klein ist.

[Rolf Frei]

Ich kann das selber auch reproduzieren. Das ist zu 100% nicht dein Fehler. Ist leider ein weiterer sehr übler Bug und betrifft nicht das TClientDataset, sondern jedes von TDataset abgeleitete Objekt. Mein Test benutzt eine 3rd Party Komponente und auch damit kann ich es reproduzieren.

Bitte melde das mit einem Beispiel in QC.

[EDIT]
Bin nicht sicher ob das überhaupt was mit dem TDataset zu tun hat oder ob es am TDBGrid liegt. Der AV tritt in TDBGridInplaceEdit.UpdateContents bei der Zeile:
Font.Assign(Column.Font);

Wenn ich da aber schrittweise debugge, kann ich nicht sehen was da falsch sein soll. Bin daher überhaupt nicht sicher was zu diesem Fehler führt.

[EDIT2]
Habe nun mal das DB Grid entfernt und ein normales TDBEdit angehängt. Auch damit knallt es. Manchmal erst beim Beenden der Applikation. Wird also doch irgendwie mit TField.Size zusammen hängen.

[Rolf Frei]

Habe mir das nun mal genauer angeschaut und habe das Problem gefunden. Da wird in TStringField.GetValue zu wenig Buffer alloziert, wenn Size kleiner ist als das effektive DB Feld. Habe folgenden Fix gemacht und nun scheint alles bestens zu laufen. Damit sollten deine AV's Geschichte sein. Habe übrigens einen QC-Eintrag mit meinem FIX erstellt.

Einen gleichartigen Fix sollte man auch noch bei TWideStringField.GetValue machen.)

FIX für TStringField.GetValue:

Delphi-Quellcode:

function TStringField.GetValue(var Value: AnsiString): Boolean;
var
  Buffer: TValueBuffer;
  NullIndex: Integer;
  Str: string;
begin
  // orig. XE3
  // SetLength(Buffer, DataSize);

  // === Fix as in older Delphi Versions ===
  if DataSize > dsMaxStringSize + 1 then
    SetLength(Buffer, DataSize)
  else
    SetLength(Buffer, dsMaxStringSize + 1);  
  // === End of Fix ===

  Result := GetData(Buffer);
  if Result then
  begin
    if Transliterate and (Buffer <> nil) and (Buffer[0] <> 0) then
      DataSet.Translate(PAnsiChar(@Buffer[0]), PAnsiChar(@Buffer[0]), False);
    Str := TEncoding.ANSI.GetString(Buffer);
    NullIndex := Str.IndexOf(#0);
    if NullIndex >= 0 then
      Value := AnsiString(Str.Remove(NullIndex))
    else
      Value := AnsiString(Str);
  end;
end;

Und hier für TWideStringField:

Delphi-Quellcode:

function TWideStringField.GetValue(var Value: string): Boolean;
var
  Buffer: TValueBuffer;
  NullIndex: Integer;
  Str: string;
begin
  // orig. XE3
  // SetLength(Buffer, ((DataSize div 2) + 1) * SizeOf(Char));

  // rf
  // === Fix as in older Delphi Versions ===
  if DataSize > ((dsMaxStringSize div 2) + 1) * SizeOf(Char) then
    SetLength(Buffer, ((DataSize div 2) + 1) * SizeOf(Char))
  else
    SetLength(Buffer, ((dsMaxStringSize div 2) + 1) * SizeOf(Char));
  // === End of Fix ===

  Result := GetData(Buffer, False);
  if Result then
  begin
    Str := TEncoding.Unicode.GetString(Buffer);
    NullIndex := Str.IndexOf(#0);
    if NullIndex >= 0 then
      Value := Str.Remove(NullIndex)
    else
      Value := Str;
  end;
end;