AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Thema durchsuchen
Ansicht
Themen-Optionen

Access Violations nach Update auf XE3

Ein Thema von Nersgatt · begonnen am 8. Okt 2012 · letzter Beitrag vom 15. Okt 2012
Antwort Antwort
Rolf Frei

Registriert seit: 19. Jun 2006
656 Beiträge
 
Delphi 11 Alexandria
 
#1

AW: Access Violations nach Update auf XE3

  Alt 15. Okt 2012, 14:41
Habe mir das nun mal genauer angeschaut und habe das Problem gefunden. Da wird in TStringField.GetValue zu wenig Buffer alloziert, wenn Size kleiner ist als das effektive DB Feld. Habe folgenden Fix gemacht und nun scheint alles bestens zu laufen. Damit sollten deine AV's Geschichte sein. Habe übrigens einen QC-Eintrag mit meinem FIX erstellt.

Einen gleichartigen Fix sollte man auch noch bei TWideStringField.GetValue machen.)

FIX für TStringField.GetValue:
Delphi-Quellcode:
function TStringField.GetValue(var Value: AnsiString): Boolean;
var
  Buffer: TValueBuffer;
  NullIndex: Integer;
  Str: string;
begin
  // orig. XE3
  // SetLength(Buffer, DataSize);

  // === Fix as in older Delphi Versions ===
  if DataSize > dsMaxStringSize + 1 then
    SetLength(Buffer, DataSize)
  else
    SetLength(Buffer, dsMaxStringSize + 1);
  // === End of Fix ===

  Result := GetData(Buffer);
  if Result then
  begin
    if Transliterate and (Buffer <> nil) and (Buffer[0] <> 0) then
      DataSet.Translate(PAnsiChar(@Buffer[0]), PAnsiChar(@Buffer[0]), False);
    Str := TEncoding.ANSI.GetString(Buffer);
    NullIndex := Str.IndexOf(#0);
    if NullIndex >= 0 then
      Value := AnsiString(Str.Remove(NullIndex))
    else
      Value := AnsiString(Str);
  end;
end;
Und hier für TWideStringField:
Delphi-Quellcode:
function TWideStringField.GetValue(var Value: string): Boolean;
var
  Buffer: TValueBuffer;
  NullIndex: Integer;
  Str: string;
begin
  // orig. XE3
  // SetLength(Buffer, ((DataSize div 2) + 1) * SizeOf(Char));

  // rf
  // === Fix as in older Delphi Versions ===
  if DataSize > ((dsMaxStringSize div 2) + 1) * SizeOf(Char) then
    SetLength(Buffer, ((DataSize div 2) + 1) * SizeOf(Char))
  else
    SetLength(Buffer, ((dsMaxStringSize div 2) + 1) * SizeOf(Char));
  // === End of Fix ===

  Result := GetData(Buffer, False);
  if Result then
  begin
    Str := TEncoding.Unicode.GetString(Buffer);
    NullIndex := Str.IndexOf(#0);
    if NullIndex >= 0 then
      Value := Str.Remove(NullIndex)
    else
      Value := Str;
  end;
end;

Geändert von Rolf Frei (15. Okt 2012 um 15:19 Uhr)
  Mit Zitat antworten Zitat
Antwort Antwort


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 03:52 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz