Sierpinski-Teppich

[Pangea]

Das klingt aber verdächtig nach dem BwInf

Aber um auf deine Frage zurückzukommen. Soweit ich das verstanden habe (kann mich aber auch irren) ist der Einsatz eines XML-Parsers prinzipiell nicht verboten. So gesehen wäre es vermutlich das einfachste einen solchen zu verwenden.

Bezüglich der Reukursion: Schau dir mal den Aufbau eines XML-Dokuments an, bzw. wie dieser von den Parsern wiedergegeben wird. Um welche Struktur handelt es sich dabei? Wie komme ich dann am besten an die Elemente?

[101nero]

Also den Sierpinksi-Teppich hab ich jetzt fertig.
Aber die Koordinaten sind noch nicht variabel sondern vorgegeben.
Um die richtigen Koordinaten in der *.svg-Datei zu finden (die Koordinaten sind beliebig, da die svg.-Dateien sich unterscheiden können.) verwende ich folgenden Code:

Code:

  s := '<line x1="100" y1="400" x2="500" y2="400" stroke="black" stroke-width="1" />';
  p1 := Pos('"', s); // Lese Position der ersten anführnugszeichen
  p2 := Pos('"', s); // Lese Position der letzten anführnugszeichen
  // was steht dazwischen:
  aNeu := Copy(s, (p1+1), (p2-1));
  Memo1.Lines.Add(aNeu);

Das Problem ist, dass die Anführungszeichen nicht richtig erkannt werden.
Der Inhalt der Variablen s, befindet sich eine eingelesene Zeile aus der *.svg-Datei.
Gesucht wird das erste " und das darauffolgende ".
Finden möchte ich also die "100" nach x=".
Gefunden wird: 100" y1="

Gibt es hier eine andere Möglichkeit?
(Davon abgesehen brauche ich nicht die x1, y1 Werte, sondern die height, und width werte.

[Sir Rufo]

Hier eine kleine Progrämmchen womit du die XML-Zeile in ihre Bestandteile zerlegen kannst.

Funktioniert aber auch nur in diesem speziellen Fall und die Werte sind noch in " eingeschlossen

Delphi-Quellcode:

program xmlRow;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  SysUtils, Classes;

procedure SplitXmlAttributes( const AXmlRow : string; out ATag : string; AAttributes : TStrings );
var
  LXmlInner :  string;
  LValueList : TStringList;
begin

  // 1. Zeichen ("<") entfernen
  LXmlInner := Copy( Trim( AXmlRow ), 2 );
  // letzen beiden Zeichen ("/>") entfernen und Leerstellen vorne/hinten entfernen
  LXmlInner := Trim( Copy( LXmlInner, 1, Length( LXmlInner ) - 2 ) );

  LValueList := TStringList.Create;
  try

    LValueList.Delimiter       := ' ';
    LValueList.StrictDelimiter := True;
    LValueList.DelimitedText   := LXmlInner;

    // Der Tag steht an erster Stelle
    ATag := LValueList[0];
    LValueList.Delete( 0 );

    // Der Rest sind die Attribute
    AAttributes.Assign( LValueList );

  finally
    LValueList.Free;
  end;

end;

procedure Test;
var
  LXmlRow :  string;
  LXmlTag :  string;
  LXmlAttr : TStrings;
  LIdx :     Integer;
begin

  LXmlAttr := TStringList.Create;
  try

    LXmlRow := '<line x1="100" y1="400" x2="500" y2="400" stroke="black" stroke-width="1" />';
    SplitXmlAttributes( LXmlRow, LXmlTag, LXmlAttr );

    Writeln( 'Tag: ', LXmlTag );
    for LIdx := 0 to Pred( LXmlAttr.Count ) do
      Writeln( LXmlAttr.Names[LIdx], ' = ', LXmlAttr.ValueFromIndex[LIdx] );

  finally
    LXmlAttr.Free;
  end;

end;

begin
  try

    Test;

  except
    on E : Exception do
      Writeln( E.ClassName, ': ', E.Message );
  end;

  ReadLn;

end.

Ausgabe

Code:

Tag: line
x1 = "100"
y1 = "400"
x2 = "500"
y2 = "400"
stroke = "black"
stroke-width = "1"

Die Attribut-Werte kannst du nun aber auch direkt durch Angabe des Attribut-Names abrufen:

Delphi-Quellcode:

var
  LXmlRow :  string;
  LXmlTag :  string;
  LXmlAttr : TStrings;
begin
  LXmlAttr := TStringList.Create;
  try

    LXmlRow := '<line x1="100" y1="400" x2="500" y2="400" stroke="black" stroke-width="1" />';
    SplitXmlAttributes( LXmlRow, LXmlTag, LXmlAttr );

    WriteLn( LXmlAttr.Values('x2') ); // => "500"

  finally
    LXmlAttr.Free;
  end;  
end;