MemoryLeak bei VirtualStringtree

[shmia]

Der Code sollte besser so aussehen:

Delphi-Quellcode:

procedure Tfrm_start.VstFreeNode(Sender: TBaseVirtualTree; Node: PVirtualNode);
var
  P: ^TObject;
begin
  P := Sender.getNodeData(Node);
  if Assigned(P) then
  begin
      P^.Free;
      P^ := nil; // zur Sicherheit
  end;
end;

Dass du "Vst" anstatt "Sender" verwendet hat, kann natürlich böse ins Auge gehen.
Eventuell lässt sich das noch so vereinfachen: (kann's nicht testen mangels VirtualTree Komponente)

Delphi-Quellcode:

procedure Tfrm_start.VstFreeNode(Sender: TBaseVirtualTree; Node: PVirtualNode);
var
  P: ^TObject;
begin
  P := Sender.getNodeData(Node);
  FreeAndNil(P^);
end;

[jbg]

Zitat von shmia:

P := Sender.getNodeData(Node);
if Assigned(P) then

Unnütz. Sender.GetNodeData liefert hier nie nil, da weder Node=nil, noch Node=RootNode, noch NodeDataSize=0 ist, denn OnFreeNode wird für diese Konstellation nicht aufgerufen.

Zitat:

P^ := nil; // zur Sicherheit

Zur Sicherheit kann man den Speicherbereich direkt vor der Freigabe auch noch mit Nullen füllen.


Wenn man sich TVirtualNode mal anschaut:

Delphi-Quellcode:

TVirtualNode = packed record
  Index,
  ChildCount: Cardinal;
  // ...
  LastChild: PVirtualNode;
  Data: record end;
end;

dann sieht man, dass Sender.GetNodeData (vereinfacht) @Node.Data zurückliefert und das "P^ := nil" nichts anderes ist, als die 4 bzw. 8 Byte die hinter Data sind mit Nullen zu überschreiben. Und das direkt vor der Freigabe des Speicherbereichs.



**Sorry, hab mich nur gerade über eine viel zu langsame Migration geärgert, die, wenn ordnetlich programmiert, in 3 Minuten erledigt wäre und nicht wie jetzt, die ganze Nacht durchlaufen muss**

[youuu]

Hm also wenn ich es so mach:

Delphi-Quellcode:

procedure Tfrm_start.VstFreeNode(Sender: TBaseVirtualTree;
  Node: PVirtualNode);
Var
  Liste: ^Tliste;
begin
  Liste := Sender.GetNodeData(node);
  Liste^.Free;
end;

Bleibt der Leak bestehen.




Edit: So werden die Nodes hinzugefügt.

Delphi-Quellcode:

while not Query.Eof do begin
  Liste := TListe .Create;
  with Liste do begin
    ... Daten
  end;

  Node := FVst.AddChild(nil, KundenListe);
  Node.CheckType:= ctCheckBox;

  Query.Next;
end;

VstFreeNode muss ich nicht noch extra speziell aufrufen oder?

[Zacherl]

Gibt es bei dir Nodes, die nicht sichtbar sind? Rufe mal für jede Node, die du hinzufügst ValidateNode(Node) auf. Ich hatte das selbe Problem, was daran liegt, dass für nicht validated Nodes kein OnFreeNode Event aufgerufen wird. Nodes werden standardmäßig erst dann validiert, wenn sie mindestens einmal sichtbar waren.

[youuu]

Sind alle Sichtbar, kein Node ist unsichtbar.

Angeblich soll hier der Leak sein  KundenListe := TKundenListe.Create;

[youuu]

Siehe Anhang ein Bild, welches mich auch verwirrt. Wieso verursacht die System.pas auch Leaks? Und das alles erst nach dem füllen des VST's

[Zacherl]

Zitat von youuu:

Sind alle Sichtbar, kein Node ist unsichtbar.

Probier das ValidateNode() zur Sicherheit bitte trotzdem mal.

Zitat von youuu:

Angeblich soll hier der Leak sein  KundenListe := TKundenListe.Create;

Das ist nur dann der Fall, wenn du deine Liste im OnFreeNode Event nicht wieder freigibst.

Ich weiß nicht, ob der VST damit zurecht kommt, wenn du direkt eine Klasse bzw. ein Objekt als Node nimmst. Ich gehe immer so vor:

Delphi-Quellcode:

type
  PMyNodeData = ^TMyNodeData;
  TMyNodeData = packed record
    Liste: TListe;
  end;

Dann irgendwo zur Initialisierung:
VST.NodeDataSize := SizeOf(TMyNodeData)

Nodes hinzufügen:

Delphi-Quellcode:

NodeData := VST.GetNodeData(VST.AddChild(nil));
NodeData^.Liste := TListe.Create;
// ..

Im OnFreeNode Event:

Delphi-Quellcode:

NodeData := Sender.GetNodeData(Node);
if Assigned(NodeData) then
begin
  NodeData^.Liste.Free;
  // Wenn du Strings oder Ähnliches direkt im TMyNodeData Record verwendest einfach noch ein
  // Finalize(NodeData^)
  // hinterherschieben
end;

Edit: Der Leak stammt nicht wirklich aus der System.pas. Es wird irgendwo ein UnicodeString erzeugt, welcher nicht mehr freigegeben wird. Lediglich die Funktion zum Erstellen eines neuen Strings befindet sich in der System.pas und wird per compiler magic oder was auch immer automatisch von Delphi aufgerufen, sobald du eine neue String Instanz erzeugst.

Edit: Was mir grade noch einfällt: Das Leak könnte sich auch in deiner TListe Klasse befinden. Prüf das am besten auch nochmal.

[youuu]

Edit: das war es, Leak ist entfernt. Danke Dir. Ich musste also nur das Objekt richtig einbinden