Ich lade ein 24Bit 16x16 Pixel PNG Image in ein TImage (Autosize True).
Image1.Picture.LoadFromFile(ExtractFilePath(ParamStr(1))+'testimage.png' )
Das Bild wird korrekt angezeigt.

Image1.Picture.Bitmap.Width gibt 16 aus.

Wenn ich nun (sogar nur lesend) auf Image1.Picture.Bitmap oder Image1.Picture.Icon zugreife (in dem Fall weise ich Image1.Picture.Icon einem anderen TIcon Objekt mit assign zu) dann wird das Bild sofort leer, Image1.Picture.Bitmap.Width wird 0 und es kracht Fehler.

Wenn ich die Delphi Anleitung zur Hilfe nehme steht folgendes drin:

"If Icon is referenced when the TPicture contains a Bitmap or Metafile graphic, the graphic won't be converted. Instead, the original contents of the TPicture are discarded and Icon returns a new, blank icon."

Also ist laut Delphi Hilfe dieses Verhalten korrekt.

Nun meine Frage, was passiert hier eigentlich, wieso wird also ein blankes Icon erzeugt?

Wie kann ich es umgehen, also aus dem Bild welches in einem TImage steckt ein TIcon mit dem gleichen Inhalt erzeugen?

Wenn du ein PNG-Image in ein TPicture lädst, dann ist dessen Graphic-Property ein TPngImage (oder etwas ähnliches je nach verwendetem PNG-Support). Das kannst du einfach überprüfen, in dem du nach dem Laden schaust, was unter Image1.Picture.Grpahic.Classname so steht.

Sobald du auf eines der Properties Bitmap, Icon oder Metafile zugreifst, ändert sich die Klasse von Graphic in den gewünschten Typ und die vorherige Instanz wird freigegeben.

Gibt es einen Weg wie ich den gerade angezeigten Inhalt in ein TIcon reinbekomme?

Zweite Frage glatt überlesen...

Wenn du aus einem PNG ein Icon machen willst, dann geht das nur über eine Konvertierung. In vielen Fällen können die TGraphic-Abkömmlinge sich selbst irgendwie umwandeln. Idealerweise machst du das über eine separate Instanz entweder des Source- oder des Zielobjekts, da die interne Instanz des TPicture ja beim Wechsel des Formats freigegeben wird.

Also konkret (ungetestet):

zusammenfalten · markieren

Delphi-Quellcode:

var
  tmpPic: TPicture;
begin
  tmpPic := TPicture.Create(nil);
  try
    tmpPic.LoadFromFile(...);
    Image1.Picture.Icon.Assign(tmpPic.Graphic);
  finally
    tmpPic.Free;
  end;
end;

oder

markieren

Delphi-Quellcode:

var
  icon: TIcon;
begin
  { irgendwo eventuell }
  icon := TIcon.Create;
  ...
  Icon.Assign(Image1.Picture.Graphic);
  ...
end;

Es schmiert leider ab.

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var tmpPic: TPicture;
begin
     try
         tmpPic := TPicture.Create;
         tmpPic.LoadFromFile(ExtractFilePath(ParamStr(1))+'testimage.png');
         Image1.Picture.Icon.Assign(tmpPic.Graphic);
     finally
         tmpPic.Free;
     end;
end;

Exception: Cannot assign a TPNGObject to a TIcon.

Zitat von Shark99:

Exception: Cannot assign a TPNGObject to a TIcon.

Dann geht das mit TPNGObject halt nicht. In dem Fall musst du dir eine passende Grafik-Bibliothek zulegen, die das untertützt.

Kannst du da was empfehlen?

versuchs mal damit ....

zusammenfalten · markieren

Delphi-Quellcode:

Procedure LoadPNGAsIcon(const fn: String; var ICO: TIcon);
var
  Header: PBitmapV5Header;
  hNewBitmap, hMonoBitmap: HBITMAP;
  Bits: Pointer;
  x, y: Integer;
  DC: HDC;
  IconInfo: _ICONINFO;
  Pixel: ^Integer;
  ScanLine: PRGBTriple;
  AlphaScanline: pByteArray;
  PNG: TPngObject;
begin

  PNG := TPngObject.Create;
  try
    PNG.LoadFromFile(fn);
    if not Assigned(ICO) then
      ICO := TIcon.Create;
    New(Header);
    FillMemory(Header, SizeOf(BitmapV5Header), 1);
    Header.bV5Size := SizeOf(BitmapV5Header);
    Header.bV5Width := PNG.Width;
    Header.bV5Height := -PNG.Height;
    Header.bV5Planes := 1;
    Header.bV5BitCount := 32;
    Header.bV5Compression := BI_BITFIELDS;
    Header.bV5RedMask := $00FF0000;
    Header.bV5GreenMask := $0000FF00;
    Header.bV5BlueMask := $000000FF;
    Header.bV5AlphaMask := $FF000000;
    DC := GetDC(0);
    hNewBitmap := CreateDIBSection(DC, PBitmapInfo(Header)^, DIB_RGB_COLORS,
      Bits, 0, 0);
    Dispose(Header);
    ReleaseDC(0, DC);
    hMonoBitmap := CreateBitmap(PNG.Width, PNG.Height, 1, 1, nil);
    Pixel := Bits;
    for y := 0 to PNG.Height - 1 do
    begin
      ScanLine := PNG.ScanLine[y];
      AlphaScanline := PNG.AlphaScanline[y];
      for x := 0 to PNG.Width - 1 do
      begin
        if Assigned(AlphaScanline) then
          Pixel^ := AlphaScanline[x]
        else
          Pixel^ := 255;
        Pixel^ := Pixel^ shl 8;
        Inc(Pixel^, ScanLine^.rgbtRed);
        Pixel^ := Pixel^ shl 8;
        Inc(Pixel^, ScanLine^.rgbtGreen);
        Pixel^ := Pixel^ shl 8;
        Inc(Pixel^, ScanLine^.rgbtBlue);
        Inc(Pixel);
        Inc(ScanLine);
      end;
    end;
    IconInfo.fIcon := true;
    IconInfo.hbmMask := hMonoBitmap;
    IconInfo.hbmColor := hNewBitmap;
    ICO.Handle := CreateIconIndirect(IconInfo);

    DeleteObject(hNewBitmap);
    DeleteObject(hMonoBitmap);
  finally
    PNG.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  ICO:TIcon;
begin
  ICO := nil;
  LoadPNGAsIcon('C:\Bilder\about.png',ico);
  image1.Picture.Assign(ico);
  ico.Free;
end;

Die Vampyre Imaging Library hat eine Demo zum Konvertieren verschiedener Formate.

turboPASCAL hat mal ein Open Source Tool veröffentlicht, das kann vlt. weiterhelfen:

http://www.delphipraxis.net/132423-%...-png-icon.html