Hallo liebe Delphi-Gemeinde,

mich plangt gerade ein Problem wo ich nicht so recht hintersteige

Ich habe zwei Datenstrukturen: Zum einen habe einen Array of Record und zum anderen eine Matrix.
Diese Fülle ich mit Daten. Das läuft soweit alles glatt.
Jetzt gehe ich die Matrix durch und schaue in jeder Zeile ob da ein String 'geld' vorkommt. Falls dies zutrifft, soll diese Zeile gelöscht werden. D.h. die folgenden Zeilen/Daten in beiden Datenstrukturen aufrücken und die betroffene Zeile somit löschen/überschreiben und zuguter letzt die Länge der Strukturen kürzen:

markieren

Delphi-Quellcode:

type
  TRecord = record
    id: Integer;
    timestamp: String;
    nr: Integer;
  end;

var
  meinRecord: array of TRecord;
  matrix: array of array of String;

In meinem Programm gehe ich so vor

zusammenfalten · markieren

Delphi-Quellcode:

SetLength(meinRecord, x); // beide Datenstrukturen haben die gleiche anzahl von Zeilen (Länge x)
SetLength(matrix, x);
for i := 0 to x-1 do
begin
  meinRecord[i] := ...; // fülle mit daten
  SetLength(matrix[i], y); // unbekannte Länge y
  for k := 0 to y-1 do
  begin
    matrix[i][k] := ...; // fülle mit daten
  end;
end;

...

n := 0;
count := 0;
for i := 0 to length(meinRecord)-1 do
begin
  m := true;
  for k := 0 to length(matrix[n])-1 do
  begin
    if (matrix[n][k] = 'geld') then
    begin
      Move(meinRecord[n+1], meinRecord[n], SizeOf(meinRecord[0])*(Length(meinRecord)-n-1));
      SetLength(meinRecord, Length(meinRecord)-1);
      Move(matrix[n+1], matrix[n], SizeOf(matrix[0])*(Length(matrix)-n-1));
      SetLength(matrix, Length(matrix)-1);
      n := i - count;
      m := false;
      count := count + 1;
      break;
    end;
  end;
  if m = true then
    n := i + 1 - count;
end;

Bei meinem Record funktioniert auch alles glatt, nur die Matrix spinnt rum. Scheinbar überschreibt er die betroffene Zeile korrekt, aber sobald die letzte Zeile gelöscht wird um die Matrix zu verkürzen, ist die überschriebene Zeile wieder leer.
Meine Vermutung: call by reference -> sobald die letzte Zeile gelöscht wird, werden auch die daten der neu überschriebenen Zeile gelöscht.
Liege ich mit meiner Vermutung richtig? Wie kann ich diesen Fehler beheben?

Viele Grüße
Saul

Zitat:

Bei meinem Record funktioniert auch alles glatt,

aber auch nur scheinbar, auch hier werden Stringreferenzen und nicht Inhalte kopiert.
Im Debugger sieht alles gut aus, aber wehe Du fasst einen der Strings an.

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
const
 C='Vergleichsstring';
var
 i:Integer;

begin
  SetLength(meinRecord,100);
  meinRecord[0].id := 1;
  meinRecord[0].timestamp := C;
  meinRecord[0].nr := 1;
  for i := 1 to High(meinRecord) do move(meinRecord[0],meinRecord[i],SizeOf(TRecord));
  meinRecord[0].timestamp := 'Wurscht'; // jetzt machen wir alles kaputt
  memo1.Lines.Add( meinRecord[1].timestamp);
end;

gültige Kopien bekommst Du durch direkte Zuweisung

 meinRecord[x] := meinRecord[y]; analog für matrix

markieren

Delphi-Quellcode:

begin
  SetLength(Matrix,10,10);
  for I := 0 to 9 do Matrix[0][i] := IntToStr(i);
  Matrix[1]:=Matrix[0];
  for I := 0 to 9 do Memo1.Lines.Add(Matrix[1][i]);
end;

D.h. man sollte die Funktion Move() vermeiden und lieber direkt bzw. selber kopieren?
Oder verstehe ich jetzt was falsch?

Doch geht schon, auch ohne Speicherlöcher:

zusammenfalten · markieren

Delphi-Quellcode:

procedure RemoveFromMyRecord(Index: Integer);
var
  Len: Integer;
begin
  Len := High(MyRecord);
  if Index <= Len then
  begin
    Finalize(MyRecord[Index], 1);
    if Index < Len then
    begin
      Move(MyRecord[Index + 1], MyRecord[Index], (Len - Index) * SizeOf(TRecord));
      FillChar(MyRecord[Len], SizeOf(TRecord), 0);
    end;
    SetLength(MyRecord, Len);
  end;
end;

procedure RemoveFromMyMatrix(Index: Integer);
var
  Len: Integer;
begin
  Len := High(MyMatrix);
  if Index <= Len then
  begin
    Finalize(MyMatrix[Index], 1);
    if Index < Len then
    begin
      Move(MyMatrix[Index + 1], MyMatrix[Index], (Len - Index) * SizeOf(string));
      FillChar(MyMatrix[Len], SizeOf(string), 0);
    end;
    SetLength(MyMatrix, Len);
  end;
end;

Hi Bjoerk,

ich danke dir für deine Hilfe.
Funktioniert 1AAAAAA =)

Gruß,
Saul