Ich vermisse Konstanten erst im Konstruktor initialisieren zu können

[Furtbichler]

'strict private' bedeutet doch, das die Variable nur innerhalb der Unit, in der sie deklariert ist, für abgeleitete Klassen sichtbar ist.

Den Quelltext gibst Du einfach nicht weiter, dann hat sich die Sache erledigt. Dein Problem ist ja ein generelles Problem, welches so gar nicht lösbar ist. Oder hab ich mal wieder irgendwas verpasst?

[Sir Rufo]

Zitat von Furtbichler:

'strict private' bedeutet doch, das die Variable nur innerhalb der Unit, in der sie deklariert ist, für abgeleitete Klassen sichtbar ist.

Den Quelltext gibst Du einfach nicht weiter, dann hat sich die Sache erledigt. Dein Problem ist ja ein generelles Problem, welches so gar nicht lösbar ist. Oder hab ich mal wieder irgendwas verpasst?

strict private nur die direkte Klasse kann darauf zugreifen. Weder innerhalb der Unit noch Ableitungen können darauf zugreifen

[Furtbichler]

Zitat von Sir Rufo:

...

Zitat von DeddyH:

...

Ich sag ab jetzt nie wieder was.

[haentschman]

Zitat:

Ich sag ab jetzt nie wieder was.

...joa is denn heut scho Weihnachten ?

mir war grad so, sorry...

[Furtbichler]

hmmm. hmmm..mhmmmhmm...hmmhmfgfds

[DeddyH]

Zitat von Furtbichler:

'strict private' bedeutet doch, das die Variable nur innerhalb der Unit, in der sie deklariert ist, für abgeleitete Klassen sichtbar ist.

Sicher? Nach meiner Kenntnis ist sie nur in der Klasse sichtbar, zu der sie gehört, aber nicht in abgeleiteten Klassen, selbe Unit oder nicht.

[edit] *Boah eyh*, roter Kasten wieder kaputt (schon das 2. Mal heute) [/edit]

[Sir Rufo]

Diese beiden (Beispiel-) Units sollten veranschaulichen, was geht, und was nicht

Delphi-Quellcode:

unit BaseClass;

interface

type
  TBaseClass0 = class
  strict private
    FStrictPrivate : Integer;
  private
    FPrivate : Integer;
  strict protected
    FStrictProtected : Integer;
  protected
    FProtected : Integer;
  public
    FPublic : Integer;

    procedure DoSomeThing; virtual;
  end;

  TBaseClass1 = class( TBaseClass0 )

  public
    procedure DoSomeThing; override;
  end;

procedure DoSomeThing( ABase : TBaseClass0 );

implementation

{ TBaseClass0 }

procedure TBaseClass0.DoSomeThing;
begin
  FStrictPrivate   := 0;
  FPrivate         := 0;
  FStrictProtected := 0;
  FProtected       := 0;
  FPublic          := 0;
end;

{ TBaseClass1 }

procedure TBaseClass1.DoSomeThing;
begin
  inherited;
  // FStrictPrivate   := 1; // nicht möglich
  FPrivate         := 1;
  FStrictProtected := 1;
  FProtected       := 1;
  FPublic          := 1;
end;

procedure DoSomeThing( ABase : TBaseClass0 );
begin
  with ABase do
    begin
      // FStrictPrivate := 3; // nicht möglich
      FPrivate := 3;
      // FStrictProtected := 3; // nicht möglich
      FProtected := 3;
      FPublic    := 3;
    end;
end;

end.

Delphi-Quellcode:

unit BaseClass2;

interface

uses
  BaseClass;

type
  TBaseClass2 = class( TBaseClass0 )

  public
    procedure DoSomeThing; override;
  end;

procedure DoSomeThing( ABase : TBaseClass0 );

implementation

{ TBaseClass2 }

procedure TBaseClass2.DoSomeThing;
begin
  inherited;
  // FStrictPrivate   := 2; // nicht möglich
  // FPrivate         := 2; // nicht möglich
  FStrictProtected := 2;
  FProtected       := 2;
  FPublic          := 2;
end;

procedure DoSomeThing( ABase : TBaseClass0 );
begin
  with ABase do
    begin
      // FStrictPrivate   := 4; // nicht möglich
      // FPrivate         := 4; // nicht möglich
      // FStrictProtected := 4; // nicht möglich
      // FProtected       := 4; // nicht möglich
      FPublic := 4;
    end;
end;

end.