EOF beendet das Einlesen einer Datei vorzeitig

[Mavarik]

Zitat von dGeek:

Datei mit seltsamen Zeichen

Dann mach doch einfach so etwas:
Ausnahmsweise per Stream und nicht wie sonst per Blockread/Write

Delphi-Quellcode:

  Procedure CorrectFile(F:String);
  var
    MS : TMemoryStream;
    I  : Integer;
    P  : PByte;
  begin
    MS := TMemoryStream.Create;
    try
      MS.LoadFromFile(F); // geändert

      MS.Position := 0;
      P := MS.Memory;
 
      For i:=0 to MS.Size-1 do
        begin
          if P^ = $1A then // Dateiende
            P^ := $20;
          inc(p);
        end;

      MS.SaveToFile(F); // geändert
    finally
      MS.Free;
    end;
  end;

oder halt klassisch

Delphi-Quellcode:

  Procedure CorrectFile(F:String);
  var
    FD      : File;
    Buffer  : Array of byte;
    Size,I  : Integer;
  begin
    AssignFile(FD,F);
    Reset(FD,1);
    try
      Size := FileSize(FD);

      Setlength(Buffer,Size);
      Blockread(fd,Buffer[0],Size);
      Seek(FD,0);

      For i:=0 to Size-1 do
        if Buffer[i] = $1A then
          Buffer[i] := $20;

      Blockwrite(FD,Buffer[0],Size);
    finally
      Closefile(FD);
    end;
  end;

Mavarik

[DeddyH]

Ein paar Ressourcenschutzblöcke wären nicht schlecht, und kann man sich die erste FileStream-Instanz nicht sparen und stattdessen LoadFromFile des MemoryStream nehmen, oder überseh ich da etwas?

[Mavarik]

Zitat von DeddyH:

Ein paar Ressourcenschutzblöcke wären nicht schlecht, und kann man sich die erste FileStream-Instanz nicht sparen und stattdessen LoadFromFile des MemoryStream nehmen, oder überseh ich da etwas?

Stimmt... War bei mir ein compressed Stream... daher... Copy Buffer...