AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Object-Pascal / Delphi-Language Delphi TThreadPool.Default.QueueWorkItem - wie parameter mitgeben

TThreadPool.Default.QueueWorkItem - wie parameter mitgeben

Ein Thema von newbe · begonnen am 24. Apr 2015 · letzter Beitrag vom 27. Apr 2015
Antwort Antwort
Seite 2 von 2     12
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#11

AW: TThreadPool.Default.QueueWorkItem - wie parameter mitgeben

  Alt 27. Apr 2015, 08:28
Hier mal den Wrapper in einer eigenen Unit mit bis zu 4 Argumenten
Delphi-Quellcode:
unit Generics.Utils;

interface

uses
  System.SysUtils;

type
  TWrapper = class
    class function Proc<T>( AProc: TProc<T>; Arg: T ): TProc; overload;
    class function Proc<T1, T2>( AProc: TProc<T1, T2>; Arg1: T1; Arg2: T2 ): TProc; overload;
    class function Proc<T1, T2, T3>( AProc: TProc<T1, T2, T3>; Arg1: T1; Arg2: T2; Arg3: T3 ): TProc; overload;
    class function Proc<T1, T2, T3, T4>( AProc: TProc<T1, T2, T3, T4>; Arg1: T1; Arg2: T2; Arg3: T3; Arg4: T4 ): TProc; overload;
  end;

implementation

{TWrapper}

class function TWrapper.Proc<T1, T2, T3, T4>( AProc: TProc<T1, T2, T3, T4>; Arg1: T1; Arg2: T2; Arg3: T3; Arg4: T4 ): TProc;
begin
  Result := procedure
    begin
      AProc( Arg1, Arg2, Arg3, Arg4 );
    end;
end;

class function TWrapper.Proc<T1, T2, T3>( AProc: TProc<T1, T2, T3>; Arg1: T1; Arg2: T2; Arg3: T3 ): TProc;
begin
  Result := procedure
    begin
      AProc( Arg1, Arg2, Arg3 );
    end;
end;

class function TWrapper.Proc<T1, T2>( AProc: TProc<T1, T2>; Arg1: T1; Arg2: T2 ): TProc;
begin
  Result := procedure
    begin
      AProc( Arg1, Arg2 );
    end;
end;

class function TWrapper.Proc<T>( AProc: TProc<T>; Arg: T ): TProc;
begin
  Result := procedure
    begin
      AProc( Arg );
    end;
end;

end.
Und nun ein kleines Beispiel
Delphi-Quellcode:
program dp_184827;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils,
  Generics.Utils in 'Generics.Utils.pas';

procedure DoFoo( AStr: string; AInt: Integer );
begin
  Writeln( 'CALL DoFoo( AStr: ', QuotedStr( AStr ), ', AInt: ', AInt );
end;

procedure Test;
var
  LProc: TProc;
begin
  // Direkter Aufruf von DoFoo
  DoFoo(
    {AStr} 'Ein String',
    {AInt} 42 );

  // Wrappen mit Argumenten
  LProc := TWrapper.Proc<string, Integer>(
    {AProc} DoFoo,
    {Arg1} 'Ein String',
    {Arg2} 42 );

  // Aufrufen
  LProc( );
end;

begin
  try
    Test;
  except
    on E: Exception do
      Writeln( E.ClassName, ': ', E.Message );
  end;
  ReadLn;

end.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
newbe

Registriert seit: 14. Okt 2008
143 Beiträge
 
Delphi 7 Personal
 
#12

AW: TThreadPool.Default.QueueWorkItem - wie parameter mitgeben

  Alt 27. Apr 2015, 08:56
Delphi-Quellcode:
// Wrappen mit Argumenten
  LProc := TWrapper.Proc<string, Integer>(
    {AProc} DoFoo,
    {Arg1} 'Ein String',
    {Arg2} 42 );
Danke erstmal für deine ausführliche Antwort.
kann ich dabei auch variablen angeben, ansonsten wärs ja ziemlich sinnlos und auch ziemlich viel Code? Die ganzen Proceduredeklarationen für einen weiteren Parameter. Da ich gerne universelle "einmal machen und vergessen"- Lösungen habe würde ich es vermutlich doch so machen das ich ein TDictionary übergebe mit Keyvaluepairs vom Typ (String, Variant). Meine einzige Sorge dabei wäre eventuell die Typkompatibilität in alle Fällen gegeben ist.

mfg Newbe
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#13

AW: TThreadPool.Default.QueueWorkItem - wie parameter mitgeben

  Alt 27. Apr 2015, 09:27
Delphi-Quellcode:
// Wrappen mit Argumenten
  LProc := TWrapper.Proc<string, Integer>(
    {AProc} DoFoo,
    {Arg1} 'Ein String',
    {Arg2} 42 );
Danke erstmal für deine ausführliche Antwort.
kann ich dabei auch variablen angeben, ansonsten wärs ja ziemlich sinnlos und auch ziemlich viel Code?
Natürlich, kannst du da auch Variablen übergeben. Von diesen wird aber nur der Wert genommen, was in diesem Fall auch wichtig und richtig ist. Das Problem mit der Schleife und den Variablen wurde ja schon angesprochen.
Die ganzen Proceduredeklarationen für einen weiteren Parameter. Da ich gerne universelle "einmal machen und vergessen"- Lösungen habe würde ich es vermutlich doch so machen das ich ein TDictionary übergebe mit Keyvaluepairs vom Typ (String, Variant). Meine einzige Sorge dabei wäre eventuell die Typkompatibilität in alle Fällen gegeben ist.

mfg Newbe
Hmmm, du hast doch mit den Typ-Argumenten etwas Generelles und dazu auch noch typsicher. Bei mehr als 4 Argumenten überlege ich allerdings auch vorher, ob es nicht Sinn machen würde, daraus einen Record oder eine Klasse zu erstellen und dann mit nur einem (bzw. sehr wenigen) Argument/en zu übergeben.

Eigentlich ist es ähnlich zu dem, was du mit deinem Dictionary da machen möchtest.

Aber dir ist doch ein Tuple bekannt? So etwas geht mit Delphi auch ... wenn man sich das baut und dann übergibt man eben so ein Tuple - also ein Argument
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
newbe

Registriert seit: 14. Okt 2008
143 Beiträge
 
Delphi 7 Personal
 
#14

AW: TThreadPool.Default.QueueWorkItem - wie parameter mitgeben

  Alt 27. Apr 2015, 09:57
@Sir Rofu

Danke für deine umfassenden Ausführungen. Ich werde das mal mit den generics probieren, mal schauen wie ich damit klar komme.

@himitsu

das ist ja mal ein fieses Stück Sourcecode xD

Delphi-Quellcode:
S := 'Welt';
B := False;
while not B do
  TThread.Synchronize(nil, procedure
    begin
      B := InputQuery('Hallo', 'Du', S);
    end;
if S <> 'Weltthen
  FühreWeltuntergangHerbei;
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 14:17 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2020 by Daniel R. Wolf