Erkennen, ob USB-Stick oder SD-Card eingesteckt oder herausgenommen?

[Popov]

Also den kleinen Tipp von mir hast du nicht umgesetzt?

Delphi-Quellcode:

type
  TForm1 = class(TForm)
  private
    { Private-Deklarationen }
    procedure WMDeviceChange(var Msg: TMessage); message WM_DEVICECHANGE;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//Reagiert auf Hinzufügen oder entfernen von Laufwerken
procedure TForm1.WMDeviceChange(var Msg: TMessage);
const
  DBT_DEVICEARRIVAL = $8000; // System eindeckt ein neues Grerät
  DBT_DEVICEREMOVECOMPLETE = $8004; // Gerät wurde entfernt
begin
  inherited;

  case Msg.wParam of
  DBT_DEVICEARRIVAL: //hinzu
      begin
        ShowMessage('Ein Gerät wurde hinzugefügt.');
      end;
  DBT_DEVICEREMOVECOMPLETE: //entfernen
      begin
        ShowMessage('Ein Gerät wurde entfernt.');
      end;
  end;
end;

[AlexII]

Zitat von Popov:

Also den kleinen Tipp von mir hast du nicht umgesetzt?

Bin gerade dabei... aber dieser Code hier wird wahrscheinlich mit Lazarus nicht funktionieren. LCL leitet die Message an die App bzw. das Form nicht weiter. Habe es gelesen... nachdem ich viele Beispiele hier ausprobiert habe und die nicht funktionierten.

[hathor]

Mit LAZARUS 1.4.0 getestet:

Delphi-Quellcode:

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Windows, Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;

var
  Form1: TForm1;
  OldWProc: WNDPROC;

implementation

{$R *.lfm}

{ TForm1 }

const DBT_DEVICEARRIVAL = $8000;
//const DBT_DEVICEQUERYREMOVE = $8001;
//const DBT_DEVICEQUERYREMOVEFAILED = $8002;
//const DBT_DEVICEREMOVEPENDING = $8003;
const DBT_DEVICEREMOVECOMPLETE = $8004;
//const DBT_DEVICETYPESPECIFIC = $8005;
//const DBT_CONFIGCHANGED = $0018;

procedure MM(s:string); begin Form1.Memo1.lines.add(s); end;

procedure FindDrives;
var
  Drive: Char;
  DriveLetter: string;
begin
  MM('The following drives were found in this computer:');
  MM('');
  // Search all drive letters
  for Drive := 'A' to 'Z' do
  begin
    DriveLetter := Drive + ':\';
    case GetDriveType(PChar(DriveLetter)) of
     DRIVE_REMOVABLE: MM(DriveLetter + ' USB Stick/Drive');
     DRIVE_FIXED:     MM(DriveLetter + ' Fixed Drive');
     DRIVE_REMOTE:    MM(DriveLetter + ' Network Drive');
     DRIVE_CDROM:     MM(DriveLetter + ' CD/DVD/BR Drive');
     DRIVE_RAMDISK:   MM(DriveLetter + ' RAM Disk');
    end;
  end;
  MM('------------------------------------------------');
end;

function MyWndProc(hWnd: HWND; uiMsg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
begin
  case uiMsg of
    WM_DEVICECHANGE:
  case wParam of
  DBT_DEVICEARRIVAL:
      begin
        Windows.Beep(1000,250); Windows.Beep(1500,250);
          Form1.Memo1.clear;
          MM('DEVICECHANGE: Drive added.');
        FindDrives;
        Exit;
      end;
  DBT_DEVICEREMOVECOMPLETE:
      begin
        Windows.Beep(2000,250); Windows.Beep(1500,250);
          Form1.Memo1.clear;
          MM('DEVICECHANGE: Drive removed.');
        FindDrives;
        Exit;
      end;
  end;
  end;
  Result := CallWindowProc(OldWProc, hWnd, uiMsg, wParam, lParam);
end;

procedure SetMyWndProc(Handle : THandle);
begin
     OldWProc := WNDPROC(SetWindowLongPtr(Handle, GWL_WNDPROC, LONG_PTR(@MyWndProc)));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
     SetMyWndProc(Handle);
     FindDrives;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.clear;
  FindDrives;
end;

end.

[BadenPower]

Zitat von hathor:

Mit LAZARUS 1.4.0 getestet:

Funktioniert mit einem USB-Stick, aber nicht mit einer Speicherkarte.

[hathor]

Bei meinem Notebook wird die SD-Card (POPPSTAR 32GB) erkannt.

[BadenPower]

Zitat von hathor:

Bei meinem Notebook wird die SD-Card (POPPSTAR 32GB) erkannt.

Am Rechnersystem, an dem ich Deinen Code getestet hatte, hängt an einem USB-Anschluß ein CardReader, welchem immer 4 Laufwerke zugeordnet sind.

Es wird also kein Laufwerk erzeugt, wenn eine Karte eingesteckt wird und kein Laufwerk entfernt, wenn die Karte herausgenommen wird.

[Popov]

Ich weiß nicht unter was der fest eingebauter CardReader läuft, aber ein Wechsellaufwerk sollte es nicht sein. Somit sollte auch keine Meldung kommen, denn das Laufwerk ist schon da und bleibt, lediglich ein Speichermedium wird gemountet. Wenn du also ein DS Karte einsteckst, dann ist es genau so wie wenn du eine CD in das CD Laufwerk einlegst.

Neben den bei hathors Code aufgelisteten Laufwerke gibt es noch paar andere:

Delphi-Quellcode:

function DriveType(DriveByte: Byte): String;
begin
  case GetDriveType(PChar(Chr(DriveByte + Ord('A')) + ':\')) of
    DRIVE_UNKNOWN:      Result := 'unbekannt';
    DRIVE_NO_ROOT_DIR:  Result := 'Laufwerk existiert nicht';
    DRIVE_REMOVABLE:    Result := 'Wechselmedium';
    DRIVE_FIXED:        Result := 'Festplatte';
    DRIVE_REMOTE:       Result := 'Netzwerk';
    DRIVE_CDROM:        Result := 'CD-ROM/DVD';
    DRIVE_RAMDISK:      Result := 'RAM Disk';
  else
    Result := 'anderer Laufwerkstyp';
  end;
end;