Virtuelles Keyboard für ein bestimmtes Control deaktivieren

[Sir Rufo]

Ja, der Grund dafür ist, dass es sich um ein Singleton handelt und es von diesem Service nicht mehr als einen geben sollte.

Das Verschieben des Konstruktors ist daher Selbstschutz und Dokumentation für: Achtung, ein Singleton!

Allerdings habe ich festgestellt, dass ich das viel zu kompliziert angegangen bin und eine Umsetzung viel schonender erfolgen kann.

Delphi-Quellcode:

unit Common.FMX.VirtualKeyboardService;

interface

uses
  System.Classes,
  System.Generics.Collections,
  FMX.Types,
  FMX.VirtualKeyboard;

type
  TVirtualKeyboardService = class( TComponent, IFMXVirtualKeyboardService )
  private
    FObjects: TList<TFmxObject>;
    FOriginalService: IFMXVirtualKeyboardService;
    constructor Create( AOwner: TComponent );
    class constructor Create;
  protected
    function GetVirtualKeyboardState: TVirtualKeyboardStates;
    function HideVirtualKeyboard: Boolean;
    procedure SetTransientState( Value: Boolean );
    function ShowVirtualKeyboard( const AControl: TFmxObject ): Boolean;
    procedure Notification( AComponent: TComponent; Operation: TOperation ); override;
  public
    class function Current: TVirtualKeyboardService;
    destructor Destroy; override;

    procedure AddOverrideObject( AObject: TFmxObject );
    procedure RemoveOverrideObject( AObject: TFmxObject );
    function IsOverriddenObject( AObject: TFmxObject ): Boolean;
  private
    class var _current: TVirtualKeyboardService;
  end;

implementation

uses
  FMX.Forms,
  FMX.Platform,
  System.SysUtils;

{ TVirtualKeyboardService }

constructor TVirtualKeyboardService.Create( AOwner: TComponent );
begin
  inherited Create( AOwner );

  FObjects := TList<TFmxObject>.Create;

  if TPlatformServices.Current.SupportsPlatformService( IFMXVirtualKeyboardService, FOriginalService ) then
  begin
    TPlatformServices.Current.RemovePlatformService( IFMXVirtualKeyboardService );
    TPlatformServices.Current.AddPlatformService( IFMXVirtualKeyboardService, Self );
  end;
end;

procedure TVirtualKeyboardService.AddOverrideObject( AObject: TFmxObject );
begin
  if Supports( AObject, IVirtualKeyboardControl ) and not FObjects.Contains( AObject ) then
  begin
    FObjects.Add( AObject );
    Self.FreeNotification( AObject );
  end;
end;

class constructor TVirtualKeyboardService.Create;
begin
  TVirtualKeyboardService._current := TVirtualKeyboardService.Create( Application );
end;

class function TVirtualKeyboardService.Current: TVirtualKeyboardService;
begin
  Result := TVirtualKeyboardService._current;
end;

destructor TVirtualKeyboardService.Destroy;
begin
  if Assigned( FOriginalService ) then
  begin
    TPlatformServices.Current.RemovePlatformService( IFMXVirtualKeyboardService );
    TPlatformServices.Current.AddPlatformService( IFMXVirtualKeyboardService, FOriginalService );
  end;
  FObjects.Free;
  inherited;
end;

function TVirtualKeyboardService.GetVirtualKeyboardState: TVirtualKeyboardStates;
begin
  Result := FOriginalService.VirtualKeyboardState;
end;

function TVirtualKeyboardService.HideVirtualKeyboard: Boolean;
begin
  Result := FOriginalService.HideVirtualKeyboard;
end;

function TVirtualKeyboardService.IsOverriddenObject( AObject: TFmxObject ): Boolean;
begin
  Result := FObjects.Contains( AObject );
end;

procedure TVirtualKeyboardService.Notification( AComponent: TComponent; Operation: TOperation );
begin
  inherited;
  if ( Operation = opRemove ) and ( AComponent is TFmxObject ) then
  begin
    RemoveOverrideObject( AComponent as TFmxObject );
  end;
end;

procedure TVirtualKeyboardService.RemoveOverrideObject( AObject: TFmxObject );
begin
  if FObjects.Contains( AObject ) then
  begin
    FObjects.Remove( AObject );
    Self.RemoveFreeNotification( AObject );
  end;
end;

procedure TVirtualKeyboardService.SetTransientState( Value: Boolean );
begin
  FOriginalService.SetTransientState( Value );
end;

function TVirtualKeyboardService.ShowVirtualKeyboard( const AControl: TFmxObject ): Boolean;
begin
  if IsOverriddenObject( AControl ) then
  begin
    HideVirtualKeyboard;
    Result := False;
  end
  else
    Result := FOriginalService.ShowVirtualKeyboard( AControl );
end;

end.

[Mavarik]

Nicht das ich die Routine nicht Cool finde, aber was macht man mit einer Eingabe die keine Tastatur hoch bringt?

[Union]

Und ich frage mich, die wievielte individuelle Implementierung ich davon sehe

[Sir Rufo]

Zitat von Union:

Und ich frage mich, die wievielte individuelle Implementierung ich davon sehe

Stimmt, ich hätte noch eine Implementierung, die auch sehr fix zu machen ist:

Delphi-Quellcode:

// No Virtual Keyboard when ReadOnly
Edit1.ReadOnly := True;

Aber dann ist es eben ein ReadOnly-Edit

[Mavarik]

Zitat von Sir Rufo:

Zitat von Union:

Und ich frage mich, die wievielte individuelle Implementierung ich davon sehe

Stimmt, ich hätte noch eine Implementierung, die auch sehr fix zu machen ist:

Delphi-Quellcode:

// No Virtual Keyboard when ReadOnly
Edit1.ReadOnly := True;

Aber dann ist es eben ein ReadOnly-Edit

Ist ja egal hast eh keine Tastatur zum tippen...

[Sir Rufo]

Zitat von Mavarik:

Nicht das ich die Routine nicht Cool finde, aber was macht man mit einer Eingabe die keine Tastatur hoch bringt?

Hier wird in dem Edit wohl offenbar das Ergebnis des Barcode-Scanners angezeigt und dieses Ergebnis möchte man wohl auch in die Zwischenablage kopieren können. Darum das Edit-Feld.

Aber warum das nicht auf ReadOnly steht, kann ich auch nicht sagen ... evtl. soll dort auch über die Zwischenablage etwas eingefügt werden können sollen tun

[DeddyH]

Ganz einfach erklärt: wie in meinen letzten beiden Threads ersichtlich versuche ich, das Scan-Ergebnis eines Zebra TC-75-Scanners zu bekommen. Per Intent klappt nicht, weil in der Firemonkey-Activity ein Ereignis fehlt, direkt über die API liefert mir nur ein schwarzes Fenster. Daher die blöde Lösung "hintenrum", indem ich einem Edit, das ich außerhalb des sichtbaren Bereichs platziere, den Fokus gebe, und das damit den gescannten String auffängt (deshalb ist ReadOnly auch eine schlechte Option). Und damit der Benutzer sich erstens nicht wundert und zweitens nicht irgendwelche versehentlichen Eingaben macht, die das Ergebnis verfälschen, soll die virtuelle Tastatur eben unterdrückt werden. Glücklich bin ich damit auch nicht, aber mehr als 3 Tage für diesen Mist will ich nicht investieren.