Verknüpfung erzeugen

[SMO]

Dein Delphi XE5 benutzt standardmäßig Unicodestrings, d.h. du musst gar nicht mit MultiByteToWideChar rummachen.

Angepasster Code von Delphi-Treff:

Delphi-Quellcode:

function CreateLink(const AFilename, ALNKFilename, ADescription: string): Boolean;
var
  psl: IShellLink;
  ppf: IPersistFile;
begin
  Result := False;
  if SUCCEEDED(CoCreateInstance(CLSID_ShellLink, nil, CLSCTX_INPROC_SERVER, IID_IShellLink, psl)) then
  begin
    psl.SetPath(PChar(AFilename));
    psl.SetDescription(PChar(ADescription));
    psl.SetWorkingDirectory(PChar(ExtractFilePath(AFilename)));
    // psl.SetIconLocation(PChar(AFilename), 0);
    if SUCCEEDED(psl.QueryInterface(IPersistFile, ppf)) then
      Result := ppf.Save(PChar(ALNKFilename), True) = ERROR_SUCCESS;
  end;
end;

Erklärung: Windows stellt viele seiner APIs, die etwas mit Strings zu tun haben, in "A" und "W" Versionen bereit.
Die "A" Version ist für den "alten" AnsiString Typ, die "W" Version für WideString (Unicode, UTF-16).
Seit Delphi 2009 ist Delphis "string" nicht mehr gleich AnsiString, sondern UnicodeString (kompatibel mit den "W" APIs).
Der Code ging davon aus, dass string = AnsiString und hat explizit die "A" Version von IShellLink angefordert (IID_IShellLinkA).
Für IPersistFile gibt es aber keine "A" Version, deswegen musste der AnsiString erst per MultiByteToWideChar konvertiert werden.
Für die neueren Delphiversionen ist IID_IShellLink ein Alias von IID_IShellLinkW und da string = UnicodeString kann man sich die Verrenkungen sparen.

Zitat von Der schöne Günther:

Hast du mal TFile.CreateSymLink(..) ausprobiert?

Ein SymLink ist nicht dasselbe wie eine Verknüpfung (lnk-Datei).

[DelphiUser123]

Hallo
Danke SMO.
Der Code funktioniert (sogar mit Parameter wenn man SetArguments hinzufügt).
Ich warte noch immer auf einen Ratschlag den CLSID Code zu umgehen für eine modernere Variante.
Ist das nicht sinnvoll für das heutige Windows?
Gruß

[SMO]

Bitte.

Ich habe auch schon diese Variante gesehen (der Einfachheit halber ohne Fehlerprüfung):

Delphi-Quellcode:

var
  IObject: IUnknown;
  ISLink: IShellLink;
  IPFile: IPersistFile;
begin
  IObject := CreateComObject(CLSID_ShellLink);
  ISLink := IObject as IShellLink;
  IPFile := IObject as IPersistFile;

  ISLink.SetPath ...
  ISLink.SetArguments ...
  IPFile.Save(PChar(LinkName), False);
end;

Was genau meinst du mit CLSID umgehen?
Um eine LNK-Datei zu erstellen muss man eben das COM-Objekt erzeugen, welches dafür zuständig ist. Und das wird per CLSID_ShellLink identifiziert. Sollte in jeder gängingen Windowsversion funktionieren.
Eine Alternative wäre, das LNK-Dateiformat zu verstehen (reverse engineering) und die Datei komplett per eigenem Code zu erstellen. Macht natürlich mehr Arbeit und ist wahrscheinlich nicht sinnvoll.

[DelphiUser123]

Microsoft sagt: "new development should use KNOWNFOLDERID values rather than CSIDL values."
Da habe ich wohl CLSID mit CSIDL verwechselt.