Rekursiv Suchen

[GroZ]

Das hab ich natürlich probiert. Jedoch das selbe Ergebnis. Kommt keine Fehlermeldung er hat halt ne Endlosschleife

Also ablaufen sollte das ganze so:

Konsole öffnen:

'Pfad eingeben' + /dir
Enter
Konvertierungsprozedur
wiederholen bis komplette Verzeichnis konvertiert ist.

[baumina]

Achso, interessanterweise machst du mit dem gefundenen TSearchRec X gar nichts.

In die repeat-Schleife kommt er nur, wenn die Eingabe genau "PFAD/dir" lautete.

[GroZ]

Was müsste ich denn da vorher noch "deklarieren"?
Hab in der OH geguckt das einzige was für mich relevant wäre, wäre FileName und der ist immer unterschiedlich. Bei meinen Testordner zum Beispiel Folien1-10

[Sir Rufo]

Ich würde mir schon mal gar keine spezielle Routine dafür bauen, sondern eine generelle und diese dann verwenden. Dann wird auch der gesamte Code übersichtlicher.

Hier etwas zum Herumspielen

Delphi-Quellcode:

program Project1;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  SysUtils;

type
  TProcessFileCallback = procedure( const AFilename: string );

procedure ProcessFiles( const ADirectory, ASearchPattern: string; ACallback: TProcessFileCallback; AAttr: Integer = faAnyFile; ARecursive: Boolean = False );
var
  SearchRec: TSearchRec;
begin
  // Dateien suchen
  if FindFirst( IncludeTrailingPathDelimiter( ADirectory ) + ASearchPattern, AAttr, SearchRec ) = 0
  then
    try
      repeat
        ACallback( IncludeTrailingPathDelimiter( ADirectory ) + SearchRec.Name );
      until FindNext( SearchRec ) <> 0;
    finally
      FindClose( SearchRec );
    end;

  // Wenn rekursiv
  if ARecursive
  then // dann
    begin
      // Verzeichnisse suchen
      if FindFirst( IncludeTrailingPathDelimiter( ADirectory ) + '*.*', faDirectory, SearchRec ) = 0
      then
        try
          repeat
            if ( SearchRec.Name <> '.' ) and ( SearchRec.Name <> '..' )
            then
              ProcessFiles( IncludeTrailingPathDelimiter( ADirectory ) + SearchRec.Name, ASearchPattern, ACallback, AAttr, ARecursive );
          until FindNext( SearchRec ) <> 0;
        finally
          FindClose( SearchRec );
        end;
    end;
end;

procedure ProcessSomeFiles( const AFilename: string );
begin
  // Hier erledigen wir die eigentliche Arbeit
  WriteLn(AFilename);
end;

procedure Test;
begin
  WriteLn('=== STARTING ===');
  ProcessFiles( 'C:\Users', '*.png', ProcessSomeFiles, faAnyFile, True );
  WriteLn('=== FINISHED ===');
end;

begin
  try
    Test;
  except
    on E: Exception do
      Writeln( E.ClassName, ': ', E.Message );
  end;

end.

[Phoenix]

@GroZ wärest Du bitte so freundlich und editierst nochmal Deinen ersten Beitrag und gibst ihm einen Aussagekräftigen Titel?
Mit "Erneute Hilfe" kann keiner was anfangen und es wäre schade, wenn wir das Thema wegen einem extrem schlecht gewählten Titel zu machen zu müssen.

Danke.

[Luckie]

Bitte gib deinen Beiträgen in Zukunft aussagekräftige Titel, in denen deutlich wird, um was es geht.

[GroZ]

@Mod Erledigt hoffe das reicht so. Was anderes ist mir nicht eingefallen

@SirRufo mein Problem besteht ja darin das auch weiterhin nur einzelene Dateien konvertierbar sein müssen. Kann ich trotzdem eine generelle nehmen?

[Sir Rufo]

Zitat von GroZ:

@SirRufo mein Problem besteht ja darin das auch weiterhin nur einzelene Dateien konvertierbar sein müssen. Kann ich trotzdem eine generelle nehmen?

Wenn ich das richtig verstanden habe, dann willst du alle *.frp Dateien im Verzeichnis C:\WoAuchImmer umwandeln. Richtig?

Delphi-Quellcode:

procedure ConvertFrpToPdf( const AFilename: string );
begin
  FrpToPdf( AFilename, ChangeFileExt( AFilename, '.pdf' ) );
end;

procedure DoIt;
begin
  ProcessFiles( 'C:\WoAuchImmer', '*.frp', ConvertFrpToPdf );
end;

Fertig => Ja, kann man (und vor allem sehr übersichtlich)

[Mavarik]

Wie wäre es, wenn Du einfach mal die Routine aus #5 nimmst?