Kompilierfehler bei während er Laufzeit erstellten Objekten

[Sir Rufo]

Ich würde generell mal diesen Verhau ein wenig strukturierter angehen, dann wird es wesentlich einfacher.

Zum einen könntest du Frames verwenden oder dir entsprechende Panels zusammenbauen:

Delphi-Quellcode:

type
  TEditPanel = class( TCustomPanel )
  private
    FBestimmungsArtCombobox: TComboBox;
    function GetBestimmungsArt: string;
    procedure SetBestimmungsArt( const Value: string );
    function GetBestimmungsArtIndex: Integer;
    procedure SetBestimmungsArtIndex( const Value: Integer );
    function GetBestimmungsArten: TStrings;
    procedure SetBestimmungsArten( const Value: TStrings );
  public
    constructor Create( AOwner: TComponent ); override;
    property BestimmungsArt: string read GetBestimmungsArt write SetBestimmungsArt;
    property BestimmungsArtIndex: Integer read GetBestimmungsArtIndex write SetBestimmungsArtIndex;
    property BestimmungsArten: TStrings read GetBestimmungsArten write SetBestimmungsArten;
  end;

implementation

{ TEditPanel }

constructor TEditPanel.Create( AOwner: TComponent );
begin
  inherited;
  FBestimmungsArtCombobox        := TComboBox.Create( Self );
  FBestimmungsArtCombobox.Parent := Self;
end;

function TEditPanel.GetBestimmungsArt: string;
begin
  Result := FBestimmungsArtCombobox.Text;
end;

function TEditPanel.GetBestimmungsArten: TStrings;
begin
  Result := FBestimmungsArtCombobox.Items;
end;

function TEditPanel.GetBestimmungsArtIndex: Integer;
begin
  Result := FBestimmungsArtCombobox.ItemIndex;
end;

procedure TEditPanel.SetBestimmungsArt( const Value: string );
begin
  FBestimmungsArtCombobox.Text := Value;
end;

procedure TEditPanel.SetBestimmungsArten( const Value: TStrings );
begin
  FBestimmungsArtCombobox.Items := Value;
end;

procedure TEditPanel.SetBestimmungsArtIndex( const Value: Integer );
begin
  FBestimmungsArtCombobox.ItemIndex := Value;
end;