AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Leerzeichen in String einfügen

Ein Thema von majornudelholz · begonnen am 26. Jan 2016 · letzter Beitrag vom 2. Feb 2016
Antwort Antwort
Seite 1 von 5  1 23     Letzte » 
Benutzerbild von majornudelholz
majornudelholz

Registriert seit: 22. Nov 2015
15 Beiträge
 
Delphi XE7 Professional
 
#1

Leerzeichen in String einfügen

  Alt 26. Jan 2016, 20:50
Hallo,

ich brauche unbedingt Hilfe, im Internet habe ich sonst nichts gescheites gefunden...
Derzeit versuche ich vergeblich Unterstriche in ein String einzufügen, natürlich in bestimmter Reihenfolge!
Aber erst einmal zur Problemstellung:
Nach Eingabe einer Zeichenkette von max. 128 Zeichen soll nach Betätigung des Buttons alle 4 Zeichen ein Unterstrich eingefügt werden!

Meine bisherige Lösung sieht wie folgt aus:
Code:
procedure TForm1.unterstrich(text:string);
var i:integer; var textn:string;
begin
  textn:=text;
   for i:=1 to length(textn) do
      begin
         if ((i mod 3) = 0) then
        begin
          insert('_', textn, i);
        end;
      end;
  label2.caption:=textn;
end;
Wie ihr sicher unschwer erkennen könnt habe ich das Hauptproblem, dass er durch das einfügen der Unterstriche die Zeichenkette verschiebt & die Zählschleife nicht mehr bis an die letzten Zeichen 'heranreicht'... Hatte überlegt, ob das evtl. iterativ lösbar ist. Habe nur keine Idee wie..

Wäre für jegliche Hilfe hierbei dankbar!
  Mit Zitat antworten Zitat
Benutzerbild von blawen
blawen

Registriert seit: 1. Dez 2003
Ort: Luterbach (CH)
651 Beiträge
 
Delphi 12 Athens
 
#2

AW: Leerzeichen in String einfügen

  Alt 26. Jan 2016, 20:53
Wie wäre es mit einer Repeat...Until Schleife?
Roland
  Mit Zitat antworten Zitat
Benutzerbild von majornudelholz
majornudelholz

Registriert seit: 22. Nov 2015
15 Beiträge
 
Delphi XE7 Professional
 
#3

AW: Leerzeichen in String einfügen

  Alt 26. Jan 2016, 20:55
Wie wäre es mit einer Repeat...Until Schleife?
Hatte ich auch schon versucht. Nur habe ich wie gesagt leider keine weiteren Ideen.
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#4

AW: Leerzeichen in String einfügen

  Alt 26. Jan 2016, 21:17
Wie wäre es mit einer Repeat...Until Schleife?
Hatte ich auch schon versucht.
Und was war das Ergebnis?
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von majornudelholz
majornudelholz

Registriert seit: 22. Nov 2015
15 Beiträge
 
Delphi XE7 Professional
 
#5

AW: Leerzeichen in String einfügen

  Alt 26. Jan 2016, 21:34
Wie wäre es mit einer Repeat...Until Schleife?
Hatte ich auch schon versucht.
Und was war das Ergebnis?
Naja, hatte damals keins, weil ich nicht wusste, wie... Habe nun aber eine Idee bzw. es klappt auch schon!
Trotzdem danke für die Mühen! ... und die schnellen Antworten!

Code:
procedure TForm1.leerzeichen(text:string);
var i:integer;
begin
  for i:=1 to 192 do
         if ((i mod 3) = 0) then begin
        //delete(text, i, 1);
        insert(' ', text, i);
        end;
  trimright(text);
  label2.caption:=text;
end;
... so hat's jetzt geklappt!
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.123 Beiträge
 
Delphi 10.3 Rio
 
#6

AW: Leerzeichen in String einfügen

  Alt 27. Jan 2016, 01:59
Code:
procedure TForm1.leerzeichen(text:string);
var i:integer;
begin
  for i:=1 to 192 do
         if ((i mod 3) = 0) then begin
        //delete(text, i, 1);
        insert(' ', text, i);
        end;
  trimright(text);
  label2.caption:=text;
end;
... so hat's jetzt geklappt!
Wie wäre es mit

Delphi-Quellcode:
procedure TForm1.leerzeichen(Const Text:string);
var
  _Result : String;
  PSource,PDest,PEnd : PChar;
  Count : Integer;
begin
  Setlength(_Result,length(Text)+Length(Text) div 4);
  PSource := @Text[Low(Text)];
  PDest := @_Result[Low(_Result)];
  PEnd := @Text[High(Text)];
  Count := 0;

  while PSource <= PEnd do
    begin
      PDest^ := PSource^;
      inc(PDest);
      inc(PSource);
      inc(Count);
      if Count = 4 then
        begin
          Count := 0;
          PDest^ := ' ';
          inc(PDest);
        end;
    end;
  label2.caption:=_Result;
end;
"Bisschen" schneller...
  Mit Zitat antworten Zitat
Dejan Vu
(Gast)

n/a Beiträge
 
#7

AW: Leerzeichen in String einfügen

  Alt 27. Jan 2016, 07:48
Bei 192 Zeichen dürften das 'schneller' weit jenseits der Messbarkeit sein.
Delphi-Quellcode:
var
  i : Integer;
  
begin
  i := 4; // Erste Einfügeposition hinter der 4 Stelle.
  while i < Length(Text) do begin
    insert (Text, i,'_');
    inc(i,5); // weil man ja nun 5 Zeichen weiter rutschen muss
  end;
End;
Getippt und nicht getestet. Sollte aber so oder ähnlich gehen.

Übrigens: Bisschen kleiner, leichter zu verstehen, geradliniger.
  Mit Zitat antworten Zitat
HolgerX

Registriert seit: 10. Apr 2006
Ort: Leverkusen
961 Beiträge
 
Delphi 6 Professional
 
#8

AW: Leerzeichen in String einfügen

  Alt 27. Jan 2016, 08:23
Hmm..

Oder mach es doch einfach mit einer rückwärts laufenden Schleife

Delphi-Quellcode:
function InsertUnderLine(AText : string; aPos : byte):string;
var
  i : integer;
begin
  result := AText;
  for i := length(AText)-1 downto 1 do begin
    if ((i mod aPos) = 0) then
      insert('_',result,i+1);
  end;
end;
Mit 'for' kann man nicht nur 'hochzählen' sondern auch 'runterzählen'
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#9

AW: Leerzeichen in String einfügen

  Alt 27. Jan 2016, 09:00
Oder mit ganz wenigen String-Kopierorgien und einem wahlfreien String den man dort einschieben kann:
Delphi-Quellcode:
function StrInsertEveryNthPos( const AStr, AInsertStr: string; APos: integer ): string;
var
  OffSet : integer;
  ResLen, ResIdx, StrIdx, InsIdx: integer;
begin
  // OffSet for ZEROBASED STRINGS
  OffSet := 1 - low( string );

  // Calculate result length

  ResLen := ( Length( AStr ) div APos );
  if Length( AStr ) mod APos = 0
  then
    Dec( ResLen );
  ResLen := Length( AInsertStr ) * ResLen;
  ResLen := ResLen + Length( AStr );

  SetLength( Result, ResLen );

  // Build result

  ResIdx := 1;

  for StrIdx := 1 to Length( AStr ) do
    begin
      Result[ ResIdx - OffSet ] := AStr[ StrIdx - OffSet ];
      Inc( ResIdx );

      // Insert the AInsertStr

      if ( StrIdx mod APos = 0 ) and ( StrIdx < Length( AStr ) )
      then
        for InsIdx := 1 to Length( AInsertStr ) do
          begin
            Result[ ResIdx - OffSet ] := AInsertStr[ InsIdx - OffSet ];
            Inc( ResIdx );
          end;
    end;
end;
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
EgonHugeist

Registriert seit: 17. Sep 2011
187 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#10

AW: Leerzeichen in String einfügen

  Alt 27. Jan 2016, 09:12
Da es sich explizit um Quad Folgen handelt..

@Maverik ungetestet aus dem Handgelenk geschüttelt:
edit:
Hab's nun doch getestet und da hat noch das mod gefehlt, sonst hängt man auch noch '_' and den letzten quad an

Code:
function leerzeichen(Const Text: String): String;
type PMyQuadMover = {$IFDEF UNICODE}PUInt64{$ELSE}PLongWord{$ENDIF};
var
  Src, Dest, PEnd: PChar;
begin
  if Text = '' then
    Result :=''
  else begin
    SetLength(Result,length(Text)+(Length(Text) div 4)-Ord(Length(Text) mod 4 = 0));
    PEnd := PChar(@Text[Length(Text)])-4;
    Dest := Pointer(Result);
    Src := Pointer(Text);
    while (Src <= PEnd) do begin//making a quad processing loop
      PMyQuadMover(Dest)^ := PMyQuadMover(Src)^;
      (Dest+4)^ := '_';
      Inc(Dest, 5);
      Inc(Src, 4);
    end;
    Inc(PEnd, 4);
    while Src < PEnd do //processing final chars
    begin
      Dest^ := Src^;
      Inc(Src);
      Inc(Dest);
    end;
    Dest^ := Src^; //null term save
  end;
end;
Das wäre schnell.. man könnte die Loops auch nach auf octets erhöhen, auf RefCount und Length vorher testen usw ..

Geändert von EgonHugeist (27. Jan 2016 um 09:55 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 14:10 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz