AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Thema durchsuchen
Ansicht
Themen-Optionen

array of const für spätere Verwendung speichern

Ein Thema von BigAl · begonnen am 31. Jan 2016 · letzter Beitrag vom 1. Feb 2016
 
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
11.744 Beiträge
 
Delphi 12 Athens
 
#6

AW: array of const für spätere Verwendung speichern

  Alt 1. Feb 2016, 14:34
TValue: Dieses Array kann man aber nicht an ein array of const übergeben?
Nicht direkt, aber über eine Schleife lässt sich natürlich einfach wieder ein array of TVarRec aufbauen:

Delphi-Quellcode:
type
  TRec = record
  private
    function GetAsVarRecs: TArray<TVarRec>;
  public
    Params: array of TValue;
    constructor Create(const AParams: array of const);
    property AsVarRecs: TArray<TVarRec> read GetAsVarRecs;
  end;

constructor TRec.Create(const AParams: array of const);
var
  I: Integer;
begin
  SetLength(Params, Length(AParams));
  for I := Low(AParams) to High(AParams) do begin
    Params[I] := AParams[I];
  end;
end;

function TRec.GetAsVarRecs: TArray<TVarRec>;
var
  I: Integer;
begin
  SetLength(result, Length(Params));
  for I := Low(Params) to High(Params) do begin
    result[I] := Params[I].AsVarRec;
  end;
end;

procedure Test(const Fmt: string; const Args: array of const);
var
  rec: TRec;
  S: string;
begin
  rec := TRec.Create(Args);
  S := Format(Fmt, rec.AsVarRecs);
  Assert(S = Format(Fmt, Args));
end;
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:25 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz