Lücken in fortlaufender Nummerierung finden

[Uwe Raabe]

Da hier ja sowieso kein potenter SQL-Server zum qualmen gebracht werden soll, würde ich hier den Heimvorteil der BDE/Paradox-Kombination ausnutzen: Was spricht denn gegen ein sequentiuelles Durchlaufen der Tabelle. Dabei kannst du doch die Lücken direkt erkennen und auflisten. Das hier unbeding mit SQL zu vergewaltigen ist doch gar nicht zielführend.

Delphi-Quellcode:

procedure FindGaps(DataSet: TDataSet; FieldName: string; Target: TStrings; CheckFirst: Boolean);

  procedure AddGap(von, bis: Integer);
  var
    S: string;
  begin
    if von < bis then begin
      S := Format('%d-%d', [von, bis]);
    end
    else begin
      S := Format('%d', [von]);
    end;
    Target.Add(S);
  end;

var
  fld: TField;
  id: Integer;
  nextId: Integer;
  S: string;
begin
  Target.BeginUpdate;
  try
    DataSet.Active := true;
    if DataSet.IsEmpty then
      Exit;
    { DataSet muss nach FieldName sortiert sein }
    fld := DataSet.FieldByName(FieldName);
    DataSet.First;
    if CheckFirst then begin
      nextId := 1;
    end
    else begin
      nextId := fld.AsInteger;
    end;
    repeat
      id := fld.AsInteger;
      if nextId < id then begin
        AddGap(nextId, id - 1);
      end;
      nextId := id + 1;
      DataSet.Next;
    until DataSet.Eof;
  finally
    Target.EndUpdate;
  end;
end;

[jobo]

Genau, der TE wollte zwar SQL, aber Dein Vorschlag finde ich hier auch am sinnvollsten!

[Neutral General]

Würde es für Paradox ne SQL-Lösung geben wäre die auch sehr wahrscheinlich schneller als eine in Delphi.
War also keine schlechte Idee nach SQL zu fragen bzw. es mit SQL zu versuchen.

[noisy_master]

Mann oh mann, ich hätte nicht gedacht, dass dazu SO viele Antworten kommen... Danke erst mal an alle

Dass das Ganze "von Hand" geht(durchgehen nach Uwe's Vorschlag) war mir auch klar, und ist definitiv die übersichtlichste und "flexibelste" Variante, da dort auch größere Lücken auffindbar sind. Ich hatte halt nur auf eine "einfache elegante" Variante per SQL gehofft....

Aber ich habe alles an Antworten bekommen, was man sich so wünschen kann...

Werde es mal mit Uwe's "durchgehen" versuchen...wird zwar nicht schnell sein, aber erstmal egal

[jobo]

ot

Zitat von Neutral General:

Würde es für Paradox ne SQL-Lösung geben wäre die auch sehr wahrscheinlich schneller als eine in Delphi.
War also keine schlechte Idee nach SQL zu fragen bzw. es mit SQL zu versuchen.

Ich denke, das ist genau das Problem, auf das Uwe hinweisen wollte. Der "Server" von Paradox ist immer(!) der eigene PC. Idealerweise liegt das Datenfile lokal und es gibt keinen Netzwerkzugriff /-transport.
Das SQL wird vermutlich eh von der BDE in sequentielle Zugriffe umgebaut, mein eigener Hinweis bezüglich not exists versus outer join ist ja auch fragwürdig bei dieser Art File DB.

SQL=schneller als per Clientprogrammierung finde ich auch immer eine gute Idee, gilt m.E. nur wenn tatsächlich ein echter Server im Spiel ist.
/ot

[Uwe Raabe]

Ich habe den Code nochmal etwas umgebaut, da der erste Datensatz überflüssigerweise zweimal überprüft wurde. Zusätzlich habe ich noch ein Begin/Endupdate auf Target eingebaut.

Leider habe ich gerade keine richtig große Paradox-Tabelle da, aber auf meinem System schafft diese Methode die 4500 Sätze in 5 ms.