specialize TFPGObjectList : AV bei Free

[Alter Mann]

Hallo,

da das mit den Rescourcen klappt, kommt das nächste Problemchen mit specialize TFPGObjectList
Folgendes ist gegeben

Code:

type
  TSmileyInfo = record
    Character : Integer;
    Resource  : Integer;
  end;

  TSmiley   = class(TObject)
  private
    FCharacter : Integer;
    FImage     : TPicture;
  public
    constructor Create(aCharacter : Integer; aImage : TPicture);
    destructor  Destroy; override;

    procedure render(deviceContext : HDC; X, Y : Integer);
    property  Character : Integer read FCharacter;
  end;

  Smileys       = specialize TFPGObjectList<TSmiley>;

  TSmileys      = class(TObject)
  private
    FSmileys    : Smileys;
  protected
    procedure Load(aSmileyInfo : TSmileyInfo);
    function  Find(aCharacter : Integer): TSmiley;
  public
    constructor Create;
    destructor  Destroy; override;
    procedure   renderSmiley(aCharacter : Integer; deviceContext : HDC; X, Y : Integer);
  end;

In TSmileys.FSmileys werden 845 Smileys geladen:

Code:

...
constructor TSmileys.Create;
var
  I : Integer;
begin
  inherited Create;
  FSmileys := Smileys.Create(True);

  for I := Low(TSmileyList) to High(TSmileyList) do
    Load(TSmileyList[I]);
end; 

procedure   TSmileys.Load(aSmileyInfo : TSmileyInfo);
begin
  FSmileys.Add(TSmiley.Create(aSmileyInfo.Character,
    ResourceLoader.loadImageFromResource(aSmileyInfo.Resource, itPNG)));
end;
...

Das Problem taucht nun beim freigeben auf, egal wie ich es mache, es kommt zu einer AV

Code:

...
constructor TSmiley.Create(aCharacter : Integer; aImage : TPicture);
begin
  inherited Create;
  FCharacter := aCharacter;
  FImage     := aImage;
end; 

destructor  TSmiley.Destroy;
begin
  if Assigned(FImage) then 
    FImage.Free;               <- Hier
  inherited Destroy;
end;  
...
destructor  TSmileys.Destroy;
var
  Smiley : TSmiley;
begin
  for Smiley in FSmileys do
    if Assigned(Smiley) then
       Smiley.Free;

  FSmileys.Free;
  inherited Destroy;
end; 
...

Das blöde ist nur das es immer bei einem anderen Picture kommt.

Wie kann ich das Image(TPicture) freigeben ohne das Knallt?
FreeAndNil geht auch nicht.

[mjustin]

Zitat von Alter Mann:

Wie kann ich das Image(TPicture) freigeben ohne das Knallt?

Besteht das Problem auch, wenn anstatt eines TImage eine andere Klasse, die weniger 'sensibel' ist (also zumBeispiel TStringList, TButton, ...) als Typ der Property TSmiley.FImage verwendet wird?

[Zacherl]

Ich sehe, dass die Referenz auf FImage im Constructor reingegeben - und nicht intern erzeugt wird. Vermutlich wird die Instanz durch irgendeinen Logikfehler deshalb mehrfach freigegeben.

[Alter Mann]

@Zacherl

Ich werde morgen mal FImage initialisieren und das übergebene Picture via Assing zuweisen,
mal sehen vielleicht geht das ja.

Danke erstmal und noch einen schönen Abend

Update:

Also eine Änderung in:

Code:

constructor TSmiley.Create(aCharacter : Integer; aImage : TPicture);
begin
  inherited Create;
  FCharacter := aCharacter;
  FImage     := TPicture.Create;
  FImage.Assign(aImage);
end;

bringt auch nichts .

[haentschman]

Moin...

Du erzeugst die Objektliste mit OwnsObjects = True und gibst im destructor selbst die enthaltenen Bilder wieder frei. Das muß Puff machen... Wenn du die Instanzen selbst verwalten möchtest dann OwnsObjects auf False. Dann würde das mit der Freigabe passen. Dann brauchst du aber auch nicht auf Assigned prüfen. Jeder Listeneintrag ist ein Pointer.

Delphi-Quellcode:

FSmileys := Smileys.Create(True); // OwnsObjects = True
.
.
.
destructor TSmileys.Destroy;
var
  Smiley : TSmiley;
begin
//  for Smiley in FSmileys do // diesen Block brauchst du nicht
//    if Assigned(Smiley) then 
//       Smiley.Free; //

  FSmileys.Free;
  inherited Destroy;
end;

..fertsch.

[Alter Mann]

Ja, sieht ganz so aus.

Ich habe es jetzt so gemacht und es geht

Code:

...
destructor  TSmiley.Destroy;
begin
  FPicture.Free;
  inherited Destroy;
end; 
...
destructor  TSmileys.Destroy;
begin
  FSmileys.Clear;
  FSmileys.Free;
  inherited Destroy;
end;

Danke

[haentschman]

Siehst du... again what learned.

Das FSmileys.Clear; kannst du auch weglassen. Das wird beim Free automatisch gemacht. Um Daniel zu zitieren: "Verschwendung von wertvollen Bits und Bytes"

[DeddyH]

Und es geht noch kürzer:

Delphi-Quellcode:

destructor TSmileys.Destroy;
begin
  FSmileys.Free;
  inherited;
end;

Da der Destruktor dieselbe Signatur hat wie der geerbte, kann der explizite Aufruf entfallen.

[haentschman]

...den hatte ich gar nicht gesehen weil selbstverfreilich.