FMX TListView mit Seattle

[Harry Stahl]

Zitat von Sherlock:

Ah, OK. Bei der Gelegenheit, wo ich das sehe, und Dich grad "dran" hab. Wieso gibt es eigentlich keinen aufzählbaren Container für die einzelnen ListBoxItems bei einer FMX.TListBox? Oder hab ich den bloß übersehen?

Vielen Dank!

Sherlock

Mit "aufzählbaren Container" meinst Du die "Items"? TListbox hat in FMX sowohl die "Items", welches nur Strings sind und die "ListItems", welches die Liste der TListBoxItems repräsentiert.

[Sherlock]

Oh. Mein. Gott. Wald...Bäume...ich danke Dir!
Äh, Edith sagt "Nein". Ich muß wohl erklären was ich machen will:

Delphi-Quellcode:

 
var BoxITem: TListBoxItem;
.
.
.
 for BoxItem in SomeListBox.ListItems do

Das geht nicht, weil ListItems nicht wirklich die Liste ist, sondern mit einem Index aufgerufen werden muß und nur ein Item zurück gibt.

Sherlock

[Harry Stahl]

Ach so, Du meinst die For in Enumeration.

Hier geht das standardmäßig nur mit den einfachen Strings:

Delphi-Quellcode:

var
  s: string;
begin
  for s in ListBox1.Items do begin
    ShowMessage (s);
  end;
end;

Warum das mit den ListItems nicht geht, hat Chris Rolliston vor einiger Zeit schon mal hier beschrieben und per ClassHelper auch eine Art Ersatzlösung dafür geboten:

https://delphihaven.wordpress.com/20...-anti-pattern/

In Anlehnung daran könnte man es (hier ein wenig vereinfacht und mit einer etwas anderen Namensgebung, die ich passender finde) für das for in mit den ListboxItems dann so machen:

Delphi-Quellcode:

type
  TFmxObjHelper = class helper for TFMXObject

  strict private
    procedure AddTypeOfObjects <T: class>(Parent: TFmxObject;
      var Arr: TArray<T>; var Count: Integer);
  public
    function ItemsOf<T: class>: TArray<T>;
  end;

procedure TFmxObjHelper.AddTypeOfObjects<T>(Parent: TFmxObject;
  var Arr: TArray<T>; var Count: Integer);
var
  Child: TFmxObject;
  I, z: Integer;
begin
  for I := 0 to Parent.childrenCount - 1 do
  begin
    Child := Parent.Children[I];

    if Child is T then
    begin
      if Length(Arr) = Count then SetLength(Arr, Count + 64);
      Arr[Count] := T(Child);
      Inc(Count);
    end;
    AddTypeOfObjects<T>(Child, Arr, Count);
  end;
end;

function TFmxObjHelper.ItemsOf<T>: TArray<T>;
var
  Count: Integer;
begin
  Count := 0;
  AddTypeOfObjects<T>(Self, Result, Count);
  SetLength(Result, Count);
end;


procedure TForm18.FormCreate(Sender: TObject);
var
  lbi: TListboxItem;
begin
  for lbi in ListBox1.ItemsOf<TListboxItem> do begin
    ShowMessage (lbi.text);
  end;
end;

[Rollo62]

Ich benutze for loop mit Hilfsvariable
  for I := 0 to Count-1 do oder

  for I := Low(Items) to High(Items) do ich weiss das es etwas mehr code und etwas weniger Tipparbeit braucht,
aber gibt es ausserdem noch einen wirkichen Grund for Item in ItemList do zu benutzen ?

Das obere macht eigentlich nie Probleme, und die Performance ist auch OK.
Vielleicht bei 5 Mio. Items sollte man drüber nachdenken, aber im täglichen Leben reicht doch eine Version.

Rollo