FormatSettings for Dummies

[haentschman]

Moin und danke....

Das weiß ich alles. Ich will aber wissen wie das Zeitformat, was der Nutzer eingestellt hat, aussieht und anwenden. Primär geht es nur um die in FormatSettings gelieferten Werte. Die sind definitiv beim Zeitformat falsch. Du kannst einstellen was du willst. Der Formatstring für die Zeit ist immer gleich.
Ich habe mir schon eine Funktion gebaut die die "Unzulänglichkeiten" ausbügelt. Das kann es doch aber nicht sein.

[Sir Rufo]

Dann lies dich in die entsprechenden API-Funktionen ein und bau dir das so wie du das haben willst.

Kleiner Tipp: Da hat sich über die Zeit von Windows XP über Vista und 7 ... etwas (einiges) getan, was du auch alles berücksichtigen musst. Mal sehen auf welchen Ansatz du kommst.

Mit System.SysUtils.GetLocaleStr kannst du sozusagen direkt auslesen, was das OS zurückgibt.

[haentschman]

Danke...

Zitat:

Da hat sich über die Zeit von Windows XP über Vista und 7

...da muß ich mal sagen das interessiert mich nicht. Ich lese die FormatSettings (dafür sind sie da) und erwarte korrekte Werte.
Stelle mal bitte in deinen Regionseinstellungen das kurze Zeitformat auf HH:mm Uhr (Vorlage). Dann zeige mir wie du mit Hilfe der Formatsettings das 13:48 Uhr (so wollte es ja der Nutzer) ohne zusätzliche Korrekturen in ein Label schreibst.

Ich will doch nur bestätigt haben, das auch bei Euch die Zeitformatierung in den FormatSettings falsch ist.

[Der schöne Günther]

Klar, das wird bei jedem so sein.

[Sir Rufo]

Die FormatSettings sind dafür da, dass Delphi mit diesen arbeiten kann und zwar auf jeder Plattform. Somit sind diese Einstellungen dort entsprechend gleichgeschaltet.

Um damit zu arbeiten verwendet man ganz simpel die Funktionen, die optional die FormatSettings als Argument anbieten. Alles, was nach Datum/Zeit riecht wird intern von System.SysUtils.DateTimeToString() (nur intern verfügbar) in einen String umgewandelt.

Wenn du wissen willst, was jetzt explizit bei dem OS an EInstellungen original drin stehen, dann musst du das über den Weg auslesen, den das OS zur Verfügung stellt.

Eigentlich nicht so schwer zu verstehen ...

[Sir Rufo]

Nur mal so gesagt:

Zitat von haentschman:

1. Warum kommt hier Label.Caption := FormatDateTime(Now, FormatSettings.ShortDateFormat) 12/04/2016 statt 12.04.2016 ?

Das kann ich noch nicht einmal kompilieren

Das hier schon
Label1.Caption := FormatDateTime( FormatSettings.ShortDateFormat, Now ); Hier mal ein kleines Beispielprogramm, wo man auch live die Änderungen sehen kann

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.AppEvnts;

type
  TForm1 = class( TForm )
    Label1: TLabel;
    ApplicationEvents1: TApplicationEvents; { OnSettingChange = ApplicationEvents1SettingChange }
    procedure ApplicationEvents1SettingChange(Sender: TObject; Flag: Integer;
      const Section: string; var Result: Integer);
    procedure FormShow(Sender: TObject);
  private
    procedure PresentData;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ApplicationEvents1SettingChange(Sender: TObject; Flag: Integer;
  const Section: string; var Result: Integer);
begin
  PresentData;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  PresentData;
end;

procedure TForm1.PresentData;
begin
  Label1.Caption := FormatDateTime( FormatSettings.ShortDateFormat, Now );
end;

end.

[haentschman]

Zitat:

Um damit zu arbeiten verwendet man ganz simpel die Funktionen, die optional die FormatSettings als Argument anbieten. Alles, was nach Datum/Zeit riecht wird intern von System.SysUtils.DateTimeToString() (nur intern verfügbar) in einen String umgewandelt.

...aber mit falschem Zeitformat.

Zitat:

Das kann ich noch nicht einmal kompilieren

...sorry war auf dem Handy aus dem Hut getippt. Value und FormatString ist umgekehrt.

Delphi-Quellcode:

procedure TForm1.PresentData;
begin
  Label1.Caption := FormatDateTime( FormatSettings.ShortDateFormat, Now );
end;

...jetzt nimmst du mal ShortTimeFormat und versuchst in der Region Englisch mit 12 Std. Anzeige und AM/PM einzustellen. Alternativ kannst du auch unser 24 Stundenformat probieren... es kommt immer 12 Std.Format ohne AM/PM raus.


Wir brechen hier ab. Ich habe mir das selbst für unsere Zwecke korrigiert.

Danke an alle...

[Sir Rufo]

Beim Zeitformat hat Emba allerdings geschlafen, das wird nicht so übernommen, wie in den Windows-Einstellungen eingetragen.

Delphi-Quellcode:

  TimePrefix := '';
  TimePostfix := '';
  if StrToIntDef(GetLocaleStr(Locale, LOCALE_ITLZERO, '0'), 0) = 0 then
    HourFormat := 'h'
  else
    HourFormat := 'hh';
  if StrToIntDef(GetLocaleStr(Locale, LOCALE_ITIME, '0'), 0) = 0 then
    if StrToIntDef(GetLocaleStr(Locale, LOCALE_ITIMEMARKPOSN, '0'), 0) = 0 then
      TimePostfix := ' AMPM'
    else
      TimePrefix := 'AMPM ';
  Result.ShortTimeFormat := TimePrefix + HourFormat + ':mm' + TimePostfix; // <- DA
  Result.LongTimeFormat := TimePrefix + HourFormat + ':mm:ss' + TimePostfix; // <- DA

Da bleibt nur der Weg über das OS (auslesen, ummodeln, verwenden)

[Stevie]

Dein Problem liegt darin, dass du annimmst,
TFormatSettings.ShortTimeFormat und LongTimeFormat hätten etwas mit dem ab Windows 7 einstellbaren "Short time" und "Long time" zu tun, was aber nicht der Fall ist.

[Sir Rufo]

Zitat von Stevie:

Dein Problem liegt darin, dass du annimmst,
TFormatSettings.ShortTimeFormat und LongTimeFormat hätten etwas mit dem ab Windows 7 einstellbaren "Short time" und "Long time" zu tun, was aber nicht der Fall ist.

Öhm ... diese Relation würde ich aber auch implizieren ... nein besser: erwarten!

So bekommt man das Gewünschte:

Delphi-Quellcode:

procedure TForm1.PresentData;
var
  lShortTimeFmt: string;
  lLongTimeFmt : string;
begin
  Label1.Caption := FormatDateTime( FormatSettings.ShortDateFormat, Now ) + ' (' + FormatSettings.ShortDateFormat + ')';

  lShortTimeFmt  := GetLocaleStr( GetThreadLocale, LOCALE_SSHORTTIME, FormatSettings.ShortDateFormat );
  Label2.Caption := FormatDateTime( lShortTimeFmt, Now );

  // Geht erst ab Windows 7!
  lLongTimeFmt   := GetLocaleStr( GetThreadLocale, LOCALE_STIMEFORMAT, FormatSettings.LongTimeFormat );
  Label3.Caption := FormatDateTime( lLongTimeFmt, Now );
end;