TList mit Record füllen und an weitere TList übergeben

[dGeek]

Entweder war ich gestern Abend zu müde oder das was ich vorhabe funktioniert nicht.

Ich habe folgenden Record:

Delphi-Quellcode:

type
 TDataType = (dtFile, dtDirectory);

type
 PFileEntry = ^TFileEntry;

 TFileEntry = packed record
  sFileName: String;
  aDataType: TDataType;
 end;

var
 aProcessFileEntry: PFileEntry;
 aProcessFileList_Record: TList; // Holder

Ich erzeuge mit New() die Datensätze (Records) füge sie der TList mit Add() hinzu.

An einer späteren Stelle muss ich die Liste aussortieren.
Ich erzeuge also eine neue TList und füge gewisse Teile der originalen Liste hinzu:

Delphi-Quellcode:

for j := 0 to iCnt - 1 do
 aTmpFileList_Record.Add(aProcessFileList_Record.Items[j]);

Mein Problem ist jetzt, dass irgendetwas nicht funktioniert und ich schätze mal es liegt an dieser zweiten Liste.
Die zweite Liste hat die korrekte Länge (Count) an Datensätzen aber beim eigentlichen Prozess, wo die Liste benötigt wird, gehts nicht weiter (keine AV, nichts).

Mache ich etwas falsch beim hinzufügen in die aTmpFileList ?

[Mavarik]

Zitat von dGeek:

Ich erzeuge mit New() die Datensätze (Records) füge sie der TList mit Add() hinzu.

Den Record oder den Pointer? Ich hoffe mal den Pointer...

Klar kann man noch mit New & Dispose arbeiten.. Aber warum nimmst Du keine Klasse und eine ObjectList mit OwnsValue und schon brauchst Du Dich um nix mehr kümmern...

Mavarik

[dGeek]

Kannst du mir weiteres dazu erklären?
Das kenne ich noch nicht.

[DeddyH]

Delphi-Quellcode:

type
  TFileEntry = class
  private
    FFileName: String;
    FDataType: TDataType;
  public
    property FileName: string read FFileName write FFileName;
    property DataType: TDataType read FDataType write FDataType;
  end;

Jetzt kannst Du beliebig viele Instanzen dieser Klasse erzeugen und einer TObjectList hinzufügen. Wenn deren Eigenschaft OwnsObjects true ist (Standard), musst Du die Objekte nicht einmal mehr selbst freigeben, dann kümmert sich die TObjectList selbst darum.

[dGeek]

Wie erzeuge ich denn Instanzen einer Klasse? Dumme Frage

Bin jetzt so weit:

Delphi-Quellcode:

type
 TDataType = (dtFile, dtDirectory);

type
 PFileEntry = ^TFileEntry;

 TFileEntry = class(TObject) // <= Object
  sFileName: String;
  aDataType: TDataType;
 end;

type
 TMyClass = class(TComponent)
 public
  FFileEntry: TObjectList;
  constructor Create; overload;
 end;

var
 aProcessFileList_ObjectList: TFileEntry;

implementation

procedure TMyClass.Create; // hier geht es nicht weiter
begin
 FFileEntry := TObjectList.Create;
 FFileEntry.OwnsObjects := true;
end;

[DeddyH]

Mal ein Beispiel im Editor heruntergetippt:

Delphi-Quellcode:

type
  TFileEntry = class
  private
    FFileName: String;
    FDataType: TDataType;
  public
    property FileName: string read FFileName write FFileName;
    property DataType: TDataType read FDataType write FDataType;
  end;
  
...

procedure TDeinForm.ButtonTestClick(Sender: TObject);
var
  Objects: TObjectList;
  FileEntry: TFileEntry;
  i: integer;
begin
  Objects := TObjectList.Create;
  try
    FileEntry := TFileEntry.Create;
    FileEntry.Filename := 'C:\Dings\Bums\Trallalla.txt';
    FileEntry.DataType := dtFile;
    Objects.Add(FileEntry);
    FileEntry := TFileEntry.Create;
    FileEntry.Filename := 'C:\Dings\Bums';
    FileEntry.DataType := dtDirectory;
    Objects.Add(FileEntry);
    for i := 0 to Objects.Count - 1 do
      ShowMessage((Objects[i] as TFileEntry).Filename);
  finally
    Objects.Free;
  end;
end;