AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein GUI-Design mit VCL / FireMonkey / Common Controls Delphi TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

Ein Thema von TUX_der_Pinguin · begonnen am 4. Apr 2017 · letzter Beitrag vom 6. Apr 2017
Antwort Antwort
Seite 2 von 5     12 34     Letzte » 
madas

Registriert seit: 9. Aug 2007
207 Beiträge
 
#11

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 11:56
Dann mache die Berechnung doch selber.
Wir machen das bei uns so (ist ein Frame mit einem VST drauf, der Tree als Name hat):

Delphi-Quellcode:
function TFrameVST.GetMaxHeaderWidth(const Column: TColumnIndex): Integer;
var
  col: TVirtualTreeColumn;
  Size: TSize;
begin
  col := Tree.Header.Columns[Column];
  Result := 2 * col.Margin;
  if (Length(col.Text) > 0) then
  begin
    Tree.Canvas.Font := Tree.Header.Font;
    GetTextExtentPoint32W(Tree.Canvas.Handle, PWideChar(col.Text), Length(col.Text), Size);
    Inc(Result, Size.cx + 4);
  end;
  if (hoShowImages in Tree.Header.Options)and(Assigned(Tree.Header.Images)) then
    Inc(Result,(Tree.Header.Images.Width + col.Spacing));
  if (hoShowSortGlyphs in Tree.Header.Options)and(Tree.Header.SortColumn = Column) then
  begin
    Inc(Result, 20); // Platz für Sortimage
    if (col.CaptionAlignment = taCenter) then
      Inc(Result, 14); // mehr Platz für Sortimage berücksichtigen
  end;
  if Result < col.MinWidth then
    Result := col.MinWidth;
  if Result > col.MaxWidth then
    Result := col.MaxWidth;
end;

procedure TFrameVST.AutoFitColumn(Column: TColumnIndex);
var
  cWidth, hWidth: Integer;
begin
  if [coResizable, coVisible] * Tree.Header.Columns[Column].Options = [coResizable, coVisible] then
  begin
    if (hoVisible in Tree.Header.Options) then
    begin
      hWidth := GetMaxHeaderWidth(Column);
      cWidth := Tree.GetMaxColumnWidth(Column);
      if cWidth < hWidth then
        cWidth := hWidth;
      if cWidth > Tree.Header.Columns[Column].MaxWidth then
        cWidth := Tree.Header.Columns[Column].MaxWidth;
      Tree.Header.Columns[Column].Width := cWidth;
    end;
  end;
end;

procedure TFrameVST.AutoFitColumns;
var
  Column: TColumnIndex;
  merkCursor: TCursor;
begin
  merkCursor := Screen.Cursor;
  Tree.BeginUpdate;
  try
    Screen.Cursor := crHourGlass;
    for Column := 0 to Tree.Header.Columns.Count-1 do
      AutoFitColumn(Column);
  finally
    Screen.Cursor := merkCursor;
    Tree.EndUpdate;
  end;
end;

FmerkOnBeforeCellPaint: TVTBeforeCellPaintEvent;

procedure TFrameVST.TreeBeforeGetMaxColumnWidth(Sender: TVTHeader; Column: TColumnIndex; var UseSmartColumnWidth: Boolean);
begin
  if Assigned(Tree.OnBeforeCellPaint) then
  begin
    FmerkOnBeforeCellPaint := Tree.OnBeforeCellPaint;
    Tree.OnBeforeCellPaint := nil;
  end;
end;

procedure TFrameVST.TreeAfterGetMaxColumnWidth(Sender: TVTHeader; Column: TColumnIndex; var MaxWidth: Integer);
begin
  if Assigned(FmerkOnBeforeCellPaint) then
  begin
    Tree.OnBeforeCellPaint := FmerkOnBeforeCellPaint;
    FmerkOnBeforeCellPaint := nil;
  end;
end;
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#12

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 11:57
Am Rande bemerkt: Du könntest das auch ein bisschen abkürzen, weil GetNodeData Failsafe ist:

Delphi-Quellcode:
  Node := vstTable.FocusedNode;
  Data := vstTable.GetNodeData(Node);
  if Assigned(Data) then
  begin
    Data.Name := 'skljglsjfgskjfsldjfksjlfkjsd'; //neuer Text ist länger als alle anderen
    Data.Type := 'dfkgjdkjgfklgjdkjgkljgkdjkkgdljgkdjgdgfdgld'; //neuer Text ist länger als alle anderen
  end;
Davon abgesehen, du hast nicht zufällig Header.AutoSizeIndex auf 0 stehen?
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden
  Mit Zitat antworten Zitat
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#13

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:03
Dann mache die Berechnung doch selber.
Wir machen das bei uns so (ist ein Frame mit einem VST drauf, der Tree als Name hat):

Delphi-Quellcode:
procedure TFrameVST.AutoFitColumn(Column: TColumnIndex);
var
  cWidth, hWidth: Integer;
begin
  if [coResizable, coVisible] * Tree.Header.Columns[Column].Options = [coResizable, coVisible] then
  begin
    if (hoVisible in Tree.Header.Options) then
    begin
      hWidth := GetMaxHeaderWidth(Column);
      cWidth := Tree.GetMaxColumnWidth(Column);
      if cWidth < hWidth then
        cWidth := hWidth;
      if cWidth > Tree.Header.Columns[Column].MaxWidth then
        cWidth := Tree.Header.Columns[Column].MaxWidth;
      Tree.Header.Columns[Column].Width := cWidth;
    end;
  end;
end;
Irgendwas scheint bei mir noch anders zu sein, den ihr verwendet ja auch GetMaxColumnWidth , und das führt bei mir ja zu einem Falschen Ergebnis.

Wäre es möglich mir die Optionen und Eigenschaften der Komponente zu zeigen, also das was in der *.dfm Datei steht? Damit ich das mit meinen Eigenschaften vergleichen kann.
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#14

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:05
Nochwas: müssten das nicht dereferenzierte Pointer sein?
Delphi-Quellcode:
  Node := vstTable.FocusedNode;
  Data := vstTable.GetNodeData(Node);
  if Assigned(Data) then
  begin
    Data^.Name := 'skljglsjfgskjfsldjfksjlfkjsd'; //neuer Text ist länger als alle anderen
    Data^.Type := 'dfkgjdkjgfklgjdkjgkljgkdjkkgdljgkdjgdgfdgld'; //neuer Text ist länger als alle anderen
  end;
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden
  Mit Zitat antworten Zitat
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#15

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:06
Am Rande bemerkt: Du könntest das auch ein bisschen abkürzen, weil GetNodeData Failsafe ist:

Delphi-Quellcode:
  Node := vstTable.FocusedNode;
  Data := vstTable.GetNodeData(Node);
  if Assigned(Data) then
  begin
    Data.Name := 'skljglsjfgskjfsldjfksjlfkjsd'; //neuer Text ist länger als alle anderen
    Data.Type := 'dfkgjdkjgfklgjdkjgkljgkdjkkgdljgkdjgdgfdgld'; //neuer Text ist länger als alle anderen
  end;
Davon abgesehen, du hast nicht zufällig Header.AutoSizeIndex auf 0 stehen?
Danke für den Tipp, und nein AutoSizeIndex steht nicht auf 0 es steht auf -1

Nochwas: müssten das nicht dereferenzierte Pointer sein?
Ähm... glaube nicht aber sagen wir mal so es funktioniert ja, zumindest der Zugriff nicht die Spaltenbreite Und selbst mit Data^.Name := ändert sich nichts.

Geändert von TUX_der_Pinguin ( 4. Apr 2017 um 12:10 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#16

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:12
Zeig mal bitte die Deklaration von PDataSet. Mein Verdacht ist, weil ich das beim VST schon mehrfach hatte: Speichersalat wegen wildem Pointergeschubse.

EDIT: Den Kommentar in der Implementierung von GetMaxColumnWidth hast du gesehen?
Delphi-Quellcode:
// This method determines the width of the largest node in the given column.
// If UseSmartColumnWidth is True then only the visible nodes which are in view will be considered
// Note: If UseSmartColumnWidth is False then every visible node in the tree will be initialized contradicting so
// the virtual paradigm.
So wie du das machst bezieht sich die Kalkulation nur auf die im Viewport sichtbaren Nodes. Falls der betreffende Node aber gerade out-of-Scroll ist oder Collapsed, dann wird der nicht einbezogen.
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden

Geändert von Codehunter ( 4. Apr 2017 um 12:21 Uhr)
  Mit Zitat antworten Zitat
TUX_der_Pinguin

Registriert seit: 1. Jun 2005
Ort: Anholt (NRW)
608 Beiträge
 
Delphi 11 Alexandria
 
#17

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:34
Bei PDataset handelt es sich um einen Zeiger auf eine Klasse.
Delphi-Quellcode:
TDataset = class(TObject)
  private
    FName: String;
    FType: String;
  public
    constructor Create;
    destructor Destroy; override;
    property Name: String read FName write FName;
    property Type: String read FType write FType;

  end;
  PDataset = ^TDataset;
Beim befüllen bzw. hinzufügen von Einträgen wird entsprechend das Objekt erstellt
Delphi-Quellcode:
Node := vstTable.AddChild(nil);
if Assigned(Node) then
begin
  Data := vstTable.GetNodeData(Node);
  if Assigned(Data) then
  begin
    //init
    Data^ := TDataset.Create;
      
    Data.Name := 'bla bla';
    Data.Type := 'bla bla';
     
  end;
end;
Die Zelle die ich versuche zu ändern ist nicht nur sichtbar sondern hat auch noch den Focus.
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#18

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:47
Oh je....

Ich ahnte es. Speichersalat.

Ich habe zumindest noch nie gesehen, dass man den VST mit Klasseninstanzen statt Records verwendet. Habe es auch noch nie probiert, weil alle Beispiele und Tutorials die ich so kenne alle auf Records basieren.

Ändere die Deklaration von TDataSet doch bitte mal testweise so um:
Delphi-Quellcode:
TDataset = record
  Name: String;
  Type: String;
end;
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.610 Beiträge
 
Delphi 10.3 Rio
 
#19

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 12:49
Oh je....

Ich ahnte es. Speichersalat.

Ich habe zumindest noch nie gesehen, dass man den VST mit Klasseninstanzen statt Records verwendet. Habe es auch noch nie probiert, weil alle Beispiele und Tutorials die ich so kenne alle auf Records basieren.
Ne nix Speichersalat. Klappt wunderbar. Mache ich auch immer so (seit Jahren) und es hat noch nie Probleme gegeben. Ich speichere mir meine Objekte allerdings immer noch in einer ObjectList<T> und gebe dem NodeObject dann nur noch eine Referenz zur Object-Instanz.

Also daran ist nichts falsch und es ist auch definitiv nicht die Ursache warum das AutoSizing nicht funktioniert.
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#20

AW: TVirtualStringTree AutoFitColumns erste Spalte wird nicht angepasst

  Alt 4. Apr 2017, 13:05
Ne nix Speichersalat. Klappt wunderbar. Mache ich auch immer so (seit Jahren) und es hat noch nie Probleme gegeben. Ich speichere mir meine Objekte allerdings immer noch in einer ObjectList<T> und gebe dem NodeObject dann nur noch eine Referenz zur Object-Instanz.
Naja, ich mache sowas ähnliches:
Delphi-Quellcode:
type
  TNodeData = record
    ObjRef: Pointer;
  end;
Und dann da die Klasseninstanzen angehangen.

Aber so wie hier gemacht, stelle ich mir das seltsam vor. GetNodeData erzeugt erst eine neue Variableninstanz vom Typ Pointer mit der Größe von [was eigentlich? -> OnGetNodeDataSize], dann lässt man den Speichermanager durch TDataSet.Create eine neue Klasseninstanz auf der selben Adresse erzeugen und dann überlässt man das der internen Speicherverwaltung vom VST?

Hmm, ok, ich arbeite immer noch mit der letzten Lischke-Version vom VST. Vielleicht sind neuere dahingehend flexibler. Wie gesagt, ich habe das nie so gemacht.

NACHTRAG:

Um wieder auf das eigentliche Problem zurück zu kommen: GetMaxColumnWidth arbeitet ja intern mit Canvas.TextWidth. Wenn man da jetzt dummerweise nicht den String sondern eine getypcastete Referenz auf den String rein wirft, erhält man recht gern den Effekt, dass TextWidth immer identische Werte ausspuckt. Würde also theoretisch das Problem erklären.
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden

Geändert von Codehunter ( 4. Apr 2017 um 13:09 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 16:45 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz