Datentyp "Int64" fehlerhaft?

[Delphi-Laie]

Erstmal danke für die rege Beteiligung!

Zitat von jaenicke:

Es gibt auch den Datentyp UInt64, der geht von 0 bis 2^64-1 und kennt keine negativen Zahlen.

Yo, ab Delphi 7.

Damit habe ich das Projekt ersatzweise auch ausprobiert. Der Wert rutscht aber auch in's negative. Habe es soeben mit Delphi 3 und Cardinal ausprobiert. Auch Cardinal rutscht in's Negative, beim nächsten shl dann unweigerlich auf 0. Und sogar dann, wenn man statt shl y" ein * 2^y verwendet. Daß so etwas mit vorzeichenlosen Typen möglich ist, ist mir völlig neu. Wieder etwas dazugelernt.

Dann werde ich vermutlich auch kaum Chancen haben, diese negativen Vorzeichen wegzubekommen, oder hat dazu noch jemand eine Idee?

Viele Grüße

Delphi-Laie

[samso]

+9223372036854775808 überschreitet halt den Wertebereich von Int64. Deshalb ist das nicht darstellbar. Was willst Du denn am Ende erreichen?

[Delphi-Laie]

Zitat von samso:

+9223372036854775808 überschreitet halt den Wertebereich von Int64. Deshalb ist das nicht darstellbar. Was willst Du denn am Ende erreichen?

Das ist mir auch gerade klargeworden. Ist 2^63, int64 geht aber nur bis 2^63-1.

Dieser Wert entsteht - und zwar im Visual Studio ohne Vorzeichen - wen die C(++?)-Funktion

Code:

int CLZ(uint64_t x) {
  printf("");
  int n;
  if (x == 0) {
    return 64;
  }
  n = 0;
  if (x <= 0x00000000FFFFFFFFL) 
   {n = n + 32;
   x = x << 32;}
  if (x <= 0x0000FFFFFFFFFFFFL)
   {n = n + 16;
   x = x << 16;}
  if (x <= 0x00FFFFFFFFFFFFFFL)
   {n = n + 8;
   x = x << 8;}
  if (x <= 0x0FFFFFFFFFFFFFFFL)
   {n = n + 4;
   x = x << 4;}
  if (x <= 0x3FFFFFFFFFFFFFFFL)
   {n = n + 2;
   x = x << 2;}
  if (x <= 0x7FFFFFFFFFFFFFFFL)
   {n = n + 1;}
  return n;
}

mit 2048 aufgerufen wird. Sie entstammt diesem Projekt und wird zur Berechnung der optimalen Länge von zu verschmelzenden Teilarrays benötigt. Die wollte ich mit Delphi nachbilden. Bis 2047 ist auch in Delphi alles in Ordnung, ab 2048 aber nicht mehr, weil dieser zitierte Wert negativ wird und das Minuszeichen nicht beseitigt werden kann, und zwar auch nicht mit dem Datentyp UInt64 (in Delphi 7). Ich werde weiter forschen.

Gruß

Delphi-Laie

[jaenicke]

Zitat von Delphi-Laie:

weil dieser zitierte Wert negativ wird und das Minuszeichen nicht beseitigt werden kann, und zwar auch nicht mit dem Datentyp UInt64 (in Delphi 7)

Da hast du denke ich nicht im Debugger nachgeschaut. Wenn du einen UInt64 Wert an IntToStr fütterst, bekommst du in der Tat negative Werte, da der Wert in Int64 konvertiert wird. Wenn du aber UIntToStr benutzt, funktioniert es. Und im Debugger sehen die Werte auch richtig aus...

Zitat von samso:

Was hältst Du von dieser Idee?

Warum nicht wie in der Vorlage?

Delphi-Quellcode:

function CLZ(var x: UInt64): Integer;
begin
  if x = 0 then
    Result := 64
  else
  begin
    Result := 0;
    if x <= $00000000FFFFFFFF then
    begin
      Result := Result + 32;
      x := x shl 32;
    end;
    if x <= $0000FFFFFFFFFFFF then
    begin
      Result := Result + 16;
      x := x shl 16;
    end;
    if x <= $00FFFFFFFFFFFFFF then
    begin
      Result := Result + 8;
      x := x shl 8;
    end;
    if x <= $0FFFFFFFFFFFFFFF then
    begin
      Result := Result + 4;
      x := x shl 4;
    end;
    if x <= $3FFFFFFFFFFFFFFF then
    begin
      Result := Result + 2;
      x := x shl 2;
    end;
    if x <= $7FFFFFFFFFFFFFFF then
    begin
      Result := Result + 1;
    end;
  end;
end;

[samso]

Zitat von jaenicke:

Warum nicht wie in der Vorlage?

Delphi-Quellcode:

function CLZ(var x: UInt64): Integer;
begin
  if x = 0 then
    Result := 64
  else
  begin
    Result := 0;
    if x <= $00000000FFFFFFFF then
    begin
      Result := Result + 32;
      x := x shl 32;
    end;
    if x <= $0000FFFFFFFFFFFF then
    begin
      Result := Result + 16;
      x := x shl 16;
    end;
    if x <= $00FFFFFFFFFFFFFF then
    begin
      Result := Result + 8;
      x := x shl 8;
    end;
    if x <= $0FFFFFFFFFFFFFFF then
    begin
      Result := Result + 4;
      x := x shl 4;
    end;
    if x <= $3FFFFFFFFFFFFFFF then
    begin
      Result := Result + 2;
      x := x shl 2;
    end;
    if x <= $7FFFFFFFFFFFFFFF then
    begin
      Result := Result + 1;
    end;
  end;
end;

Weil das halt mangels UInt64 nicht mit Delphi 4,5,6 zusammen spielt? Deshalb kann auch kein UIntToStr benutzt werden, weil es das damals auch nicht gab...

[samso]

Was hältst Du von dieser Idee?

Delphi-Quellcode:

function CLZ(x: Int64): Integer;
var
  n: Integer;
begin
  if (x = 0)
  then
    Result := 64
  else begin
    n := 0;
    if (x and not $00000000FFFFFFFF)=0
    then begin
      n := n + 32;
      x := x shl 32;
    end;
    if (x and not $0000FFFFFFFFFFFF)=0
    then begin
      n := n + 16;
      x := x shl 16;
    end;
    if (x and not $00FFFFFFFFFFFFFF)=0
    then begin
      n := n + 8;
      x := x shl 8;
    end;
    if (x and not $0FFFFFFFFFFFFFFF)=0
    then begin
      n := n + 4;
      x := x shl 4;
    end;
    if (x and not $3FFFFFFFFFFFFFFF)=0
    then begin
      n := n + 2;
      x := x shl 2;
    end;
    if (x and not $7FFFFFFFFFFFFFFF)=0
    then
      n := n + 1;
    Result := n;
  end;
end;

[himitsu]

Zitat:

Delphi 7

Ich weiß leider nicht in welchen Versionen, aber ich glaub es war irgendwo zwischen 2005 und XE4,
da gab es einen Bug im Delphi, wo UInt64 teilweise wie ein Int64 behandelt wurde.

Für 32 Bit-Anwendungen gibt es eine 64 Bit-Emulation, wo der Compiler bei den Integer-Operatoren + - * div mod and or nicht die CPU rechnen lässt, sondern das mit 32 Bit-Operationen in der System.pas erledigt.
Der Bug bestand darin, dass der Compiler bei UInt64 ausversehn die Funktionen für Int64 verwendete.

[Delphi-Laie]

Zitat von samso:

Was hältst Du von dieser Idee?

Sehr viel, denn sie ist die Lösung meines Problemes. Ich hatte die Hoffnung schon aufgegeben. Ich hatte einfach 1:1 von der Vorlage übernommen und die Bedingungen so formuliert:

if x<=$FFFFFFFF then

usw. Dabei stieß ich dann bei Eingabewerten ab 2048 an die 64-Bit-Grenze, die schier unüberwindlich schien.

Jedenfalls sortiert das erste Timsort in diesem Projekt nun auch bei Elementeanzahlen ab 2048 so schnell, wie es sein soll, also auch hinsichtlich der Geschwindigkeit korrekt. Das ist Dein Verdienst, und dafür danke ich Dir sehr!

Danke auch an die anderen, die sich beteiligten! Meine Fehlervermutung hat sich wieder einmal nicht bestätigt. Was ich allerdings immer noch nicht begreife, ist, wieso wiederholte Multiplikationen oder shl-Befehle bei vorzeichenlosen Integertypen zum Ende in negative Werte einmünden (können).

[Zacherl]

Zitat von Delphi-Laie:

Was ich allerdings immer noch nicht begreife, ist, wieso wiederholte Multiplikationen oder shl-Befehle bei vorzeichenlosen Integertypen zum Ende in negative Werte einmünden (können).

Signed/Unsigned ist halt nur eine Darstellungssache. Wenn du mit unsigned int rechnest, aber am Ende das Ergebnis einem signed int zuweist, dann kann es halt passieren, dass das MSB als Vorzeichen (fehl-)interpretiert wird. Unter Umständen wird der Wert sogar noch sign-extended.