Externes Programm ausführen

[Benmik]

EXIF Tool ist auch für mich ein extrem interessantes Programm. Nur der Weg über diese temporären Dateien stört mich enorm.
Geht eigentlich nicht der Weg über eine pipe? Auf Harveys Seite gibt es einen Link zu VB-Beispiel-Code, der das über CreatePipe macht. Siehe vielleicht auch diese Beiträge hier.

PS: Bin ja doof, ich sehe eben, die Umsetzung schlummert schon längst auf meiner Festplatte...

Hier ist die Unit:

Delphi-Quellcode:

unit ExifTool;

interface
uses Classes;

var
  ETout, ETerr: TStringList; //data from ExifTool will be here

function ExecuteET(const ETcmd,WorkDir: string): Boolean;

implementation
uses Windows;

function ExecuteET(const ETcmd,WorkDir: string): Boolean;
const
  szBuffer=255;
var
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
  PWorkDir: PChar;
  SecurityAttr: TSecurityAttributes;
  PipeOutputRead: THandle;
  PipeOutputWrite: THandle;
  PipeErrorsRead: THandle;
  PipeErrorsWrite: THandle;
  Succeed: Boolean;
  Buffer: array [0..szBuffer] of Char;
  BytesRead: DWORD;
  Stream: TMemoryStream;
begin
  //=== Usual steps to initialize data for CreateProcess:
  FillChar(Buffer,SizeOf(Buffer),0);
  FillChar(ProcessInfo, SizeOf(TProcessInformation), 0);
  FillChar(SecurityAttr, SizeOf(TSecurityAttributes), 0);
  SecurityAttr.nLength := SizeOf(SecurityAttr);
  SecurityAttr.bInheritHandle := true;
  SecurityAttr.lpSecurityDescriptor := nil;
  CreatePipe(PipeOutputRead, PipeOutputWrite, @SecurityAttr, 0);
  CreatePipe(PipeErrorsRead, PipeErrorsWrite, @SecurityAttr, 0);
  FillChar(StartupInfo, SizeOf(TStartupInfo), 0);
  StartupInfo.cb:=SizeOf(StartupInfo);
  with StartupInfo do begin
    hStdInput:=0; hStdOutput:=PipeOutputWrite; hStdError:=PipeErrorsWrite;
    wShowWindow:=SW_HIDE;
    dwFlags:=STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
  end;
  if WorkDir='' then PWorkDir:=nil else PWorkDir:=PChar(WorkDir);
  ETout.Clear; ETerr.Clear;

  //=== Here is where ExifTool is called:
  if  CreateProcess(nil, PChar(ETcmd), nil, nil, true,
    CREATE_DEFAULT_ERROR_MODE or CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS,
    nil, PWorkDir, StartupInfo, ProcessInfo)
  then begin      //=ExifTool started successfully:
    result:=true;
    CloseHandle(PipeOutputWrite);
    CloseHandle(PipeErrorsWrite);
  end else begin  //=ExifTool not started (because, i.e. not found):
    result:=false;
    CloseHandle(PipeOutputRead); CloseHandle(PipeOutputWrite);
    CloseHandle(PipeErrorsRead); CloseHandle(PipeErrorsWrite);
  end;

  if result then begin
    //= Get output written by ExifTool(tag names/values):
    Stream:=TMemoryStream.Create;
    try
      repeat
        succeed:=ReadFile(PipeOutputRead,Buffer,szBuffer,BytesRead,nil);
        if not succeed then break;
        Stream.Write(Buffer,BytesRead)
      until (BytesRead=0);
      Stream.Position:=0; ETout.LoadFromStream(Stream);
    finally Stream.Free; end;
    CloseHandle(PipeOutputRead);
    //= Get errors written by ExifTool (if any):
    Stream:=TMemoryStream.Create;
    try
      repeat
        succeed:=ReadFile(PipeErrorsRead,Buffer,szBuffer,BytesRead,nil);
        if not succeed then break;
        Stream.Write(Buffer,BytesRead);
      until (BytesRead=0);
      Stream.Position:=0; ETerr.LoadFromStream(Stream);
    finally Stream.Free; end;
    CloseHandle(PipeErrorsRead);

    WaitForSingleObject(ProcessInfo.hProcess,5000); //=5sec
    CloseHandle(ProcessInfo.hThread); CloseHandle(ProcessInfo.hProcess);
  end;
end;

initialization
begin
  ETout:=TStringList.Create;
  ETerr:=TStringList.Create;
end;

finalization
begin
  ETerr.Free;
  ETout.Free;
end;

end.

Aufruf:

Delphi-Quellcode:

  procedure FühreTestCodeAus;
  var ETool,ETCmd,Datname:string;
  begin
    ETool   := 'C:\EXIFTool\exiftool.exe ';
    ETCmd := ' -k -a -u -g1 -lang de ';
    Datname := '"C:\Temp\Test\01-Testdatei.JPG"';
    ExecuteET(ETool + ETCmd + Datname,'');
  end;

Das Ergebnis ist dann in ETout

[Delphi.Narium]

Handelt es sich bei dem Inhalt der Temp-Datei um die Konsolenausgabe des ExifTools, die per > in 'ne Datei umgeleitet wurde?

Dann mal hier im Forum nach "Process Pipe" suchen. Da müsste was brauchbares zu finden sein, per Pipe bekommt man die Konsolenausgabe des ExifTools dann direkt ins Programm geliefert.

[Benmik]

Zitat von Delphi.Narium:

Handelt es sich bei dem Inhalt der Temp-Datei um die Konsolenausgabe des ExifTools, die per > in 'ne Datei umgeleitet wurde?

Nein, dafür gibt es bei EXIFTools einen eigenen Schalter. Die Erläuterung hierzu hat er ja auch als Datei beigefügt.

[Delphi.Narium]

Ok. Und wenn man den Schalter weglässt, dann erfolgt die Ausgabe auf die Konsole und kann dann (ohne Datei) per Pipe ins Programm übernommen werden.

Er wäre (denk ich) mal 'nen Versuch wert, ob man so die Kommunikation zwischen Programm und ExifTool vereinfachen kann und man muss sich dann nicht darum kümmern, ob man für (nur temporär benötigte) Dateien alle erforderlichen Rechte hat.

[Benmik]

Vielleicht hast du meine Antwort übersehen (#16).

[Delphi.Narium]

Ja, die Änderung von 23:21 Uhr, hab' ich irgendwie nicht mitbekommen, aber genau das meinte ich. Ist wohl schon zu spät

[jaenicke]

In solch einem Fall ist es am einfachsten den Process Monitor zu benutzen, um damit einfach festzustellen was eigentlich mit der temporären Datei schiefgeht. Dort siehst du ganz genau, ob die Datei im falschen Ordner erstellt werden soll oder was sonst das Problem ist.
https://technet.microsoft.com/de-de/...ssmonitor.aspx
Bei Filter setzt du process name is deine.exe, das war es.

[Willie1]

Ich werde alles ausprobieren, ich bin sehr interessiert. Exiftool ist meiner Meinung nach das beste Programm für Metadaten von Bildern, besonders zum Schreiben von Daten z.B des Orientation-Tag, damit das Bild richtig gedreht wird.
Danke, ich melde mich...
Willie.

[Willie1]

Hallo,

ich weiß jetzt, wie Exiftool in der Eingabeaufforderung eine externe Textdatei mit den
Metadaten anlegt.
Es geht so: In der Eingabeauff.:
1. Beispiel exiftool Korfu.jpg >"%temp%"\Bild.txt piped Bild.txt in Temp-Ordner des BS.
2. Beispiel exiftool Korfu.jpg -w! .txt legt Korfu.txt im gleichen Ordner wie das Bild ab.
3. Beispiel exiftool Korfu.jpg -w! %dc:\data\%f.txt legt Korfu.txt im Ordner Data ab,
falls nicht vorhanden, wird er angelegt.
4. Beispiel exiftool Korfu.jpg -w! %d"%temp%"\%f.txt legt Korfu.txt im Temp-Ordner des BS ab.
Hier klappt es.

Ich habe das Brett an der dünnsten Stelle gebohr, benutze ShellExecute mit dem Parameter Korfu.jpg -w! .txt wird Korfu.txt im gleichen Ordner wie das Bild angelegt. Wenn ich einen anderen Pfad wähle, geht es nicht.
Jaenicke, als Amateur bin ich mit ProcessMon überfordert. Die Help.chm funktioniert nicht! Kannst du mir bitte genauer beschreiben, wie ich vorgehen mus. Ich darf nochmal daraufweisen, es hat 5 Jahre lang funktioniert.

Benmik,
es sieht ja so aus, als ob der Umweg über eine externe Datei nicht notwendig ist. Ich hatte Piping in der Eingeauff. erfolgreich getestet aber den Weg über TMemoryStream kenne ich nicht. Es klappt, ich werde ihn in mein Programm einbauen.

Danke und Gruß Willie.