FMX: TBitmap.Assign Methode erscheint mir nicht korrekt

[Sherlock]

Ich habe die ganz dufte CopyFromBitmap Methode entdeckt. Damit hat sich der Spuk für mich erledigt. Ich setze die Größe meines Ziels auf die Größe der Quelle und dann führe ich TBitmap.CopyFromBitmap(Source) aus und fertig. Kein Speicherleck mehr.

Wenn ich dann mal Zeit habe, schaue ich mir vielleicht an, was beim Assign falsch laufen könnte, aber jetzt bin ich glücklich. Danke Himitsu, es hilft häufig einfach nur über ein Problem zu reden.

Sherlock

[Schokohase]

Ein Speicherleck oder Bug ist mir an der Stelle nicht bekannt und es funktioniert so wie es soll.

Weder hier

Delphi-Quellcode:

var
  bmp: TBitmap;
begin
  bmp := TBitmap.CreateFromFile('picture.png');
  try
    Image1.Bitmap := bmp;
  finally
    bmp.Free();
  end;
end;

noch da

Delphi-Quellcode:

var
  bmp: TBitmap;
begin
  bmp := TBitmap.CreateFromFile('picture.png');
  try
    Image1.Bitmap.Assign(bmp);
  finally
    bmp.Free();
  end;
end;

passiert etwas Merkwürdiges.

Interessant wäre zu sehen, was du in deinem Code konkret veranstaltest ...

[himitsu]

Image1.Bitmap := bmp; und Image1.Bitmap.Assign(bmp); ist das Selbe, siehe dem Setter von .Bitmap

[edit] OK, bei Startet nicht, aber glaub mir einfach, dass der Setter intern das Assign aufruft.

[Der schöne Günther]

Vor allem wäre die Plattform interessant (also mit ARC oder ohne).

[Sherlock]

Tja, mein Code reicht durch mehrere Ebenen und in mehrere Listen. Ich war überzeugt, alles wird gut aufgeräumt. Und dadurch, daß ich nicht mehr Assign sondern CopyFromBitmap verwende werden mir auch keine Leaks mehr gemeldet. Eventuell habe ich auch einfach nur den Überblick verloren... Dennoch sehen meine eigenen Assign-Methoden anders aus, als das da. Für mich besteht ein Assign darin, zwei vollständig unabhängige Objekte gleichen Inhalts zu erzeugen...Klonen sozusagen. Und das passiert da IMHO nicht. Und den Inhalt eines Objekts zu setzen, daß in der nächsten Zeile durch ein anderes ersetzt wird, finde ich auch komisch.

Sherlock

[Schokohase]

Du meinst dein Assign sieht ungefähr so aus?

Delphi-Quellcode:

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.Classes,
  System.SysUtils;

type
  TMyClass = class( TPersistent )
  private
    FData: string;
  public
    procedure Assign( Source: TPersistent ); override;
  public
    property Data: string read FData write FData;
  end;

procedure TMyClass.Assign( Source: TPersistent );
begin
  if ( Source is TMyClass ) then
  begin
    FData := TMyClass( Source ).FData;
  end
  else
    inherited;
end;

var
  a, b: TMyClass;

begin
  try
    a := nil;
    b := nil;
    try
      a := TMyClass.Create();
      b := TMyClass.Create();

      a.Data := 'Foo';
      b.Assign(a);
      WriteLn(b.Data);

    finally
      a.Free;
      b.Free;
    end;
  except
    on E: Exception do
      Writeln( E.ClassName, ': ', E.Message );
  end;
end.

[Sherlock]

Ja, ungefähr. Wenn "komplexe" Classmember vorhanden sind, werden die dann über deren Assign geklont.

Sherlock

[Schokohase]

Ja, dachte ich mir ... darum habe ich extra ein string gewählt, denn dort wird beim Zuweisen nicht der Inhalt kopiert, sondern nur die Referenz (mit Erhöhung des Referenz-Zählers).

Es passiert dort also hinter den Kulissen exakt das Gleiche, was bei TBitmap mit dem Wert in FImage passiert (nur eben explizit).

Der tiefere Sinn dahinter: Ein und dasselbe Bild braucht nur einmal im Speicher liegen auch wenn man es an n Stellen anzeigen möchte.

Delphi-Quellcode:

var
  bitmaps: TObjectList<TBitmap>;
  b, bmp: TBitmap;
begin
  ...
  // Variante 1 - langsam, viel Spiecher verbraten
  for i := 1 to 100 do
  begin
    bitmaps.Add( TBitmap.CreateFromFile( 'test.png' ) );
  end;

  // Variante 2 - langsamer, viel Speicher verbraten
  bmp := TBitmap.CreateFromFile( 'test.png' );
  try
    for i := 1 to 100 do
    begin
      b := TBitmap.Create();
      b.SetSize( bmp.Size );
      b.CopyFromBitmap( bmp );
      bitmaps.Add( b );
    end;
  finally
    bmp.Free();
  end;

  // Variante 3 - sehr schnell, sehr wenig Speicher
  bmp := TBitmap.CreateFromFile( 'test.png' );
  try
    for i := 1 to 100 do
    begin
      b := TBitmap.Create();
      b.Assign( bmp );
      bitmaps.Add( b );
    end;
  finally
    bmp.Free();
  end;  
  ...
end;

Keine dieser Varianten erzeugt allerdings ein Speicherleck und die Assign -Methode von TBitmap ist völlig korrekt, auch wenn diese noch so ungewöhnlich aussieht.