AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Delphi Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

Ein Thema von Axti · begonnen am 13. Jun 2018 · letzter Beitrag vom 19. Jun 2018
Antwort Antwort
Seite 2 von 2     12
Dennis07

Registriert seit: 19. Sep 2011
Ort: Deutschland
479 Beiträge
 
Delphi 11 Alexandria
 
#11

AW: Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

  Alt 15. Jun 2018, 17:32
Delphi-Quellcode:
    for linePath in TempMenuData do
    begin
      if (MenuLevel = 1)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')
        and TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempMenuTop := TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempMenuTop := tempMenuTop.Replace(' ', EmptyStr);
        tempMenuTop := tempMenuTop.Replace('object', EmptyStr);
        tempMenuTop := tempMenuTop.Replace(':TMenuItem', EmptyStr);

        MenuLevel := 2;
      end
      else if (MenuLevel = 2)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')
        and TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempPath := tempMenuTop + '->' + TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempPath := tempPath.Replace(' ', EmptyStr);
        tempPath := tempPath.Replace('object', EmptyStr);
        tempPath := tempPath.Replace(':TMenuItem', EmptyStr);

        if TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1].Contains('Action') then
        begin
          tempMenuAction := TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1];
          tempMenuAction := tempMenuAction.Replace('Action = ', '');
          tempMenuAction := tempMenuAction.Replace(' ', '');
        end;

        MenuLevel := 3;
      end
      else if (MenuLevel = 3)
        and (TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('object')

        and TempMenuData.Strings[TempMenuData.IndexOf(linePath)].Contains('TMenuItem'))
      then
      begin
        tempPath := tempPath + '->' + TempMenuData.Strings[TempMenuData.IndexOf(linePath)];
        tempPath := tempPath.Replace(' ', EmptyStr);
        tempPath := tempPath.Replace('object', EmptyStr);
        tempPath := tempPath.Replace(':TMenuItem', EmptyStr);

        if TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1].Contains('Action') then
        begin
          tempMenuAction := TempMenuData.Strings[TempMenuData.IndexOf(linePath)+1];
          tempMenuAction := tempMenuAction.Replace('Action = ', '');
          tempMenuAction := tempMenuAction.Replace(' ', '');
        end;
      end;

      if not linePath.Contains('end') then
      begin
        for lineNewPath in FinishedTable do
        begin
          if FinishedTable[FinishedTable.IndexOf(lineNewPath)].Contains(tempMenuAction)
           and not FinishedTable[FinishedFile.IndexOf(lineNewPath)].Contains('Path')
          then
          begin
            FinishedTable.Strings[FinishedTable.IndexOf(lineNewPath)]
                := FinishedTable.Strings[FinishedTable.IndexOf(lineNewPath)] +
                   ' Path: ' + tempPath;
            break;
          end;
        end;
      end
      else if linePath.Contains('end') then
      begin
        MenuLevel := MenuLevel-1;
      end;

      if MenuLevel = 0 then
      begin
        tempPath := EmptyStr;
      end;

    end;
So solltest du bei Parsern aber nicht arbeiten. StringReplace ist sehr unsicher, da du den Kontext nicht beachtest. Das kann in einigen Fällen zu unbeabsichtigten Ergebnissen oder sogar Fehlern führen. Wieso benutzt du nicht einfach TParser? Da brauchst du dir um all das keine Gedanken zu machen, und außerdem ist ein andauerndes Aufrufen von StringReplace auch nicht gerade performant.
Dennis
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.014 Beiträge
 
Delphi 12 Athens
 
#12

AW: Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

  Alt 15. Jun 2018, 22:54
Zitat:
Wieso benutzt du nicht einfach TParser?
Weil er nichts fertiges nutzen will, denn sonst würde er direkt TReader verwenden, welches das Format sogar direkt versteht.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Dennis07

Registriert seit: 19. Sep 2011
Ort: Deutschland
479 Beiträge
 
Delphi 11 Alexandria
 
#13

AW: Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

  Alt 15. Jun 2018, 23:10
sonst würde er direkt TReader verwenden, welches das Format sogar direkt versteht.
Das tut TParser doch auch??

Und falls er es nicht verwenden will (wieso auch immer), kann er es sich doch innerhalb von ner halben Stunde einfach nachbauen...?
Dennis
  Mit Zitat antworten Zitat
Dennis07

Registriert seit: 19. Sep 2011
Ort: Deutschland
479 Beiträge
 
Delphi 11 Alexandria
 
#14

AW: Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

  Alt 15. Jun 2018, 23:32
Übrigens hat er nirgendwo geschrieben, dass er nichts fertiges benutzen will (korrigiere mich bitte, falls ich falsch liege, habe aber nichts gefunden, das darauf hindeutet. Und selbst wenn, TParser ist nichts "fertiges", es ist nur ein Baustein, genau wie TStringList. Dennoch kann es dir einiges an Arbeit hier abnehmen. Habe das ganze mal (außer die Menüstruktur, da ich noch nicht genau verstanden habe, wie das mit dem "auslesen" gemeint ist) hingeschrieben. So in etwa ließe sich das mit TParser lösen:

Delphi-Quellcode:
program DfmAnalyzer;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils, System.Classes, System.Generics.Collections, Vcl.Controls;

var
  FileName: String;
  Stream: TFileStream;
  Parser: TParser;
  Current: String;

  FormName: String;
  Actions: TDictionary<TComponentName, TCaption>;

procedure ParseObject(const Depth: Byte = 0; const Item: Boolean = False);

  procedure ParseCollection;
  begin
    Parser.NextToken;
    while Parser.Token <> '>do
    begin
      if Parser.TokenSymbolIs('item') then
      begin
        ParseObject(Succ(Depth), True);
      end;
      Parser.NextToken;
    end;
    Parser.NextToken;
  end;

var
  ComponentName: String;
  ComponentType: String;
begin
  Parser.NextToken;
  if not Item then
  begin
    ComponentName := Parser.TokenString;
    if Depth = 0 then
    begin
      FormName := ComponentName;
    end;
    Parser.NextToken;
    Parser.NextToken;
    ComponentType := Parser.TokenString;
    Parser.NextToken;
  end;
  while not Parser.TokenSymbolIs('end') do
  begin
    if Parser.TokenSymbolIs('object') then
    begin
      ParseObject(Succ(Depth));
    end else
    begin
      if Parser.Token = '<then
      begin
        ParseCollection;
      end else
      begin
        if not Item and (ComponentType = 'TAction') and
          (Parser.TokenSymbolIs('Caption')) then
        begin
          Parser.NextToken;
          Parser.NextToken;
          Actions.Add(ComponentName, Parser.TokenWideString);
        end;
      end;
    end;
    Parser.NextToken;
  end;
end;

begin
  try
    ReadLn(FileName);
    Stream := TFileStream.Create(FileName, fmOpenRead);
    Stream.Seek(0, soBeginning);
    Parser := TParser.Create(Stream, TFormatSettings.Invariant);
    Actions := TDictionary<TComponentName, TCaption>.Create;
    try
      ParseObject;
      WriteLn('Formularname: ', FormName);
      for Current in Actions.Keys do
      begin
        WriteLn('Caption von ', Current, ': ', QuotedStr(Actions[Current]));
      end;
    finally
      Actions.Free;
      Parser.Free;
      Stream.Free;
      ReadLn;
    end;
  except
    on E: Exception do
      WriteLn(E.ClassName, ': ', E.Message);
  end;

end.
Das nur mal, um evtl. einen Denkanstoß zu geben.
Dennis
  Mit Zitat antworten Zitat
Axti

Registriert seit: 13. Jun 2018
5 Beiträge
 
Delphi 10.1 Berlin Professional
 
#15

AW: Externes Programm zum durchsuchen von *.dfm Dateien und Speicherung von Actions

  Alt 19. Jun 2018, 09:34
Hab die Vorschläge jetzt ausprobiert und jetzt funktioniert alles super. Danke
Alexander
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 13:44 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz