Bitmap.Canvas -> Form.Canvas ... nix zu sehen

[TERWI]

Siehe #26.

[KodeZwerg]

Hab mich vertan, tut mir leid für msg.

[jaenicke]

Zitat von TERWI:

Siehe #26.

Dort verstehe ich es so als ob der Thread durchaus mit der Ausgabe und sogar einem VCL-Formular zu tun hat:

Zitat von TERWI:

Auch die OSD-Form (hier hilfweise als extra Form) wird von nichts & niemand anderem als genau diesem Thread aufgerufen. M.E.n kann also auch da kein Konflikt auftreten.

Beides ist aber aus einem Thread heraus verboten.

Ich habe nicht umsonst (mit wenig Resonanz leider) den Beginn einer Multithread-Komponentenbibliothek veröffentlicht, eben weil Threads und VCL nicht zusammen funktionieren:
https://github.com/jaenicke/MTCL

[TERWI]

Zitat von jaenicke:

...Beides ist aber aus einem Thread heraus verboten.

Gut, sei es einfach eben mal so.
Allerdings - siehe #20 - scheint es ja zu funktionieren. Auch Image1.Picture.Assign(BitMap); geht.
X andere Versuche mit Draw, CopyRect, BrushCopy auf (irgendein) Canvas funzen nicht, bzw. nur (sehr ) kurz.

Und:
Das Geflacker scheint offensichtlich eine ganz andere Ursache zu haben -> nämlich in der "Malerei" der Ursprungs-Bitmap, also FBMOSD.

Die Katze mal aus dem Sack gelassen:
Das ganze ist/wird ein DVB-Teletext-Parser, der etwas flotter, universeller mit ein paar extra Features sein soll.
Zur Zt. fliegen da noch etwa bis zu 20 BitMaps/s an die OSD, weil der Decoder noch nicht optimiert ist, bzw. noch Fehler im Detail stecken.
Durch Fehlinterpretation von Steuerzeichen kommt es daher unregelmäßig zu diesen "Flashes", wenn mit clWHite das BitMap gelöscht wird.
Ein Eigentor .....

Nun mal schauen, wie es mit dem schreiben der BM direkt in den Video-Renderer klappt, das richtige OSD also.

Vergessen:
Ich hab testweise den ParserThread rausgenommen, nun läuft alles "straight" aus der OnTSReceive Methode.
Effekt: (Erwartungsgemäß) Genau das gleiche Geflacker wie mit Parser.
Es lieht also nicht am Thread.

[jaenicke]

Das Flackern liegt an der Art zu zeichnen. Wenn du TImage benutzt, wirst du das auch nicht wegbekommen. Das geht wirklich nur indem du im OnPaint selbst zeichnest. Damit lässt sich das weitgehend unter Kontrolle bekommen.

Viel sinnvoller wäre aber eine hardwarebeschleunigte Herangehensweise. Dann ist das ganze nicht so CPU lastig und flackert auch nicht. Delphi 2009 bietet da allerdings leider noch nichts direkt, da brauchst du externe Bibliotheken.

[Neutral General]

Mal ganz egal woran es liegt oder auch nicht.

Ich fasse zusammen: Greif in einem Thread NICHT auf die VCL zu
Und generell auch nicht ohne weiteres auf Objekte die außerhalb des Threads benutzt werden

Die Sache ist die: Je nachdem KANN es gut gehen. Vielleicht geht es dann 99 von 100 mal gut.
Und das 100. Mal bricht alles zusammen und du weißt nicht woher das auf einmal kam.

Wollte das nur noch mal klar machen weil ich das Gefühl habe dass du glaubst dass wir dich nur aus Spaß oder Prinzip warnen "weil man das nicht" macht.
Es ist aber tatsächlich ein richtiger Fehler mit dem du dir früher oder später ins Knie schießen wirst.

[jaenicke]

Dazu gibt es auch gerade einen aktuellen Blogeintrag.
https://wiert.me/2018/07/11/dont-acc...-to-demo-that/
Dort wird auch ein Beispiel gezeigt, das dem Thema hier sehr ähnlich ist:

Zitat:

Found a simple one.

Create a new VCL program. Drop a TImage on the form. Insert this code:

Delphi-Quellcode:

procedure TForm47.FormCreate(Sender: TObject);
begin
  TThread.CreateAnonymousThread(
  procedure
  begin
    PaintToImage(Image1);
  end).Start;
end;

procedure TForm47.PaintToImage(image: TImage);
begin
  while true do begin
    Image1.Picture.Bitmap := TBitmap.Create;
    Image1.Picture.Bitmap.Free;
  end;
end;

Run in debugger. Instant access violation in the WMPaint handler of the main thread.

[TERWI]

Nach vielem & langen suchen & lesen bin ich ein klein wenig schlauer geworden - so wirklich verstanden hab ich das allerdings immer noch nicht, wieso genau das nicht funktioniert...

Nach dem Beispiel von Sir Rufo u. a. in "Threads und TBitmaps" scheint es ja mit BitMap.Assign zu funktionieren (wenn man weiteres beachtet).

Mein Versuch nun, die Bitmap mittels IVMRMixerBitmap9 in den VMR9-Renderer zu schieben, ging wie erwartet in die Hose. Wie beim normalen Canvas: Man sieht kurz was, danach nicht mehr.

Mittlerweile qualmt die Birne und ich sehe die Bits vor lauter Maps nicht mehr. Ich bin doch sicher nicht der erste auf diesem Planeten, der so etwas versucht.
Gibt's da nicht irgendeine andere Möglichkeit/Krücke, das zu lösen ? Mittels DIB o. ä. ?

[jaenicke]

Zitat von TERWI:

Gibt's da nicht irgendeine andere Möglichkeit/Krücke, das zu lösen ? Mittels DIB o. ä. ?

Ich habe doch schon eine einfache Möglichkeit genannt... nimm einfach das Handle statt die ganze Bitmap durch verschiedene Threads zu reichen. Hier eine schnell hingeworfene Demo, nicht schön geschrieben, aber sie zeigt, dass es so geht...

Delphi-Quellcode:

type
  TTestThread = class(TThread)
  protected
    procedure Execute; override;
  end;

  TfrmThreadDemo = class(TForm)
    procedure FormDestroy(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormPaint(Sender: TObject);
  private
    FTestThread: TTestThread;
    FExampleBitmap: TBitmap;
  end;

var
  frmThreadDemo: TfrmThreadDemo;

implementation

{$R *.dfm}

{ TTestThread }

procedure TTestThread.Execute;
var
  NewBitmap: TBitmap;
begin
  while not Terminated do
  begin
    NewBitmap := TBitmap.Create;
    try
      NewBitmap.SetSize(200, 200);
      NewBitmap.Canvas.MoveTo(Random(200), Random(200));
      NewBitmap.Canvas.LineTo(Random(200), Random(200));
      System.TMonitor.Enter(frmThreadDemo.FExampleBitmap);
      try
        frmThreadDemo.FExampleBitmap.ReleaseHandle;
        frmThreadDemo.FExampleBitmap.Handle := NewBitmap.ReleaseHandle;
      finally
        System.TMonitor.Exit(frmThreadDemo.FExampleBitmap);
      end;
      TThread.Synchronize(nil, procedure
        begin
          frmThreadDemo.Invalidate;
        end);
    finally
      NewBitmap.Free;
    end;
    Sleep(10);
  end;
end;

procedure TfrmThreadDemo.FormDestroy(Sender: TObject);
begin
  FTestThread.Free;
  FExampleBitmap.Free;
end;

procedure TfrmThreadDemo.FormCreate(Sender: TObject);
begin
  FExampleBitmap := TBitmap.Create;
  FTestThread := TTestThread.Create;
end;

procedure TfrmThreadDemo.FormPaint(Sender: TObject);
begin
  System.TMonitor.Enter(frmThreadDemo.FExampleBitmap);
  try
    Canvas.Draw(0, 0, FExampleBitmap);
  finally
    System.TMonitor.Exit(frmThreadDemo.FExampleBitmap);
  end;
end;

Das komplette Projekt liegt auch im Anhang.