AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Cross-Platform-Entwicklung Heruntergeladenes APK starten in Android

Heruntergeladenes APK starten in Android

Ein Thema von skoschke · begonnen am 7. Dez 2018 · letzter Beitrag vom 6. Sep 2021
Antwort Antwort
skoschke

Registriert seit: 6. Jan 2009
522 Beiträge
 
Delphi 10.4 Sydney
 
#1

Heruntergeladenes APK starten in Android

  Alt 7. Dez 2018, 07:52
Hallo,

die Versionsabfrage sowie der FTP-Download eines APK funktioniert, nun stehe ich vor dem nächsten Schritt:

Wie muss der Intent aussehen, dieses APK aus meiner App heraus zu installieren?

Geht das überhaupt, die eigene App aus der App heraus zu updaten?
Wenn nein, wie könnte man vorgehen?

Danke
Ciao
Stefan
  Mit Zitat antworten Zitat
Rollo62

Registriert seit: 15. Mär 2007
3.882 Beiträge
 
Delphi 12 Athens
 
#2

AW: Heruntergeladenes APK starten in Android

  Alt 7. Dez 2018, 08:52
Ich habe gute Erfahrungen mit TotalCommander (Android) gemacht.
Der hat, wenn man auf die APK hält, ein Contect-Menü was "Öffnen mit" oder so ähnlich zeigt.

Darin ist der Android-PackageManager gelistet.

Aus irgendwelchen Gründen kann ich bei mir auch nicht immer Packages per FTP oder Downloads installieren, da wird anscheinend nicht immer der richtige PackageManager geöffnet.
Mal gehts, mal gehts nicht mit Android Bordmitteln.

Genau in solchen Fällen hatte TC gut geholfen.

Rollo
  Mit Zitat antworten Zitat
skoschke

Registriert seit: 6. Jan 2009
522 Beiträge
 
Delphi 10.4 Sydney
 
#3

AW: Heruntergeladenes APK starten in Android

  Alt 7. Dez 2018, 09:52
Danke,

aber ich möchte direkt aus der App das APK installieren, der Anwender soll nicht erst irgendeinen Dateimanager starten (oder gar erst installieren müssen) und dann manuell starten!

Ciao
Stefan
  Mit Zitat antworten Zitat
Schokohase
(Gast)

n/a Beiträge
 
#4

AW: Heruntergeladenes APK starten in Android

  Alt 7. Dez 2018, 09:55
10 Sekunden google mit Bei Google suchenstart apk from application führt zu Stackoverflow: Install Application programmatically on Android und ein Delphi Beispiel mit dem Intent im Allgemeinen findet man in der Dokumentation (FMX.Android Intents Sample - SendIntent)

Geändert von Schokohase ( 7. Dez 2018 um 09:59 Uhr)
  Mit Zitat antworten Zitat
sevo

Registriert seit: 7. Dez 2018
1 Beiträge
 
#5

AW: Heruntergeladenes APK starten in Android

  Alt 7. Dez 2018, 10:10
Hi,

ich habe das so umgesetzt:

1. Download des APK, das sollte asynchron / im Hintergrund geschehen, da sonst die App nicht mehr reagiert.
Delphi-Quellcode:
HttpClient := THTTPClient.Create;
try
  DestFile := TFileStream.Create('/sdcard/Download/' + DestFileName, fmCreate);
  HttpClient.Get(UpdateFile.DownloadURL, DestFile);
finally
  DestFile.Free;
end;
2. "Aufruf" des heruntergeladenen APK mittels Intent. FÜhrt dazu, dass der Benutzer das APK installieren und neu starten kann, oder abbrechen.
Diesen Aufruf führe ich im Synchronized/Mainthread aus.
Quelle: http://www.fmxexpress.com/build-your...ey-on-android/
Delphi-Quellcode:
aFile := TJFile.JavaClass.init(StringToJString('/sdcard/Download'), StringToJString(DestFileName));
Intent := TJIntent.Create;
Intent.setAction(TJintent.JavaClass.ACTION_VIEW);
Intent.addFlags(TJIntent.JavaClass.FLAG_ACTIVITY_NEW_TASK);
Intent.setDataAndType(TJnet_Uri.Javaclass.fromFile(aFile), //Androidapi.JNI.Net.pas
                      StringToJString('application/vnd.android.package-archive'));
SharedActivityContext.startActivity(Intent);
Für asynchrone Funktionen die ein synchrone (bei z.B. Aktualisierung der GUI) Aktion triggern habe ich eine kleine Hilfsfunktion geschrieben:
Die Fkt. ShowActivity und HideActivity öffnen und schließen hier eine Form, die einen Ladebalken (Kreis) anzeigt und die Eingaben des Benutzer ignoriert (HardwareBack-Key).
Delphi-Quellcode:
procedure CallAsync(AsyncProc : TThreadProcedure; SyncProcCalledAfterAsync : TThreadProcedure);
begin
  if (Assigned(AsyncProc)) then begin
    ShowActivity;
    TThread.CreateAnonymousThread(
      procedure ()
      begin
        try
          AsyncProc;
        finally
          TThread.Synchronize(nil,
            procedure
            begin
              HideActivity;
              if (Assigned(SyncProcCalledAfterAsync)) then begin
                SyncProcCalledAfterAsync;
              end;
            end);
        end;
      end).Start;
  end;
end;
Gruß

sevo
  Mit Zitat antworten Zitat
skoschke

Registriert seit: 6. Jan 2009
522 Beiträge
 
Delphi 10.4 Sydney
 
#6

AW: Heruntergeladenes APK starten in Android

  Alt 7. Dez 2018, 13:38
Hallo sevo,

prima, vielen Dank, genau das habe ich gesucht!

Ciao
Stefan
  Mit Zitat antworten Zitat
skoschke

Registriert seit: 6. Jan 2009
522 Beiträge
 
Delphi 10.4 Sydney
 
#7

AW: Heruntergeladenes APK starten in Android

  Alt 6. Sep 2021, 08:57
Hallo,

ich hole das Ganze noch mal hoch, da ich mit Android >= 8 und 2 Apps Probleme habe:

In beiden Apps wird ein Update-APK geladen und per Intent gestartet.
Bei einer App funktioniert es, bei der anderen startet das Update APK nicht, es gibt auch keinerlei Fehlermeldungen.
Das APK kann über eigene Dateien manuell problemlos gestartet werden.
Beide Apps verwenden den gleichen Code:
Delphi-Quellcode:
procedure StartUpdate;
var
  Intent: JIntent;
  filename: string;
  fileext: string;
  dsc: string;
  Authority: JString;
  LUri: Jnet_Uri;
  aFile: JFile;
begin
  dsc := TPath.DirectorySeparatorChar;
  filename := DownloadDir + FilenameAPK;
  fileext := ExtractFileExt(filename);
  fileext := uppercase(stringreplace(fileext, '.', '', []));
  if not fileexists(filename) then
  begin
    showmessage(filename + ' nicht gefunden !');
    exit;
  end;
  if TOSVersion.Check(8) then
  begin
    try
      // wichtig ab Android 8 Zugriffsrechte!
      Authority := StringToJString
        (JStringToString(TAndroidHelper.Context.getApplicationContext.
        getPackageName) + '.fileprovider');
      aFile := TJFile.JavaClass.init(StringToJString(DownloadDir),
        StringToJString(FilenameAPK));
      LUri := TJFileProvider.JavaClass.getUriForFile(TAndroidHelper.Context,
        Authority, TJFile.JavaClass.init(StringToJString(filename)));
      Intent := TJIntent.Create;
      Intent.setAction(TJIntent.JavaClass.ACTION_VIEW);
      // Intent := TJIntent.JavaClass.init(TJIntent.JavaClass.ACTION_VIEW);
      Intent.setFlags(TJIntent.JavaClass.FLAG_ACTIVITY_NEW_TASK);
      Intent.addFlags(TJIntent.JavaClass.FLAG_GRANT_READ_URI_PERMISSION);
      Intent.setDataAndType(LUri,
        StringToJString('application/vnd.android.package-archive'));
      TAndroidHelper.Activity.startActivity(Intent);
    except
      showmessage('Fehler');
    end;
  end
.....
Wo kann ich ansetzen zum Suchen, warum es im einen Programm geht, im anderen nicht?
Die Permissions sind auch in beiden identisch.

Ciao
Stefan
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 14:24 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz