AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

DunitX Testcase parameter

Ein Thema von Klaus01 · begonnen am 14. Feb 2020 · letzter Beitrag vom 17. Feb 2020
Antwort Antwort
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.370 Beiträge
 
Delphi XE7 Professional
 
#1

DunitX Testcase parameter

  Alt 14. Feb 2020, 13:12
Hallo,

sind in Delphi die DUnitX Testcase Parameter auf Strings begrenzt?
Kann ich über die Parameter keine Object-Instanzen übergeben?

Mir würde sowas vorschweben:
Delphi-Quellcode:
    [Test]
    [Testcase('with nil parameter','nil')]
    [Testcase('with correct parameter','TUserGroupData.Create("tester")')]
    procedure addUserGroup(item: TBasicElement);
Die Tests laufen erfogreich durch - in beiden Fällen ist aber "item" nil.

Grüße
Klaus
Klaus
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
3.669 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#2

AW: DunitX Testcase parameter

  Alt 14. Feb 2020, 13:26
Was erwartest du? Dass der Text genommen und zu Code kompiliert wird?

sind in Delphi die DUnitX Testcase Parameter auf Strings begrenzt?
Nicht nur auf Strings, aber auf alles, was const sein kann - das schließt Objekte aus.
Allerdings kannst du Testdaten auch anderes erzeugen, dazu musst du dir das TestCaseProviderAttribute anschauen - bestimmt gibts im DUnitX Verzeichnis oder in den Tests ein Beispiel wie das einzusetzen ist.
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight

Geändert von Stevie (14. Feb 2020 um 13:29 Uhr)
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.370 Beiträge
 
Delphi XE7 Professional
 
#3

AW: DunitX Testcase parameter

  Alt 14. Feb 2020, 13:33
.. nein nicht direkt.

Wenn ich aber eine Instanz übergeben
Delphi-Quellcode:
    [Test]
    [Testcase('with nil parameter','nil')]
    [Testcase('with correct parameter',TUserGroupData.Create('tester'))]
    procedure addUserGroup(item: TBasicElement);
Dann kompiliert das ganze nicht:
[dcc32 Error] TestUserGroupList.pas(17): E2250 There is no overloaded version of 'Create' that can be called with these arguments

Integer werden auch als String übergeben und dann anscheinend konvertiert.
Beispiel: https://www.howtobuildsoftware.com/i...case-in-dunitx

Grüße
Klaus
Klaus
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.370 Beiträge
 
Delphi XE7 Professional
 
#4

AW: DunitX Testcase parameter

  Alt 14. Feb 2020, 13:33
Allerdings kannst du Testdaten auch anderes erzeugen, dazu musst du dir das TestCaseProviderAttribute anschauen - bestimmt gibts im DUnitX Verzeichnis oder in den Tests ein Beispiel wie das einzusetzen ist.
Danke werde ich machen.
Klaus
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.370 Beiträge
 
Delphi XE7 Professional
 
#5

AW: DunitX Testcase parameter

  Alt 17. Feb 2020, 07:37
folgende Units müssen eingebunden werden
(TestInsight ist nicht zwingend nötig)
Delphi-Quellcode:
uses
  System.Generics.Collections,
  DUnitX.InternalDataProvider,
  DUnitX.TestDataProvider,
  DUnitX.Types,
  DUnitX.TestFramework,
  TestInsight.DUnitX,
  ...
Die Erstellung der Ableitung von TTestDataProvider.

Delphi-Quellcode:
type
  TTestData = record
    userGroupData: TBasicElement;
    expectedListCount: Integer;
  end;

  TUserGroupDataAttributeProvider = class(TTestDataProvider)
    private
      fList : TList<TTestData>;
      procedure initTestData;
    public
      constructor Create; override;
      function GetCaseCount(const Methodname:string):integer; override;
      function GetCaseName(const Methodname:string):String; override;
      function GetCaseParams(const Methodname:string;const casenr:integer):TValuearray; override;
      Destructor Destroy;override;
  end;

  [TestFixture]
  TestTUserGroupList = class(TObject)
  public
    [Test]
    procedure CreateUserGroupList;
    [Test]
    [TestCaseProvider('UserGroupDataAttributeProvider')]
    procedure addUserGroup(item: TBasicElement; expected: Integer);
  end;

Delphi-Quellcode:
constructor TUserGroupDataAttributeProvider.create();
begin
  inherited;
  fList := TList<TTestData>.Create();
  initTestData;
end;

destructor TUserGroupDataAttributeProvider.Destroy;
begin
  fList.Free;
  inherited;
end;

function TUserGroupDataAttributeProvider.GetCaseCount(const Methodname: string): integer;
begin
  result := fList.Count;
end;

function TUserGroupDataAttributeProvider.GetCaseName(const Methodname: string): String;
begin
  result := '';
  if Methodname = 'addUserGroupthen
    result := 'TestAddUserGroup';
end;

function TUserGroupDataAttributeProvider.GetCaseParams(const Methodname: string;
  const casenr: integer): TValuearray;
begin
  SetLength(result,0);
  if (Casenr >=0) and (Casenr < flist.count) then
  begin
    SetLength(result,2);
    result[0] := fList[CaseNr].userGroupData;
    result[1] := fList[CaseNr].expectedListCount;
  end;
end;

// TestDaten
procedure TUserGroupDataAttributeProvider.initTestData;
var
  item: TTestData;
begin
  item.userGroupData := nil;
  item.expectedListCount := 0;
  fList.Add(item);
  item.userGroupData := TUserGroupData.create();
  item.expectedListCount := 0;
  fList.Add(item);
  item.userGroupData := TUserGroupData.create('tester');
  item.expectedListCount := 1;
  fList.Add(item);
end;
Delphi-Quellcode:
initialization
  TestDataProviderManager.RegisterProvider('UserGroupDataAttributeProvider',TUserGroupDataAttributeProvider);
  TDUnitX.RegisterTestFixture(TestTUserGroupList);
end.
Der Testcase sieht dann "ganz normal" aus.
Delphi-Quellcode:
procedure TestTUserGroupList.addUserGroup(item: TBasicElement; expected: Integer);
var
  userGroupList: TUserGroupList;
  itemCount: Integer;
begin
  userGroupList := TUserGroupList.Create();
  try
    try
      itemCount := userGroupList.Count;
      userGroupList.addNew(item);
      assert.AreEqual(expected, userGroupList.count - itemCount,'ok');
    except
      on e:Exception do
        assert.Fail(e.Message);
    end;
  finally
    userGroupList.Free;
  end;
end;
Grüße
Klaus
Klaus
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 06:41 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf