AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

DEC 6.1 generelle Fragen

Ein Thema von DieDolly · begonnen am 15. Feb 2021 · letzter Beitrag vom 23. Feb 2021
Antwort Antwort
Seite 2 von 3     12 3   
DieDolly

Registriert seit: 22. Jun 2018
1.740 Beiträge
 
#11

AW: DEC 6.1 generelle Fragen

  Alt 15. Feb 2021, 23:27
Zitat:
Wichtig wäre hier, dass du eine gemeinsame Basisklasse von allen Ver-/Ent-/Hashing-Verfahren findest, die noch alle Methoden die du benötigst zur Verfügung stellst.
Das habe ich versucht. Ich dachte wenn ich bis runter auf TDECHash gehe, ist das die gemeinsame Basisklasse aber das erzeugt eine AV beim Ausführen.
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.573 Beiträge
 
Delphi 10.3 Rio
 
#12

AW: DEC 6.1 generelle Fragen

  Alt 15. Feb 2021, 23:42
Ich habe jetzt nur mal schnell in GitHub direkt in den Sourcen geschaut. Versuch mal die THashBaseMD4 Klasse. Die sieht mir eigentlich nach der passenden Basisklasse aus. Mit TDECHash bist du ja schon fast ganz oben angekommen.
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
1.740 Beiträge
 
#13

AW: DEC 6.1 generelle Fragen

  Alt 15. Feb 2021, 23:47
Gerade auch schon versucht.
Delphi-Quellcode:
function X(Hash: THashBaseMD4): string;
begin
...
 Result := Hash.CalcString('123');
...
end;

showmessage(X(THash_MD5));
Zitat:
E2010 Inkompatible Typen: 'THashBaseMD4' und 'class of THash_MD5'
Ansonsten lege ich mir einfach ein type THashMethods = (MD5, SHA256);, übergebe als parameter THashMethods.XYZ und gucke dann in in der Funktion mittels case was übergeben wurde.
Eine sehr schlechte Umsetzung wäre das aber.

Geändert von DieDolly (15. Feb 2021 um 23:51 Uhr)
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.573 Beiträge
 
Delphi 10.3 Rio
 
#14

AW: DEC 6.1 generelle Fragen

  Alt 16. Feb 2021, 00:08
Naja du musst schon eine Instanz und nicht die Klasse übergeben. Ich habe mal schnell ein Testprojekt zusammen geknüppelt. Kompiliert zumindest einwandfrei. Auch zur Laufzeit kommen bei mir keinerlei Fehler.

Delphi-Quellcode:
program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, DECHash;

type
  THashTest = class
  private

  public
    function HashData(HashClass: THashBaseMD4): string;
  end;


{ THashTest }

function THashTest.HashData(HashClass: THashBaseMD4): string;
begin
  Result := HashClass.CalcString('');
end;

var
  sha256: THash_SHA256;
  md5: THash_MD5;
  hashTest: THashTest;

begin
  try
    sha256 := THash_SHA256.Create;
    md5 := THash_MD5.Create;
    hashTest := THashTest.Create;
    Writeln(hashTest.HashData(sha256));
    Writeln(hashTest.HashData(md5));
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
1.740 Beiträge
 
#15

AW: DEC 6.1 generelle Fragen

  Alt 16. Feb 2021, 00:31
Habe das jetzt etwas umständlich gemacht aber es funktioniert. Mein Aufruf bleibt der gleiche.

Delphi-Quellcode:
unit DEC.Hashing;

interface

uses
 System.Classes, System.SysUtils, DECHash, DECFormat;

type
 THashMethod = (hmMD5, hmSHA256);

type
 THashFunctions = record
 private
  class function GetHash(const HashMethod: THashMethod): THashBaseMD4; static;
  class function HashStringBase(const Text: string; const HashMethod: THashMethod): string; static;
  class function HashFileBase(const FileName: string; const HashMethod: THashMethod): string; static;
  class function HashStreamBase(const Stream: TStream; const HashMethod: THashMethod): string; static;
 public
  class function MD5String(const Text: string): string; static;
  class function MD5File(const FileName: string): string; static;
  class function MD5Stream(const Stream: TStream): string; static;

  class function SHA256String(const Text: string): string; static;
  class function SHA256File(const FileName: string): string; static;
  class function SHA256Stream(const Stream: TStream): string; static;
 end;

implementation

// Base functions
// ==============================================================================================================================================
class function THashFunctions.GetHash(const HashMethod: THashMethod): THashBaseMD4;
begin
 Result := nil;
 case HashMethod of
  hmMD5:
   Result := THash_MD5.Create;
  hmSHA256:
   Result := THash_SHA256.Create;
 end;
end;

class function THashFunctions.HashStringBase(const Text: string; const HashMethod: THashMethod): string;
var
 Hash: THashBaseMD4;
begin
 Hash := THashFunctions.GetHash(HashMethod);
 try
  Result := string(Hash.CalcString(RawByteString(Text), TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

class function THashFunctions.HashFileBase(const FileName: string; const HashMethod: THashMethod): string;
var
 Hash: THashBaseMD4;
begin
 Hash := THashFunctions.GetHash(HashMethod);
 try
  Result := string(Hash.CalcFile(FileName, TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

class function THashFunctions.HashStreamBase(const Stream: TStream; const HashMethod: THashMethod): string;
var
 Hash: THashBaseMD4;
begin
 Hash := THashFunctions.GetHash(HashMethod);
 try
  Result := string(Hash.CalcStream(Stream, Stream.Size, TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;
// ==============================================================================================================================================

// MD5
// ==============================================================================================================================================
class function THashFunctions.MD5String(const Text: string): string;
begin
 Result := HashStringBase(Text, THashMethod.hmMD5);
end;

class function THashFunctions.MD5File(const FileName: string): string;
begin
 Result := HashFileBase(FileName, THashMethod.hmMD5);
end;

class function THashFunctions.MD5Stream(const Stream: TStream): string;
begin
 Result := HashStreamBase(Stream, THashMethod.hmMD5);
end;
// ==============================================================================================================================================

// SHA256
// ==============================================================================================================================================
class function THashFunctions.SHA256String(const Text: string): string;
begin
 Result := HashStringBase(Text, THashMethod.hmSHA256);
end;

class function THashFunctions.SHA256File(const FileName: string): string;
begin
 Result := HashFileBase(FileName, THashMethod.hmMD5);
end;

class function THashFunctions.SHA256Stream(const Stream: TStream): string;
begin
 Result := HashStreamBase(Stream, THashMethod.hmMD5);
end;
// ==============================================================================================================================================

end.
  Mit Zitat antworten Zitat
Aviator

Registriert seit: 3. Jun 2010
1.573 Beiträge
 
Delphi 10.3 Rio
 
#16

AW: DEC 6.1 generelle Fragen

  Alt 16. Feb 2021, 00:34
Und warum? Ich habe doch geschrieben wie es funktioniert.

Naja mach wie du denkst. Du musst ja mit dem Source Code klar kommen.
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
1.740 Beiträge
 
#17

AW: DEC 6.1 generelle Fragen

  Alt 16. Feb 2021, 00:41
Ich verstehe nicht wie ich dein Beispiel in eine Unit packen soll. Ich brauche am Ende eine Unit wo ich von Außen nur aufzurufen brauche ob ich md5 oder sha256 möchte jeweils für string, datei und stream. Ich kann deinen Code jetzt 6x kopieren aber dann habe ich wieder doppelten Code.
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
2.605 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#18

AW: DEC 6.1 generelle Fragen

  Alt 16. Feb 2021, 12:49
Ich würde dir erstmal sowas vorschlagen:

Delphi-Quellcode:
unit DEC.Hashing;

interface

uses
 System.Classes, System.SysUtils, DECHash, DECFormat;

type
 THashBaseMD4Class = class of THashBaseMD4;

type
 THashFunctions = record
 private
  class function HashStringBase(const Text: string; const HashClass: THashBaseMD4Class): string; static;
  class function HashFileBase(const FileName: string; const HashClass: THashBaseMD4Class): string; static;
  class function HashStreamBase(const Stream: TStream; const HashClass: THashBaseMD4Class): string; static;
 public
  class function MD5String(const Text: string): string; static;
  class function MD5File(const FileName: string): string; static;
  class function MD5Stream(const Stream: TStream): string; static;

  class function SHA256String(const Text: string): string; static;
  class function SHA256File(const FileName: string): string; static;
  class function SHA256Stream(const Stream: TStream): string; static;
 end;

implementation

// Base functions
// ==============================================================================================================================================
class function THashFunctions.HashStringBase(const Text: string; const
    HashClass: THashBaseMD4Class): string;
var
 Hash: THashBaseMD4;
begin
 Hash := HashClass.Create;
 try
  Result := string(Hash.CalcString(RawByteString(Text), TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

class function THashFunctions.HashFileBase(const FileName: string; const
    HashClass: THashBaseMD4Class): string;
var
 Hash: THashBaseMD4;
begin
 Hash := HashClass.Create;
 try
  Result := string(Hash.CalcFile(FileName, TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

class function THashFunctions.HashStreamBase(const Stream: TStream; const
    HashClass: THashBaseMD4Class): string;
var
 Hash: THashBaseMD4;
begin
 Hash := HashClass.Create;
 try
  Result := string(Hash.CalcStream(Stream, Stream.Size, TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;
// ==============================================================================================================================================

// MD5
// ==============================================================================================================================================
class function THashFunctions.MD5String(const Text: string): string;
begin
 Result := HashStringBase(Text, THash_MD5);
end;

class function THashFunctions.MD5File(const FileName: string): string;
begin
 Result := HashFileBase(FileName, THash_MD5);
end;

class function THashFunctions.MD5Stream(const Stream: TStream): string;
begin
 Result := HashStreamBase(Stream, THash_MD5);
end;
// ==============================================================================================================================================

// SHA256
// ==============================================================================================================================================
class function THashFunctions.SHA256String(const Text: string): string;
begin
 Result := HashStringBase(Text, THash_SHA256);
end;

class function THashFunctions.SHA256File(const FileName: string): string;
begin
 Result := HashFileBase(FileName, THash_SHA256);
end;

class function THashFunctions.SHA256Stream(const Stream: TStream): string;
begin
 Result := HashStreamBase(Stream, THash_SHA256);
end;
// ==============================================================================================================================================

end.
Aber das finde ich unelegant.
Denn es geht noch besser.

Delphi-Quellcode:
unit DEC.Hashing;

interface

uses
 System.Classes, System.SysUtils, DECHash, DECFormat,
 DECHashAuthentication; // <----- neue Unit, nicht vergessen, da kommt die Definition von TDECHashAuthentication her

type
 THashFunctions = record
 public
  class function HashString<HashClass: TDECHashAuthentication, constructor>(const Text: string): string; static;
  class function HashFile<HashClass: TDECHashAuthentication, constructor>(const FileName: string): string; static;
  class function HashStream<HashClass: TDECHashAuthentication, constructor>(const Stream: TStream): string; static;
 end;

implementation

// Base functions
// ==============================================================================================================================================
class function THashFunctions.HashString<HashClass>(const Text: string): string;
var
 Hash: TDECHashAuthentication;
begin
 Hash := HashClass.Create;
 try
  Result := string(Hash.CalcString(RawByteString(Text), TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

class function THashFunctions.HashFile<HashClass>(const FileName: string): string;
var
 Hash: TDECHashAuthentication;
begin
 Hash := HashClass.Create;
 try
  Result := string(Hash.CalcFile(FileName, TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

class function THashFunctions.HashStream<HashClass>(const Stream: TStream): string;
var
 Hash: TDECHashAuthentication;
begin
 Hash := HashClass.Create;
 try
  Result := string(Hash.CalcStream(Stream, Stream.Size, TFormat_HEX)).ToLower;
 finally
  Hash.Free;
 end;
end;

end.
Anzuwenden dann so:

Delphi-Quellcode:
var
  LStream: TStream;
  MyHash: string;
begin
  MyHash := THashFunctions.HashString<THash_MD5>('Hello');
  MyHash := THashFunctions.HashFile<THash_MD5>('World');
  LStream := TFileStream.Create('C:\temp\Project2.dpr', fmCreate);
  try
    MyHash := THashFunctions.HashStream<THash_MD5>(LStream);
  finally
    LStream.Free;
  end;

  MyHash := THashFunctions.HashString<THash_SHA256>('Hello');
  MyHash := THashFunctions.HashFile<THash_SHA256>('World');
  LStream := TFileStream.Create('C:\temp\Project2.dpr', fmCreate);
  try
    MyHash := THashFunctions.HashStream<THash_SHA256>(LStream);
  finally
    LStream.Free;
  end;
end.
Vorteil: Alle anderen Nachfahren von TDECHashAuthentication können können jetzt ganz einfach benutzt werden (THash_RipeMD128, THash_Tiger, THash_SHA512, THash_Sapphire...usw.)

Geändert von TiGü (16. Feb 2021 um 12:57 Uhr)
  Mit Zitat antworten Zitat
TurboMagic

Registriert seit: 28. Feb 2016
Ort: Nordost Baden-Württemberg
1.251 Beiträge
 
Delphi 10.3 Rio
 
#19

AW: DEC 6.1 generelle Fragen

  Alt 16. Feb 2021, 18:15
Danke an alle, die hier auch zur DEC Support leisten...
Top! Gerne weiter so...
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
2.605 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#20

AW: DEC 6.1 generelle Fragen

  Alt 23. Feb 2021, 09:42
@DieDolly: Bist du hier zu einer für dich brauchbaren Lösung gekommen?
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 06:20 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf