AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Memory Leak bei TJsonObject

Ein Thema von Kostas · begonnen am 23. Dez 2021 · letzter Beitrag vom 23. Dez 2021
Antwort Antwort
Kostas

Registriert seit: 14. Mai 2003
Ort: Gerstrhofen
1.058 Beiträge
 
Delphi 10 Seattle Enterprise
 
#1

Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 14:08
Hallo Zusammen,

das Problem vorab: beim Zuweisen von LResponse entsteht ein Memory Leak.

Über die folgende Methode rufe ich per indy ein JSON response ab. Der Inhalt ist ein neues Token welches abgelaufen ist ab.
Es funktioniert einwandfrei. Wenn ich jedoch die Anwendung beende, wird ein Memory Leak signalisiert da ich Application.MainFormOnTaskbar := True; in der Projektdatei aktiviert habe.
Ich habe Schrittweise alles auskommentiert und die Stelle lokalisieren können die dafür verantwortlich ist. Es ist die Zuweisung von LResponse
Delphi-Quellcode:
procedure TdmCleverReach.RefreshToken;
var LResponse: TJsonObject;
    LResponseStream: TBytesStream;
    FormData: TidMultiPartFormDataStream;
begin

  Formdata := TIdMultiPartFormDataStream.Create;
  Formdata.AddFormField('grant_type', 'refresh_token');
  Formdata.AddFormField('refresh_token', INIRefreshToken);
  Formdata.AddFormField('client_id', INIClientID);
  Formdata.AddFormField('client_secret', INIClientSecret);
  FormData.Position := 0;

  LResponseStream := TBytesStream.Create;
  LResponse := TJsonObject.Create;
  try
    IdhttpToken.Request.CustomHeaders.Clear;
    IdhttpToken.Request.CustomHeaders.AddPair('Content-Type','multipart/form-data');
    try
      IdhttpToken.Post(INITokenURL,FormData,LResponseStream);
      LResponseStream.Position := 0;

      //Hier scheint der Memory Leak zu entstehen, aber warum?
>>>> LResponse := TJsonObject.ParseJSONValue(LResponseStream.Bytes, 0, LResponseStream.Size) as TJsonObject;


    LResponseStream.SaveToFile(PrgPath + '\ResponseStream.JSON');

  finally
    Formdata.Free;
    LResponse.Free;
    LResponseStream.Free;
  end;
end;
Was mache ich falsch?

Gruß Kostas
  Mit Zitat antworten Zitat
peterbelow

Registriert seit: 12. Jan 2019
Ort: Hessen
670 Beiträge
 
Delphi 11 Alexandria
 
#2

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 14:14
Hallo Zusammen,

das Problem vorab: beim Zuweisen von LResponse entsteht ein Memory Leak.

Ich habe Schrittweise alles auskommentiert und die Stelle lokalisieren können die dafür verantwortlich ist. Es ist die Zuweisung von LResponse
Delphi-Quellcode:
procedure TdmCleverReach.RefreshToken;
var LResponse: TJsonObject;
    LResponseStream: TBytesStream;
    FormData: TidMultiPartFormDataStream;
begin

  Formdata := TIdMultiPartFormDataStream.Create;
  Formdata.AddFormField('grant_type', 'refresh_token');
  Formdata.AddFormField('refresh_token', INIRefreshToken);
  Formdata.AddFormField('client_id', INIClientID);
  Formdata.AddFormField('client_secret', INIClientSecret);
  FormData.Position := 0;

  LResponseStream := TBytesStream.Create;
  LResponse := TJsonObject.Create;
Die hier erzeugte Instanz wird nie verwendet und auch nie freigegeben.

Weiter unten überrschreibt dein Kode

   LResponse := TJsonObject.ParseJSONValue(LResponseStream.Bytes, 0, LResponseStream.Size) as TJsonObject; das Objekt.
Peter Below
  Mit Zitat antworten Zitat
Kostas

Registriert seit: 14. Mai 2003
Ort: Gerstrhofen
1.058 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 14:31
oh, genau das habe ich übersehen dass ParseJSONValue ein neues Object erzeugt.

herzlichen Dank.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#4

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 14:42
Und jetzt sag blos, dass es dir der Compiler nicht vorher gesagt hat?
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Kostas

Registriert seit: 14. Mai 2003
Ort: Gerstrhofen
1.058 Beiträge
 
Delphi 10 Seattle Enterprise
 
#5

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 15:08
Nein, von Compiler habe ich keine Warnung oder Hinweis bekommen.
Ist das einstellbar in den Optionen?

Gruß Kostas
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#6

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 15:16
Und jetzt sag blos, dass es dir der Compiler nicht vorher gesagt hat?
Das ist gar nicht mal so sicher. Schließlich könnte ja die zuerst erzeugte Instanz bei einer Exception im finally freigegeben werden und würde somit tatsächlich verwendet.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Incocnito

Registriert seit: 28. Nov 2016
208 Beiträge
 
#7

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 15:28
In der Tat ... entweder musst du vor der neu-Zuweisung das "alte" Objekt freigeben, oder du ziehst das Free aus dem unteren finally weiter nach oben.
Delphi-Quellcode:
procedure TdmCleverReach.RefreshToken;
var LResponse: TJsonObject;
    LResponseStream: TBytesStream;
    FormData: TidMultiPartFormDataStream;
begin

  Formdata := TIdMultiPartFormDataStream.Create;
  Formdata.AddFormField('grant_type', 'refresh_token');
  Formdata.AddFormField('refresh_token', INIRefreshToken);
  Formdata.AddFormField('client_id', INIClientID);
  Formdata.AddFormField('client_secret', INIClientSecret);
  FormData.Position := 0;

  LResponseStream := TBytesStream.Create;
  try
    IdhttpToken.Request.CustomHeaders.Clear;
    IdhttpToken.Request.CustomHeaders.AddPair('Content-Type','multipart/form-data');
    try
      IdhttpToken.Post(INITokenURL,FormData,LResponseStream);
      LResponseStream.Position := 0;

      //Hier scheint der Memory Leak zu entstehen, aber warum?
      LResponse := TJsonObject.ParseJSONValue(LResponseStream.Bytes, 0, LResponseStream.Size) as TJsonObject;
      try
        // whatever
      finally
        LResponse.Free;
      end;
      LResponseStream.SaveToFile(PrgPath + '\ResponseStream.JSON');
    finally
      // ...
    end;
  finally
    Formdata.Free;
    LResponseStream.Free;
  end;
end;
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#8

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 15:35
Delphi-Quellcode:
  LResponse := nil;
  try
    ...
    LResponse := TJsonObject.ParseJSONValue(LResponseStream.Bytes, 0, LResponseStream.Size) as TJsonObject;
  finally
    LResponse.Free;
    ...
  end;
Da genügt dann ein Ressourcenschutzblock.
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#9

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 15:44
Das ist gar nicht mal so sicher. Schließlich könnte ja die zuerst erzeugte Instanz bei einer Exception im finally freigegeben werden und würde somit tatsächlich verwendet.
Aber nur wenn es knallt,
allerdings sollte bei der zweiten Zuweisung eigentlich eine Warnung kommen, denn ohne knallen würde der erste Wert niemals verwendet.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Kostas

Registriert seit: 14. Mai 2003
Ort: Gerstrhofen
1.058 Beiträge
 
Delphi 10 Seattle Enterprise
 
#10

AW: Memory Leak bei TJsonObject

  Alt 23. Dez 2021, 17:03
LResponse wird vorher NICHT erzeugt!

So habe ich es jetzt umgesetzt.

Delphi-Quellcode:
    try
      LResponse := TJsonObject.ParseJSONValue(LResponseStream.Bytes, 0, LResponseStream.Size) as TJsonObject;

      if Assigned(LResponse) then
      begin
        LResponse.TryGetValue<String>('access_token', access_token);
        LResponse.TryGetValue<String>('refresh_token', refresh_token);
        LResponse.TryGetValue<integer>('expires_in', expires_in);
        LResponse.Free;
      end;
    except
      // Fehlerbehandlung.
    end;
Vielen lieben Dank und frohe Weihnachten an alle.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 07:17 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz