Ich habe die folgende Funktion:

markieren

Delphi-Quellcode:

function VarToIntDef(const V: Variant; const ADefault: Integer): Integer;
begin
  if VarIsOrdinal(V) and not VarIsEmptyOrNull(V) then
    Result := V
  else
    Result := ADefault;
end;

Die hat bei einen Kunden einen VarCastError (@VarToInteger) ausgelößt. Wo genau und warum wurde nicht übermittelt und ich weiß auch nicht welcher Kunde.
Wo liegt der Fehler? Auf was müsste ich V setzen um den VarCastError auszulösen?

Wenn es Ordinal (varSmallInt, varInteger, varBoolean, varShortInt, varByte, varWord, varUInt32, varInt64 oder varUInt64) ist, dann kann es niemals Empty oder Null (varEmpty oder varNull) sein.

Nunja, ein UInt32, Int64 oder UInt64 darin wird in den Integer (Int32) nicht rein passen.

zusammenfalten · markieren

Delphi-Quellcode:

var
  V: Variant;
  i: Integer;
begin
  V := Int64(1234567890123);
  if VarIsOrdinal(V) then
    i := V
  else
    i := 123;
  if i = 0 then ;
end;

Ergibt zwar keinen VarCastError, aber zumindestens ein ERangeError (Fehler bei Bereichsprüfung) kommt raus.

Warum schaust du also nicht selbst etwas in die Funkionen rein und guckst, wo/wann ein CastError geworfen wird?
System.Variants._VarToInteger liefert einen CastError bei Null oder bei einem unpassendem String, aber nichts davon kommt am VarIsOrdinal vorbei.

Fazit: Dein VarIsEmptyOrNull ist dran Schuld, auch wenn niemand weiß was das macht, weil jemand vergaß es zu sagen.

Zitat von himitsu:

Fazit: Dein VarIsEmptyOrNull ist dran Schuld

Huch, das ist ja auch eine Funktion von mir. War mir gar nicht mehr bewußt. Die sieht so aus:

markieren

Delphi-Quellcode:

function VarIsEmptyOrNull(const Value: Variant): Boolean;
begin
  Result := VarIsClear(Value) or VarIsEmpty(Value) or VarIsNull(Value) or
    (VarCompareValue(Value, Unassigned) = vrEqual);

  if not Result and VarIsStr(Value) then
    Result := Value = '';
end;

Da wird doch nichts nach Int gewandelt? Wie kann die also Schuld daran sein? Oder übersehe ich was? Nur so aus Interesse, denn Du hast natürlich recht: Die Funktion brauche ich gar nicht mehr...

Sagen wir es mal so: Ich fand in den anderen Funktionen (noch) nichts, was für diesen Fehler verantwortlich sein könnte, also blieb erstmal nur noch das übrig.



PS: Unassigned = Clear
und Empty ist auch im Clear mit enthalten

Entsprechend bleibt funktionell kaum noch etwas übrig.

zusammenfalten · markieren

Delphi-Quellcode:

function VarToIntDef(const V: Variant; const ADefault: Integer): Integer;
begin
  if VarIsOrdinal(V) {and not VarIsEmptyOrNull(V)} then // ist es Ordinal, ist es gleichzeitig niemals das Andere
    Result := V //:= _VarToInteger(V) // größer signed 32-Bit knallt es
  else
    Result := ADefault;
end;

{function VarIsEmptyOrNull(const Value: Variant): Boolean;
begin
  Result := VarIsClear(Value) or VarIsNull(Value);
  if not Result and VarIsStr(Value) then
    Result := Value = '';
end;}

VarIsEmptyOrNull hat auf's Ergebnis keinen Einfluss,
aber es wird dennoch ausgeführt, wenn VarIsOrdinal zutrifft, wobei es dann immer False lieft.
(und and not False , bzw. and True ändert dann nichts mehr)

VarCompareValue und VarIsEmpty werden immer nur sinnlos ausgeführt.
Sie liefern immer nur True, wenn das VarIsClear bereits gemacht hatte und dann werden sie vom OR nicht mehr ausgeführt.
Alles in VarIsEmptyOrNull wird auch nur ausgefüjrt, wenn VarIsOrdinal True sagte, wo dann alles im VarIsEmptyOrNull nur noch False liefern kann.
(es wird also alles zwar ausgeführt, aber sinnlos, da es das Endergebnis nicht beeinflussen kann, weil es ja immer and True sein wird, sobald es ausgeführt wird)

Was am Ende übrig bleibt, kann eigentlich keinen CastError auslösen (abgesehn von eventuell dem, was sinnlos enthalten war)
und übrig bleibt noch ein Fehler, wenn es größer als 32 Bit wird. (ERangeError)

Du hast also viel Code, der eigentlich nichts macht, da er keine Auswirkung auf's Ergebnis hat, außer eventuell Fehler zu verursachen.

Lösung:

markieren

Delphi-Quellcode:

function VarToIntDef(const V: Variant; const ADefault: Integer): Integer;
begin
  if VarIsType(V, [varSmallInt, varInteger, varBoolean, varShortInt, varByte, varWord]) then // entspricht VarIsOrdinal bis Int32 (signed 32-Bit)
    Result := V
  {else if VarIsStr(V) then
    Result := StrToIntDef(V, ADefault)}
  else
    Result := ADefault;
end;

Allerdings fehlt bei deinem Code, z.B. die Behandlung von nummerischen Strings, welche ich oben noch heimlich mit eingefügt hab.