Unterschiedliche Darstellung mit und ohne laufendem Delphi

[Redeemer]

Eins ist Release und eins ist Debug.

[Alucard]

Erstmal sorry für die arg verspätete Antwort und vielen Dank für euren Input. Leider habe ich hier im Forum ständig Login- und Passwort-Probleme. Eigentlich hatte ich die gleich folgende Antwort direkt nach Uwes Post abgesetzt, aber die hatte es irgendwie zerhagelt und ich hatte seitdem keine Zeit mehr.


Alright, das ist jetzt peinlich

Kurzfassung: Der Fehler lag gänzlich woanders und - was wichtiger ist - in meiner Verantwortung

Die Listen werden aus zwei Text-Dateien gelesen (je eine für die obere und die untere Box) und im Falle der unteren noch nach einigen Kriterien geprüft. Bei bestandener Prüfung wird das Element angezeigt, sonst halt nicht. Da ich seit der Umstellung ausschließlich Probleme im Zusammenhang mit High-DPI hatte, bin ich blöderweise betriebsblind geworden und habe übersehen, dass in dieser Prüfung der Name des Rechners auf Übereinstimmung mit einer (hart-codierten) Liste untersucht wird - ggf. schaut diese Prüfung auch, ob Delphi läuft

Delphi-Quellcode:

procedure LadenWebTools;
var User : string;
    Delphi : boolean;
    Data : TStringList;
   i : integer;
const EntryLength : integer = 6;
begin
User   := GetEnvironmentVariable('Computername');
Delphi := FindWindow('TAppBuilder', nil) <> 0;

Data := TStringList.Create;
Data.LoadFromFile('WebTools.txt');

i := 0;
SetLength(WebTools, 0);

While i <= Data.Count - 1 do
      begin
      SetLength(WebTools, Length(WebTools) + 1);

      With WebTools[High(WebTools)] do
           begin
           Name := Data[i];
           { mehr Daten... }
           Tag  := Data[i + 4];
           { mehr Daten... }

           Inc(i, EntryLength);

           { Eintrag wieder löschen, wenn
              -- kein Icon gefunden
              -- keine User Übereinstimmung
              -- bei laufendem Delphi User ignorieren }
           If (FileExists('WebTools\' + Name + '.png') = false) Or
              ( (Tag = 'Home') And (Delphi = false) And (User <> 'User_Home_1')
                                                    And (User <> 'User_Home_2')
                                                    And (User <> 'User_Home_n')  ) Or
              ( (Tag = 'Work') And (Delphi = false) And (User <> 'User_Work'  )  )
              then SetLength(WebTools, Length(WebTools) - 1);
           end;
      end;

Data.Free

For i := 0 to High(WebTools) do
    begin
    WebTools[i].Panel     := TPanel.Create(Self);
    WebTools[i].Image     := TImage.Create(Self);
    WebTools[i].Text      := TPanel.Create(Self);
    WebTools[i].BtnOpen   := TButton.Create(Self);
    WebTools[i].BtnSearch := TButton.Create(Self);

    { Design... }
    end;
end;

[jaenicke]

Das passiert. Das wichtigste ist ja, dass es nun funktioniert.

Einen Tipp habe ich aber noch. Du machst das ganze ziemlich umständlich. Einfacher und übersichtlicher wäre es so:

Delphi-Quellcode:

procedure LadenWebTools;

  function ReadNextWebTool(const ADataList: TStringList; const AIndex: Integer): TWebTool;
  begin
    Result.Name := ADataList[AIndex];
    { mehr Daten... }
    Result.Tag := ADataList[AIndex + 4];
    { mehr Daten... }
  end;

var
  User: string;
  Delphi: Boolean;
  Data: TStringList;
  CurrentTool: TWebTool;
  i : integer;
const 
  EntryLength: Integer = 6;
begin
  User := GetEnvironmentVariable('Computername');
  Delphi := FindWindow('TAppBuilder', nil) <> 0;

  Data := TStringList.Create;
  try
    Data.LoadFromFile('WebTools.txt');

    i := 0;
    SetLength(WebTools, 0);

    while i <= Data.Count - 1 do
    begin
      CurrentTool := ReadNextWebTool(Data, i);
      Inc(i, EntryLength);
      if FileExists('WebTools\' + Name + '.png')
        and CurrentTool.Tag ... then
      begin
        SetLength(WebTools, Length(WebTools) + 1);
        WebTools[High(WebTools)] := CurrentTool;
      end;
    end;
  finally
    Data.Free;
  end;
[...]

Dann hast du eine Funktion, die dir den nächsten Eintrag liest und kannst mit dessen Daten zur Prüfung arbeiten. Daher kannst du das Array dann nur erweitern, wenn du den Eintrag möchtest und musst nichts wieder löschen.
Und du brauchst das leidige with nicht.

[Uwe Raabe]

Die ReadNextWebTool Implementierung sieht aber nicht wirklich gesund aus...

[jaenicke]

Zitat von Uwe Raabe:

Die ReadNextWebTool Implementierung sieht aber nicht wirklich gesund aus...

Ups, ja, ich habe den Parameternamen nicht angepasst. Danke!

[Uwe Raabe]

Na ja, auch der Index I ist dort nicht wirklich bekannt.

[jaenicke]

Ja gut, wenn es sein muss...
So sollte es besser passen.

[Alucard]

Zitat von Uwe Raabe:

Die ReadNextWebTool Implementierung sieht aber nicht wirklich gesund aus...

Das hatte ich mir zur ersten Version der Antwort auch gedacht, aber wenigstens war das ein offensichtlicher Schnitzer und nicht einer von den fiesen versteckten, die einen Ewigkeiten aufhalten


Was anderes: Sowohl Jaenicke als auch Uwe (iwo bei Stackoverflow...) haben ihre Abneigung gegen das

Code:

With {...} do {...};

geäußert - Warum? Ich finde, das schafft echt Übersicht im Code. Tatsächlich baue ich das sogar nachträglich noch in alte Projekte ein, wenn ich ne passende Stelle sehe

[jaenicke]

Zitat von Alucard:

Was anderes: Sowohl Jaenicke als auch Uwe (iwo bei Stackoverflow...) haben ihre Abneigung gegen das

Code:

With {...} do {...};

geäußert - Warum? Ich finde, das schafft echt Übersicht im Code. Tatsächlich baue ich das sogar nachträglich noch in alte Projekte ein, wenn ich ne passende Stelle sehe

• Du kannst an der Stelle den Debugger nicht gut verwenden. Der weiß nicht, was wohin gehört und kann daher keine Tooltips mit dem Wert anzeigen. Und du kannst einen Wert auch nicht einfach mit Strg + F7 auswerten, sondern musst immer den Ausdruck aus with dazu kopieren.
• Bei einem Upgrade auf eine neue Delphiversion oder auf neue Versionen externer Komponenten können sich schwer zu findende Fehler einschleichen.
  Beispiel: TRect hat in XE2 Width und Height bekommen. Wenn irgendwo ein with auf ein TRect verwendet wurde, was z.B. bei den VirtualTrees der Fall war, gab es im besten Fall einen Fehler beim Kompilieren, aber es gab auch Fälle, in denen plötzlich das TRect geändert wurde statt des Formulars oder der Komponente, die eigentlich gemeint war. Das war dann bei komplexeren Projekten auf den ersten Blick gar nicht zu sehen und führte teilweise zu längerer Fehlersuche.
• Man sieht nicht auf den ersten Blick, welcher Identifier zu dem Element in with gehört und welcher eigenständig ist, was die Lesbarkeit erschwert. Wenn du selbst in einem Jahr auf den Quelltext schaust oder gar jemand anderes, braucht das Verständnis des Quelltextes entsprechend länger.
• Du kannst Teile des Quelltextes nicht einfach kopieren oder überarbeiten, weil du auf das with Rücksicht nehmen muss, was die Wartbarkeit reduziert.
• Der LSP und damit die Codevervollständigung funktionieren damit schlechter. Kreuzbeziehungen und with sind da sehr schlecht.

Tatsächlich kenne ich Hooks in Quelltextrepositories, die ein Einchecken verhindern, wenn darin ein with enthalten ist.

[himitsu]

Abgesehn davon: relative Pfade