WebStencilProcessor Funktionsaufruf im Template

[Starsky911]

Ist es möglich in einem HTML-Template numerische Werte zu formatieren?
Ich würde gerne die Funktion FormatFloat für die Formatierung von Betragswerten nutzen, bekomme eine Fehlermeldung.
Es besteht ja die Möglichkeit Stringwerte zu formatieren mit z.B. Uppercase.
Gibt es eine Übersicht welche Funktionen über RTTI nutzbar sind und welche nicht?

Code:

<tbody>
  @foreach Artikelliste {
    <tr>
      <td>@(UpperCase(loop.bezeichnung))</td>      <-- Funktioniert 
      <td>@(FormatFloat('0.00',loop.betrag))</td>  <-- Fehler
    </tr>
  }
</tbody>

Vielen Dank im Voraus.
Starsky

[gubbe]

Ich würde es mal mit loop.betrag.toString probieren (Parameter siehe Doku).

[Starsky911]

Zitat von gubbe:

Ich würde es mal mit loop.betrag.toString probieren (Parameter siehe Doku).

Das funktioniert leider auch nicht.

[gubbe]

Mit Format würde es funktionieren:

Format('%.2f', loop.Betrag)
Tausender- und Dezimaltrennzeichen werden aus den globalen Variablen übernommen (DecimalSeparator und Thousandseparator).

Für die Auswertung der Ausdrücke werden die gleichen Funktionen wie bei LiveBindings verwendet.

Die Basis-Funktionen sind damit:

ToStr, ToVariant, ToNotifyEvent, Round, Format, UpperCase, LowerCase, FormatDateTime, StrToDateTime, Math_Min, Math_Max, IfThen, IfAny, IfAll, SubString

[gubbe]

Deine Frage hat mich auf die Idee gebracht, mal zu schauen, wie man eigene Funktionen erweitern könnte. Hier ein Beispiel.

Wenn Du z.B. eine Funktion "FormatFloat" nutzen willst, kannst Du Sie folgendermaßen definieren.
Zum Registrieren rufst Du "RegisterOwnFunctions" in Deinem Code auf.

Delphi-Quellcode:

uses
  System.Bindings.Methods, System.Bindings.EvalProtocol, System.Bindings.Consts;

function MakeMethodFormatFloat: IInvokable;
begin
  Result := MakeInvokable(function(Args: TArray<IValue>): IValue
  var
    v1: IValue;
    Value: Extended;
    formatted: string;
  begin
    if Length(Args) <> 2 then
      raise EEvaluatorError.CreateRes(@sFormatArgError);
    v1 := Args[0];
    if not (v1.GetType.Kind in [tkString, tkUString, tkWString]) then
      raise EEvaluatorError.CreateRes(@sFormatExpectedStr);
    if Args[1].GetValue.IsEmpty then
      Exit(TValueWrapper.Create(nil)) // Handle null
    else
    begin
      Value := Args[1].GetValue.AsExtended;
      formatted := FormatFloat(v1.GetValue.AsString, Value, TFormatSettings.Create);
    end;
    Result := TValueWrapper.Create(formatted);
  end);
end;

procedure RegisterOwnFunctions;
begin
  TBindingMethodsFactory.RegisterMethod(
    TMethodDescription.Create(
      MakeMethodFormatFloat,
      'FormatFloat',
      'FormatFloat', '', True,
      '',
      nil));
end;