Sprach ID aus Exe auslesen

[BastiFantasti]

Hallo zusammen,

mit den Winapi Aufrufen GetFileVersionInfoSize/GetFileVersionInfo ist es ja möglich sämtliche Informationen aus der Exe auszulesen wie:
- Versionsnummern,
- Firmenname
- Produktname
...
- SpecialBuild
- DebugBuild
usw

Die "Sprache ID" kann man auch auf der Versionsinfo Seite definieren,
nur habe ich bis jetzt keine Möglichkeit gefunden, die "Sprache ID" Eigenschaft später zur Laufzeit auszulesen.

Hat hier jemand eine Idee?

Viele Grüße
Bastian

[Uwe Raabe]

Mit VerQueryValue und "\VarFileInfo\Translation" für den lpSubBlock Parameter kommst du an die Liste der unterstützen Sprachen. Wie üblich ist das aber eine gehörige Frickelei.

Falls du die FireDAC-Sourcen hast findest du ein Beispiel in FDGetVersionInfo (FireDAC.Stan.Utils.pas).

[KHJ]

Vielleicht in JclFileVersion => TJclFileVersionInfo
Siehe auch das Beispielprogramm dazu.

[Michael II]

Dies funktioniert bei meiner App. (Copilot )

Delphi-Quellcode:

procedure sprachIDCodepage;
var
  InfoSize: DWORD;
  InfoData: Pointer;
  Translation: Pointer;
  TranslationLen: UINT;
  LangID, CodePage: Word;
begin
  InfoSize := GetFileVersionInfoSize(PChar(ParamStr(0)), InfoSize);
  if InfoSize > 0 then
  begin
    GetMem(InfoData, InfoSize);
    try
      if GetFileVersionInfo(PChar(ParamStr(0)), 0, InfoSize, InfoData) then
      begin
        if VerQueryValue(InfoData, '\VarFileInfo\Translation', Translation, TranslationLen) then
        begin
          LangID := MakeWord(PByte(Translation)^, PByte(Integer(Translation) + 1)^);
          CodePage := MakeWord(PByte(Integer(Translation) + 2)^, PByte(Integer(Translation) + 3)^);
          ShowMessage(Format('Sprach-ID: %x, Codepage: %x', [LangID, CodePage]));
        end;
      end;
    finally
      FreeMem(InfoData);
    end;
  end;
end;

[himitsu]

Und knallt hoffentlich wunderschön, mit 64 Bit.

Wer nach 14 20 Jahren des 64-Bit-Delphi 64-Bit-Windows immernoch Pointer zu Integer castet, dem gehört ordentlich der Popo versohlt.

Delphi-Quellcode:

procedure SprachID2Codepage;
var
  InfoSize: DWORD;
  InfoData: TBytes;
  Translation: Pointer;
  TranslationLen: UINT;
  LangID, CodePage: Word;
begin
  InfoSize := GetFileVersionInfoSize(PChar(ParamStr(0)), InfoSize);
  if InfoSize > 0 then
  begin
    SetLength(InfoData, InfoSize);
    if GetFileVersionInfo(PChar(ParamStr(0)), 0, InfoSize, @InfoData[0]) then
    begin
      if VerQueryValue(@InfoData[0], '\VarFileInfo\Translation', Translation, TranslationLen) then
      begin
        LangID   := PWord(Translation)^;
        CodePage := PWord(IntPtr(Translation) + 2)^;  // oder PByte statt IntPtr/Pointer und schön die Pointer-Arithmetik nutzen :D
        ShowMessage(Format('Sprach-ID: %.4x, Codepage: %.4x', [LangID, CodePage]));
      end;
    end;
  end;
end;

Automatische Speicherverwaltung und Casten in gleich den "richtigen" Typen ... hach, das Leben könnte so einfach sein.

[BastiFantasti]

Guten Morgen zusammen,

danke für die Rückmeldungen!
Ich werde die genannten Möglichkeiten unter 32 und 64 Bit probieren und berichten.

Viele Grüße
Bastian

[Michael II]

Zitat von himitsu:

Und knallt hoffentlich wunderschön, mit 64 Bit.

Wer nach 14 20 Jahren des 64-Bit-Delphi 64-Bit-Windows immer noch Pointer zu Integer castet, dem gehört ordentlich der Popo versohlt.


Automatische Speicherverwaltung und Casten in gleich den "richtigen" Typen ... hach, das Leben könnte so einfach sein.

Ja du hast Recht - aber ich kann dir versichern, an jenem Tag hat mir das Leben gleich nach dem Aufwachen den Popo fast maximal versohlt und ich wollte mich Stunden später ein wenig ablenken und helfen und habe dabei voll gepennt. Sorry.

Da ich immer wieder solche Tage habe und hier nicht mehr nerven will, melde ich mich aus diesem Forum ab. Herzlichen Dank allen, welche mir irgendwann einmal geholfen haben - und besten Dank den Betreibern des Forums für all Ihre Arbeit.

Alles Gute.

[HolgerX]

Hmm...

Wieso macht ihr das nicht so wie MS es sogar in seinem Beispiel angibt:

Delphi-Quellcode:

type
  TTransRec = packed record
    Lang, // language code
    CharSet: Word; // character set (code page)
  end;
  PTransRec = ^TTransRec; // pointer to TTransRec

procedure SprachID2Codepage;
var
  InfoSize: DWORD;
  InfoData: Array of Byte;
  Translation: PTransRec;
  TranslationLen: UINT;
begin
  InfoSize := GetFileVersionInfoSize(PChar(ParamStr(0)), InfoSize);
  if InfoSize > 0 then
  begin
    SetLength(InfoData, InfoSize);
    if GetFileVersionInfo(PChar(ParamStr(0)), 0, InfoSize, @InfoData[0]) then
    begin
      if VerQueryValue(@InfoData[0], '\VarFileInfo\Translation', Pointer(Translation), TranslationLen) then
      begin
        ShowMessage(Format('Sprach-ID: %.4x, Codepage: %.4x', [Translation.Lang, Translation.CharSet]));
      end;
    end;
  end;
end;

Das sollte doch für 32 und 64 Bit funktionieren ?
(Kann es gerade nicht mit 64bit testen)

Delphi-Quellcode:

  for Idx := 0 to Pred(TranslationLen) do
  begin
    ShowMessage(Format('Sprach-ID: %.4x, Codepage: %.4x', [Translation.Lang, Translation.CharSet]));
    Inc(Translation);
  end;

Selbst ein Durchgehen durch alle Codes ist so sauber möglich...
Oder vertue ich mich hier?

[BastiFantasti]

Guten morgen zusammen,

ja das Microsoft Beispiel wie oben angegeben funktioniert für 32/64 Bit.
Auf der Seite von Microsoft wo die Funktionen und Variablen entsprechend aufgelistet sind konnte ich aber nichts über das Auslesen der Sprache finden.
Nur die Infos wie Version, Firma, Produktname, usw...

Die Funktion über die JVCL wie in deren Beispiel beschrieben funktionieren auch.

Kann man aus den Delphi Resource Dateien auch die Sprachinfo auslesen (die für die Übersetzung verwendeten .de-DE, .en-US, usw)?
Dann wäre man hier etwas flexibler mit der Namenskonvention und müsste z.B. für die deutsche Übersetzung nicht nach .DE, .de-DE, .DEU, .de-AT usw. parsen.

[himitsu]

Zitat von BastiFantasti:

Kann man aus den Delphi Resource Dateien auch die Sprachinfo auslesen (die für die Übersetzung verwendeten .de-DE, .en-US, usw)?

Das kommt drauf an, ob Delphi nur auf die Dateiendung geht (was es tut)
und ob sie dennoch die Sprachinfos an der Ressource gesetzt haben. (wäre Ideal, dann wäre es ja auch möglich mehrere Sprachen in einer Datei zu haben, bzw. alles auch direkt in EXE/DLL zu linken)

Aber ich denke mal nicht, dass sie die Sprache hier gesetzt haben (hab aber auch nicht nachgesehn)

Die .de usw. sind ja einfach nur Ressoucen-DLLs, genauso wie die CodeDLL, wo die englische Ressourcen einkompiliert sind.