AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Sonstige Fragen zu Delphi Delphi Prüfen, ob ein Popupmenü geöffnet ist
Thema durchsuchen
Ansicht
Themen-Optionen

Prüfen, ob ein Popupmenü geöffnet ist

Ein Thema von Ben · begonnen am 29. Jul 2004 · letzter Beitrag vom 9. Aug 2015
 
Ben

Registriert seit: 16. Apr 2003
Ort: Neumünster
73 Beiträge
 
Delphi 5 Standard
 
#2

Re: Prüfen, ob ein Popupmenü auf ist

  Alt 29. Jul 2004, 14:33
Ok, Problem hat sich gelöst.

Zunächst muss eine Unit ExPopupList erstellt und eingebunden werden:
Code:
unit ExPopupList;

interface

uses Controls;

const
  CM_MENUCLOSED   = CM_BASE - 1;
  CM_ENTERMENULOOP = CM_BASE - 2;
  CM_EXITMENULOOP = CM_BASE - 3;

implementation

uses Messages, Forms, Menus;

Type
  TExPopupList = class( TPopupList )
  protected
    procedure WndProc(var Message: TMessage); override;
  end;

procedure TExPopupList.WndProc(var Message: TMessage);
  Procedure Send( msg: Integer );
  Begin
    If Assigned( Screen.Activeform ) Then
      Screen.ActiveForm.Perform( msg, Message.wparam,
Message.lparam );
  End;
begin
  Case message.Msg Of
    WM_ENTERMENULOOP: Send( CM_ENTERMENULOOP );
    WM_EXITMENULOOP : Send( CM_EXITMENULOOP );
    WM_MENUSELECT  :
      With TWMMenuSelect( Message ) Do
        If (Menuflag = $FFFF) and (Menu = 0) Then
          Send( CM_MENUCLOSED );
  End;
  inherited;
end;

Initialization
  PopupList.Free;
  PopupList:= TExPopupList.Create;
end.
Im Programm lässt sich das Öffnen und Schließen von Menüs dann so erkennen:
Code:
    procedure CMMenuClosed(var Msg: TMessage ); message CM_MENUCLOSED;
    procedure CM_ENTERMENULOOP(var Msg: TMessage ); message CM_ENTERMENULOOP;

procedure TMainForm.CMMenuClosed(var msg: TMessage);
begin
  Tag := 0;
end;

procedure TMainForm.CM_ENTERMENULOOP(var Msg: TMessage);
begin
  Tag := 1;
end;
Hier im Beispiel habe ich in MainForm.Tag festgelegt, ob ein Menü geöffnet ist (1) oder nicht (0).


Vielleicht könnte das in die Code-Library aufgenommen werden, habe schon häufiger gesehen, dass es gefragt wurde.

Gruß, Ben
Ben Hübner
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 22:02 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz