TStringList in .NET?

[Robert_G]

StringBuilder ist prima geeignet um Strings zu manipulieren. Das ist aber keine Liste von Strings, durch die man iterieren kann!
Wenn es dir um das einfache LoadFromFile/Stream geht könntest du irgendwas ähnliches wie das hier nehmen:

Delphi-Quellcode:

interface
uses 
   System.IO,
   System.Collections.Specialized;

type
  StringList = public class(StringCollection)
  public
      method LoadFromStream(aStream :Stream); virtual;
      method SaveToStream(aStream :Stream); virtual;
      
      method LoadFromFile(aFileName :string); virtual;
      method SaveToFile(aFileName :string); virtual;
  end;
  
implementation

method StringList.LoadFromStream(aStream :Stream); 
var
   Reader :TextReader;
begin
   Clear;
   
   using Reader := new StreamReader(aStream) do
   begin
      while Reader.Peek <> -1 do
         Add(Reader.ReadLine);
   end;
end;

method StringList.SaveToStream(aStream :Stream); 
var
   Writer :TextWriter;
begin
   using Writer := new StreamWriter(aStream) do
   begin
      for each Item :string in self do
         Writer.WriteLine(Item);

      Writer.Close;
   end;
end;

method StringList.LoadFromFile(aFileName :string); 
var
   Stream :FileStream;
begin
   using Stream := new FileStream(aFileName, FileMode.Open) do
      LoadFromStream(Stream);  
   
end;

method StringList.SaveToFile(aFileName :string); 
var
   Stream :FileStream;
begin
   using Stream := new FileStream(aFileName, FileMode.OpenOrCreate) do
      SaveToStream(Stream);  
end;

Zitat:

Dieses Thema wurde von "sakura" von "Programmieren allgemein" nach "Sonstige Fragen zu Delphi" verschoben.
DELPHI FRAGE

Hmpf? Ist das nicht eine allgemeine .Net Frage?