AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Thema durchsuchen
Ansicht
Themen-Optionen

LabelFelder im QR dynamisch anlegbar?

Ein Thema von Mada · begonnen am 18. Mär 2003 · letzter Beitrag vom 19. Mär 2003
 
Benutzerbild von Garby
Garby

Registriert seit: 17. Mär 2003
Ort: Tirol
199 Beiträge
 
Delphi 2005 Professional
 
#2

nur so als Beispiel...

  Alt 18. Mär 2003, 18:23
Hallo,

ich habe ein vorhandenes Beispiel ein bisschen modifiziert, sodass es für dich passen sollte:

Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  QuickRpt, QRCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    btnDrucken: TButton;
    procedure btnDruckenClick(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure ArrayDrucken(Arr: array of Integer);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

{ TForm1 }

procedure TForm1.ArrayDrucken(Arr: array of Integer);
var i, aTop:Integer;
begin
  aTop := 0;
  with TQuickRep.Create(nil) do begin
    Bands.HasDetail := True;
    for i := Low(Arr) to High(Arr) do
      if Arr[i] <> 0 then
        with TQRLabel(Bands.DetailBand.AddPrintable(TQRLabel)) do begin
          Left := 0;
          Top := aTop + Font.Size * 2;
          aTop := Top;
          AutoSize := True;
          Caption := IntToStr(Arr[i]);
          Font.Style := [fsBold];
        end; // End With

    Font.Size := 8;
    Bands.HasPageFooter := True;
    with TQRSysData(Bands.PageFooterBand.AddPrintable(TQRSysData)) do begin
      Data := qrsDate;
      AlignToBand := True;
      Alignment := taRightJustify;
      Top := 2;
    end; // end with
    with TQRSysData(Bands.PageFooterBand.AddPrintable(TQRSysData)) do begin
      Data := qrsPageNumber;
      Text := 'Seite ';
      AlignToBand := True;
      Alignment := taLeftJustify;
      Top := 2;
    end; // end with

    PreviewModal;
    Free;
  end;
end;

procedure TForm1.btnDruckenClick(Sender: TObject);
begin
  ArrayDrucken([1, 2, 3, 0, 6, 5, 0, 3, 2, 3, 0, 6, 5, 0, 3, 2, 3, 0, 6, 5]);
end;

end.
Ciao,
Garby
Walter
Wenn zwei dasselbe tun, ist es noch lange nicht dasselbe
(Adelphi)
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 15:44 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz