Hi,

ich hab da mal ne Frage: (Entweder bin ich blind oder blöd aber ich finds net)
Wie kann ich Text in einem Edit zentriert darstellen, also das es in der Mitte steht (der Text) ?


Thx

afaik gar nicht. Es gibt auf jeden fall keine entsprechende Property! (oder ich bin auch blind )

mfg

Gut, dann bin ich doch nicht blöd !

Aber wie kann ich das machen ?

Dazu müssen die CreateParams von der Klasse TEdit überschrieben werden.
Folgende Unit kann als Komponente installiert werden.

zusammenfalten · markieren

Delphi-Quellcode:

unit AlignEdit;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type

  TAlign = (eaLeft, eaCenter, eaRight);

  TAlignEdit = class(TEdit)
  private
    { Private-Deklarationen }
    FAlign: TAlign;
    procedure SetAlign(const Value: TAlign);
  protected
    { Protected-Deklarationen }
    procedure CreateParams(var Params: TCreateParams); override;
  public
    { Public-Deklarationen }
    constructor Create(AOwner: TComponent); override;
  published
    { Published-Deklarationen }
    property Alignment: TAlign read FAlign write SetAlign default eaLeft;
  end;

procedure Register;

implementation

constructor TAlignEdit.Create(Aowner: TComponent);
begin
  inherited Create(AOwner);
  FAlign := eaLeft;
end;

procedure TAlignEdit.SetAlign(const Value: TAlign);
begin
  if FAlign <> Value then
  begin
    FAlign := Value;
    RecreateWnd;
  end;
end;

procedure TAlignEdit.CreateParams(var Params: TCreateParams);
begin
  inherited;
  case FAlign of
    eaLeft: Params.Style := Params.Style or ES_LEFT;
    eaCenter: Params.Style := Params.Style or ES_CENTER;
    eaRight: Params.Style := Params.Style or ES_RIGHT;
  end;
end;

procedure Register;
begin
  RegisterComponents('SwissDelphiCenter', [TAlignEdit]);
end;

end.

Dankeschön, mal gucken ob ich das installiert bekomme.
Nur unter D05 kann ich ja nur noch Packages erstellen !?

Na dann erstellst du ein Package, fügst die Unit hinzu, compilierst und installierst es. Fertig!