Hi,

ich habe ein Verzeichniss, x Ini-Dateien und null Ahung wie ich es anstellen soll rauszufinden wieviele Ini-Dateien sich in diesem Verzeichniss befinden. Das Einzigste was ich mir vorstellen könnt, ware eine Schleifen, die ihre Abbruchbedingen immer um eins erhöht.

Irgendjemand ne Ahnung?

Hi!
Such mal nach FindFirst und FindNext

Hai,

in der Code-Library gibt es diesen Beitrag um Dateien in einem Verzeichniss aufzulisten. Mit ein, zwei Handgriffen müsstest Du das für deinen Fall anpassen können.

Also vom Prinzip her klappt des nun bei mir. Nur nicht alle Dateien werden ausgelesen, so werden z.B. von 6 Dateien nur 5 in die Memo geschrieben (die 4te wird ausgelassen, warum auch immer).

Hier mal der Code

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var Ini: TInifile; i : integer; F: TSearchRec;
var1 : string;
begin

Findfirst('Stocks\*.ini', faAnyFile , F);
Ini:= TInifile.create('Stocks\'+F.Name);
var1:= Ini.readstring('Stock','Name','NIX');
Memo1.lines.Add(var1);


repeat
Findnext(F);

Ini:= TInifile.create('Stocks\'+F.Name);
var1:= Ini.readstring('Stock','Name','NIX');
Memo1.lines.Add(var1);

until (FindNext(F) <> 0);
//Memo1.Lines.Add(inttostr(i));


end;

Hi! FindClose und Resourcenschutzblöcke nicht vergessen

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var Ini: TInifile;
    i : integer;
    F: TSearchRec;
    s, RootDir : string;
begin
  i := 0;
  RootDir := ExtractFilePath(ParamStr(0));

  If FindFirst(RootDir + 'Stocks\*.ini', faAnyFile-faDirectory, F) = 0 then
  Repeat
   Ini:= TInifile.Create(RootDir + 'Stocks\'+F.Name);
   try
    inc(i);
    s := Ini.ReadString('Stock','Name','');
    Memo1.Lines.Add(IntToStr(i) +': ' + s);
   finally
    Ini.Free;
   end;
  Until FindNext(F) <> 0;

  SysUtils.FindClose(F);
end;

Ach sag doch einfach, das ich zuviel Code hab.

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var Ini: TInifile; i : integer; F: TSearchRec;
var1 : string;
begin

if (Findfirst('Stocks\*.ini', faAnyFile , F)=0) then

repeat
      try
      Ini:= TInifile.create('Stocks\'+F.Name);
      var1:= Ini.readstring('Stock','Name','NIX');
      Memo1.lines.Add(var1);
      finally
      Ini.free;
      end;
until (FindNext(F) <> 0);

SysUtils.FindClose(F);
end;

So okay?

Warum eigentlich SysUtils.FindClose(F) und nicht nur FindClose(F)?

es reicht auch nur "FindClose". Und das FindClose braucht nur aufgerufen werden wenn FindFirst erfolgreich ist, ansonsten wird bei Findfirst intern schon FindClose aufgerufen.

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var Ini: TInifile;
    i : integer;
    F: TSearchRec;
    s, RootDir : string;
begin
  i := 0;
  RootDir := ExtractFilePath(ParamStr(0));

  If FindFirst(RootDir + 'Stocks\*.ini', faAnyFile-faDirectory, F) = 0 then
  begin
    Repeat
      Ini:= TInifile.Create(RootDir + 'Stocks\'+F.Name);
      try
        inc(i);
        s := Ini.ReadString('Stock','Name','');
        Memo1.Lines.Add(IntToStr(i) +': ' + s);
      finally
        Ini.Free;
      end;
    Until FindNext(F) <> 0;
    FindClose(F);
  end;
end;