AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Sonstige Fragen zu Delphi Delphi String von Thread an Hauptformular schicken
Thema durchsuchen
Ansicht
Themen-Optionen

String von Thread an Hauptformular schicken

Ein Thema von mumu · begonnen am 20. Mai 2005 · letzter Beitrag vom 21. Mai 2005
 
Benutzerbild von Sprint
Sprint

Registriert seit: 18. Aug 2004
Ort: Edewecht
712 Beiträge
 
Delphi 5 Professional
 
#3

Re: String von Thread an Hauptformular schicken

  Alt 21. Mai 2005, 00:45
Zitat von mumu:
ich möchte einen string aus meinem thread an mein hauptformular übergeben und dort weiterarbeiten.
Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

const
  WM_USER_THREADMESSAGE = WM_USER + $101;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure WMUserThreadMessage(var Message: TMessage); message WM_USER_THREADMESSAGE;
  public
    { Public-Deklarationen }
  end;

  TMyThread = class(TThread)
  private
    FMainFormHandle: HWND;
  protected
    procedure Execute; override;
  public
    property MainFormHandle: HWND read FMainFormHandle write FMainFormHandle;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{--------------------------------------------------------------------------------------------------}

{ TMyThread }

procedure TMyThread.Execute;
var
  S: String;
begin
  S := 'Hello World!';
  SendMessage(FMainFormHandle, WM_USER_THREADMESSAGE, Length(S), LPARAM(PChar(S)));
end;

{--------------------------------------------------------------------------------------------------}

{ TForm1 }

procedure TForm1.WMUserThreadMessage(var Message: TMessage);
var
  S: String;
begin
  SetLength(S, Message.WParam);
  StrLCopy(PChar(S), PChar(Message.LParam), Message.WParam);
  ShowMessage(S);
end;

{--------------------------------------------------------------------------------------------------}

procedure TForm1.Button1Click(Sender: TObject);
begin
  with TMyThread.Create(True) do
  begin
    FreeOnTerminate := True;
    MainFormHandle := Self.Handle;
    Resume;
  end;
end;

{--------------------------------------------------------------------------------------------------}

end.
Ciao, Sprint.

"I don't know what I am doing, but I am sure I am having fun!"
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 00:07 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz