AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Code-Bibliothek Library: Object-Pascal / Delphi-Language Delphi TObjectList-Descendant mit Templates

TObjectList-Descendant mit Templates

Ein Thema von alcaeus · begonnen am 19. Jun 2005 · letzter Beitrag vom 26. Jul 2006
Antwort Antwort
Benutzerbild von alcaeus
alcaeus

Registriert seit: 11. Aug 2003
Ort: München
6.537 Beiträge
 
#1

TObjectList-Descendant mit Templates

  Alt 19. Jun 2005, 12:57
Hallo ihr,

nachdem Robert_G hier eine Verwendung eines TObjectList-Descendants mit eigenem Typ erklaert hat, kam immer wieder der Einwand auf, dass so etwas viel zu viel Arbeit sei. Die Implementierung wuerde zu lange dauern usw. Nun, seit heute haben auch diese Gegner von TObjectList () einen Grund weniger.
Ich habe mir den Code von Robert_G geschnappt, dazu das Collection-Template von maximov, und habe eine template-Version dieses TObjectList-Descendants erstellt. Fuer alle die sich mit Templates nicht auskennen: hier gehts weiter.

Die Verwendung koennte nicht einfacher sein. Ich deklariere mir meine Item-Klasse:
Delphi-Quellcode:
type TMyItemClass = class(TObject)
private
  fFoo: String;
  fBar: Integer;
published
  property Foo: String read fFoo;
  property Bar: String read fBar;
end;
Anschliessend deklariere ich mir mein Template:
Delphi-Quellcode:
_LIST_ITEM_ = TMyItemClass;
{$DEFINE TYPED_LIST_TEMPLATE}
{$INCLUDE objlist_tmpl.pas}
TTypedList = _LIST_;
TListItemClass = _LIST_ITEM_CLASS_;

implementation

{$INCLUDE objlist_tmpl.pas}
Jeder der schon mal mit den Collection templates gearbeitet hat, wird dieses Verfahren kennen und auch schaetzen
Anschliessend kann ich ganz normal drauf zugreifen, so wie ich es mit TObject bei einer ObjectList tun kann:

Delphi-Quellcode:
fTypedList := TTypedList.Create;
fTypedList.Add(TListItem.Create);
fTypedList.Add(TListItem.Create);
fTypedList.Add(TListItem.Create);
fTypedList.Add(TListItem.Create);
with fTypedList.GetIEnumerator() do
begin
   while MoveNext() do
   begin
      Current.Foo := 'Bar';
   end;
end;
In Delphi 2005 wuerde der letzte Teil natuerlich so aussehn:
Delphi-Quellcode:
for SomeItem in fTypedList do
   SomeItem.Foo := 'Bar';
Die Klasse kann natuerlich alles, was TObjectList auch kann, nur mit dem Vorteil dass ich mir saemtliche Typecasts spare, und die Funktionalitaet nicht mehr implementieren muss. Ich muss dem Ding einfach nur noch meine Klasse geben, und fertig

Zum Kompilieren braucht ihr natuerlich die objlist_tmpl.pas sowie die Jedi-Include-Datei. Ich haenge beides mal hier an, falls ich die Jedi-Datei hier nicht anhaengen darf sagt es mir, und sie fliegt raus.

Greetz
alcaeus

[edit=Dax]Dämliches Highlighting Mfg, Dax[/edit]
Angehängte Dateien
Dateityp: txt jedi.inc.removethis_193.txt (37,2 KB, 123x aufgerufen)
Dateityp: pas objlist_tmpl_420.pas (4,7 KB, 165x aufgerufen)
Andreas B.
Die Mutter der Dummen ist immer schwanger.
Ein Portal für Informatik-Studenten: www.infler.de
  Mit Zitat antworten Zitat
Dax
(Gast)

n/a Beiträge
 
#2

Re: TObjectList-Descendant mit Templates

  Alt 26. Jul 2006, 00:59
stoxx hat in diesem Beitrag eine Version dieses Templates vorgestellt, das sich einfach und ohne die jedi.inc benutzen lässt:

Delphi-Quellcode:
{$IFDEF DEVELOP_NEVER}  // never define
unit templateTListU;

interface


uses
  Sysutils,
  Classes,
  Contnrs;

type
  _TObjectListItem = TObject;
{$ENDIF DEVELOP_NEVER}


{$IFDEF _DECLARE_SECOND_PASS}
   {$DEFINE _SECOND_PASS}
   {$UNDEF _DECLARE_SECOND_PASS}
{$ENDIF _DECLARE_SECOND_PASS}



{$IFNDEF _SECOND_PASS}
type

  _TObjectlist = class
  private
  protected
    fList: TObjectList;
    function GetItems(_Idx: integer): _TObjectListItem;
    function GetCount: integer;
  public
    constructor Create;
    destructor Destroy; override;
    function Add(_Item: _TObjectListItem): integer;
    function Remove(_Item: _TObjectListItem): integer;
    procedure Clear;
    property Items[_Idx: integer]: _TObjectListItem read GetItems; default;
    property Count: integer read GetCount;
  end;
{$DEFINE _DECLARE_SECOND_PASS}
{$ENDIF _SECOND_PASS}


{$IFDEF DEVELOP_NEVER}
implementation
{$ENDIF DEVELOP_NEVER}


{$IFDEF _SECOND_PASS}


{ _TObjectlist }

constructor _TObjectlist.Create;
begin
  inherited Create;
  fList := TObjectList.Create;
end;

destructor _TObjectlist.Destroy;
begin
  fList.Free;
  inherited;
end;

function _TObjectlist.Add(_Item: _TObjectListItem): integer;
begin
  Result := fList.Add(_Item);
end;

function _TObjectlist.Remove(_Item: _TObjectListItem): integer;
begin
  Result := fList.Remove(_Item);
end;

procedure _TObjectlist.Clear;
begin
  fList.clear;
end;

function _TObjectlist.GetItems(_Idx: integer): _TObjectListItem;
begin
  Result := fList[_Idx] as _TObjectListItem;
end;

function _TObjectlist.GetCount: integer;
begin
  Result := fList.Count;
end;
{$UNDEF _SECOND_PASS}
{$ENDIF _Second_PASS}


//{$WARNINGS off}
Ein kleines Beispiel in Form einer streng typisierten Liste von Labels hat er auch gleich mitgeliefert:
Delphi-Quellcode:
unit u_MemoList;

interface

uses
  Sysutils,
  Classes,
  Contnrs,
  StdCtrls;


type
  _TObjectListItem = TMemo;
    {$I templateTListU.pas}
  TMemoList = class(_TObjectList)
  end;


implementation
  {$I templateTListU.pas}
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:59 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz