Hi,

ich habe einen String der in etwa so aussehen kann

Zitat:

screenshot$%&$%&||

Jetzt möchte ich, dass nur zeichen des Alphab. im strig stehen bleiben dürfen.
Wie mache ich das am besten?

Sieht der String immer in der Form aus? Also fängt er mit dem relevanten Teil an oder kann der relevante Teil auch mitten in lustigen Zeichen stehen?

Mal so aus dem Blauen heraus:

zusammenfalten · markieren

Delphi-Quellcode:

function StripToLetters(const InStr: string): string;
var
  I, Cnt: Integer;
begin
  SetLength(Result, Length(InStr));
  Cnt := 0;
  for I := 1 to Length(InStr) do
  begin
    if InStr[I] in ['A'..'Z', 'a'..'z'] then
    begin
      Inc(Cnt);
      Result[Cnt] := InStr[I];
    end;
  end;
  SetLength(Result, Cnt);
end;

......

Zitat von sakura:

Mal so aus dem Blauen heraus:

zusammenfalten · markieren

Delphi-Quellcode:

function StripToLetters(const InStr: string): string;
var
  I, Cnt: Integer;
begin
  SetLength(Result, Length(InStr));
  Cnt := 0;
  for I := 1 to Length(InStr) do
  begin
    if InStr[I] in ['A'..'Z', 'a'..'z'] then
    begin
      Inc(Cnt);
      Result[Cnt] := InStr[I];
    end;
  end;
  SetLength(Result, Cnt);
end;

Warum machst du das so kompliziert? Gibts irgend n Grund mit SetLength zu arbeiten?

Ich würde das einfach so machen:

zusammenfalten · markieren

Delphi-Quellcode:

function StripToLetters(const InStr: string): string;
var
  i: Integer;
begin
  for i := 1 to Length(InStr) do
  begin
    if InStr[i] in ['A'..'Z', 'a'..'z'] then
    begin
      Result := Result + InStr[i];
    end;
  end;
end;

Welchen Vorteil hätte nun deine Methode?

mfg

Christian

Zitat von r2c2:

Welchen Vorteil hätte nun deine Methode?

Mache mal einen Performancetest. Entweder ein 2 MB String oder einfach einen relativ kurzen nehmen und den 10000 mal bearbeiten lassen. Dann wirst Du es merken

......

Zitat von sakura:

Zitat von r2c2:

Welchen Vorteil hätte nun deine Methode?

Mache mal einen Performancetest. Entweder ein 2 MB String oder einfach einen relativ kurzen nehmen und den 10000 mal bearbeiten lassen. Dann wirst Du es merken

Gut, werd ich machen. Sowas interessiert. Ich nehme mal an, das hängt damit zusammen, dass n string n dynamischer Array is und, dass + InStr[i] immer wieder implizit SetLength benutzt. Is das so?

mfg

Christian

Zitat von r2c2:

Gut, werd ich machen. Sowas interessiert. Ich nehme mal an, das hängt damit zusammen, dass n string n dynamischer Array is und, dass + InStr[i] immer wieder implizit SetLength benutzt. Is das so?

So oder sehr ähnlich, ja Durch das stete Verlängern des Strings wird immer wieder ein neuer Speicherbereich alloziert und die Daten kopiert

Bei kleinen Datenmengen ist es gehupft wie gesprungen, aber bei großen...

......

Hai ihr,

nur mal so als vergleichswert:

zusammenfalten · markieren

Delphi-Quellcode:

begin
  for ndx := 1 to 1000 do
  begin
    s := s + 'A';
  end;
end;

function StripToLetters(const InStr: string): string;
var
  I, Cnt: Integer;
begin
  SetLength(Result, Length(InStr));
  Cnt := 0;
  for I := 1 to Length(InStr) do
  begin
    if InStr[I] in ['A'..'Z', 'a'..'z'] then
    begin
      Inc(Cnt);
      Result[Cnt] := InStr[I];
    end;
  end;
  SetLength(Result, Cnt);
end;

function StripToLetters2(const InStr: string): string;
var
  i: Integer;
begin
  for i := 1 to Length(InStr) do
  begin
    if InStr[i] in ['A'..'Z', 'a'..'z'] then
    begin
      Result := Result + InStr[i];
    end;
  end;
end;

procedure TForm1.btn_Test1Click(Sender: TObject);
var
  start : Cardinal;
  ende : Cardinal;
  foo : string;
  ndx : integer;
begin
  start := GetTickCount;
  for ndx := 1 to 1000 do
    foo := StripToLetters(s);
  ende := GetTickCount;
  lbl_Label1.Caption := Format('Zeit %d',[ende-start]);

  start := GetTickCount;
  for ndx := 1 to 1000 do
    foo := StripToLetters2(s);
  ende := GetTickCount;
  lbl_Label2.Caption := Format('Zeit %d',[ende-start]);
end;

Bei Funktion1 : 1 ms
Bei Funktion2 : 2200 ms

Zitat von Sharky:

Bei Funktion1 : 1 ms
Bei Funktion2 : 2200 ms

Cool, gell Ändere mal den TestString-Generator zu

markieren

Delphi-Quellcode:

begin
  Randomize;
  for ndx := 1 to 1000 do
  begin
    s := s + Chr(Random(Ord('z')-32)+32);
  end;
end;

Damit ist der String etwas verteilter und das Ergebnis "ehrlicher".

......

Zitat von sakura:

...Damit ist der String etwas verteilter und das Ergebnis "ehrlicher". ...

Das interessiert mich jetzt aber:

Was ist es für ein Unterschied wie der String der Untersucht werden soll zusammengesetzt wurde?

BTW: In meinen Tests fehlt noch die Zeitmessung bei der Funktion von r2c2 wenn eine etxtra "foobar" Variable verwendet wird und deren Inhalt am Ende "an Result" übergeben wird.