AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Thema durchsuchen
Ansicht
Themen-Optionen

Login Simulieren

Ein Thema von Peter.K · begonnen am 22. Jan 2006 · letzter Beitrag vom 22. Jan 2006
 
marabu

Registriert seit: 6. Apr 2005
10.109 Beiträge
 
#13

Re: Login Simolieren

  Alt 22. Jan 2006, 21:25
Hallo Peter,

wer kann der kann - will meinen, das ist nicht unbedingt die Materie mit der man anfängt - aber egal.

In diesem thread hatte ich eine Lösung für dein Problem beschrieben, die du ohne größere Änderung übernehmen können solltest.

Ziehe ein Panel (Align = alTop) auf eine Form, darunter einen WebBrowser (Align = alClient). Auf das Panel ziehe einen Button.

Delphi-Quellcode:
unit WebFrm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, OleCtrls, SHDocVw, ExtCtrls;

type
  TWebForm = class(TForm)
    ActionPanel: TPanel;
    WebBrowser: TWebBrowser;
    LoginButton: TButton;
    procedure WebBrowserBeforeNavigate2(Sender: TObject;
      const pDisp: IDispatch; var URL, Flags, TargetFrameName, PostData,
      Headers: OleVariant; var Cancel: WordBool);
    procedure WebBrowserDocumentComplete(Sender: TObject;
      const pDisp: IDispatch; var URL: OleVariant);
    procedure LoginButtonClick(Sender: TObject);
  private
    DocumentLoaded: Boolean;
  end;

var
  WebForm: TWebForm;

implementation

{$R *.dfm}

procedure TWebForm.WebBrowserBeforeNavigate2(Sender: TObject;
  const pDisp: IDispatch; var URL, Flags, TargetFrameName, PostData,
  Headers: OleVariant; var Cancel: WordBool);
begin
  if pDisp = WebBrowser.DefaultInterface then
    DocumentLoaded := false;
end;

procedure TWebForm.WebBrowserDocumentComplete(Sender: TObject;
  const pDisp: IDispatch; var URL: OleVariant);
begin
  if pDisp = WebBrowser.DefaultInterface then
    DocumentLoaded := true;
end;

procedure TWebForm.LoginButtonClick(Sender: TObject);
begin
  with WebBrowser do
  begin
    OnDocumentComplete := WebBrowserDocumentComplete;
    Navigate('http://www.hotmail.com');
  end;

  repeat
    Application.ProcessMessages;
  until DocumentLoaded;

  with WebBrowser do
  begin
    OnDocumentComplete := nil;
    OleObject.document.forms.item(0).elements.item('login').value:='peter@nimmerland.de';
    OleObject.document.forms.item(0).elements.item('passwd').value:='pan';
    OleObject.document.forms.item(0).submit;
  end;
end;

end.
Viel Glück

marabu
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 17:54 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz