Hi...

Irgendwie ein absolut blödes Problem.

ich möchte in einem String keine doppelten Leerzeichen mehr haben.
Hierfür jetzt mal die Funktion StringReplace getestet.

Was bei beliebigen Zeichen funktioniert bringt mich hier fast zum Wahnsinn
s := StringReplace(s, ' ', ' ', [rfReplaceAll,rfIgnoreCase]); funktioniert nicht und
s := StringReplace(s, #32#32, #32, [rfReplaceAll,rfIgnoreCase]); auch nicht und
s := AnsiReplaceText(s, #32#32, #32); bringt auch nicht den erwünschten Erfolg.

Any hint?

Hi,

du könntest eventuell mit regulären Ausdrücken arbeiten.

Dann z.B. so einen Ausdruck wie (\s){2,} (oder ggf. direkt über die Angabe des Charakter-Codes, da \s ggf. auch andere Zeichen matched, soweit ich weiss) der nach mindestens 2 Leerzeichen matched suchen und das ganze Ergebnis mit einem Leerzeichen ersetzen.

mfG
mirage228

Zitat von Pichel:

ich möchte in einem String keine doppelten Leerzeichen mehr haben.
Hierfür jetzt mal die Funktion StringReplace getestet.

Das funktioniert, wie auch bei anderen Zeichen mit StringReplace nicht. Wenn Du aus 'aa' einfach 'a' machen willst, dann wird aus dem String baac -> bac, und aus baaaac -> baac, ist bei Leerzeichen nicht anders.

Da musst Du Dir selbst eine kleine Funktion schreiben. Z.B.:

zusammenfalten · markieren

Delphi-Quellcode:

function RemoveDblSpaces(const InStr: string): string;
var
  LastIsSpace: Boolean;
  I, Cnt: Integer;
  Res: string;
begin
  SetLength(Res, Length(InStr));
  Cnt := 0;
  LastIsSpace := False;
  for I := 1 to Length(InStr) do
  begin
    if LastIsSpace and (InStr[I] = #32) then
      Continue;
    LastIsSpace := InStr[I] = #32;
    Inc(Cnt);
    Res[Cnt] := InStr[I];
  end;
  SetLength(Res, Cnt);
  Result := Res;
end;

......

Alternative Lösung:

markieren

Delphi-Quellcode:

while Pos(' ', DeinString) > 0 do
  Delete(DeinString, Pos(' ', DeinString), 1);

oder

markieren

Delphi-Quellcode:

while Pos(' ', DeinString) > 0 do
  DeinString := StringReplace(DeinString, ' ', ' ', [rfReplaceAll]);

Kommen die doppelten Leerzeichen häufig in einem String vor, dann dürfte die zweite Variante schneller sein.

Zitat von Jasocul:

Alternative Lösung:

Die Lösung funktioniert und ist schön kurz, aber hast Du Dir Gedanken über die Geschwindigkeit gemacht

......

Zitat von sakura:

Die Lösung funktioniert und ist schön kurz, aber hast Du Dir Gedanken über die Geschwindigkeit gemacht

Ich habe zumindest mit dieser Frage gerechnet.
Käme auf einen Versuch an. Vielleicht hat Pichel ja Lust, die Varianten zu vergleichen?

Zitat von Jasocul:

Vielleicht hat Pichel ja Lust, die Varianten zu vergleichen?

Vielleicht, vielleicht aber auch nicht Hier mal der TestCode (2 Labels auf einer Form)

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
const
  x: array[0..27] of string = (
    'a', 'b', 'c', 'd', 'e', 'f', 'g', 'h', 'i', 'j', 'k', 'l', 'm',
    'n', 'o', 'p', 'q', 'r', 's', 't', 'u', 'v', 'w', 'x', 'y', 'z',
    #32, #32#32
  );
  TEST = 1000;
var
  Start, Stop, Freq: Int64;
  I: Integer;
  Source, Work, Dest: string;
begin
  Source := '';
  for I := 0 to 5000 do
    Source := Source + x[Random(Length(x))];

  QueryPerformanceFrequency(Freq);

  QueryPerformanceCounter(Start);
  for I := 1 to TEST do
  begin
    Work := Source;
    Dest := RemoveDblSpaces(Work);
  end;
  QueryPerformanceCounter(Stop);
  Label1.Caption := Format('%f ms', [(Stop - Start) / Freq * 1000]);

  QueryPerformanceCounter(Start);
  for I := 1 to TEST do
  begin
    Work := Source;
    while Pos(' ', Work) > 0 do
      Delete(Work, Pos(' ', Work), 1);
    Dest := Work;
  end;
  QueryPerformanceCounter(Stop);
  Label2.Caption := Format('%f ms', [(Stop - Start) / Freq * 1000]);
end;

Variante 1: ca. 42 ms
Variante 2: ca. 1567 ms

Vernichtendes Urteil gegen die while/Delete-Schleife

......

Zitat von Jasocul:

Käme auf einen Versuch an. Vielleicht hat Pichel ja Lust, die Varianten zu vergleichen?

Also meine "alte" Variante brauchte 2.654sek

markieren

Delphi-Quellcode:

while Pos(' ', DeinString) > 0 do
  Delete(DeinString, Pos(' ', DeinString), 1);

2.592sek
und

markieren

Delphi-Quellcode:

while Pos(' ', DeinString) > 0 do
  DeinString := StringReplace(DeinString, ' ', ' ', [rfReplaceAll]);

1.573sek

und das ganze bei einer Stringlänge von 77000 Zeichen, nicht so "pralle"

Zitat von Pichel:

Also meine "alte" Variante brauchte 2.654sek
[...]
und 1.573sek

und das ganze bei einer Stringlänge von 77000 Zeichen, nicht so "pralle"

Nimm mein, die hat auf meinem PC nur 0,78 Millisekunden benötigt

......

Ok, OK, Ich gebe auf. War schon klar, dass das schneller ist, aber so eklatant? Das, ich 'abe nischt erwartet.