Jpeg Resource

[MrKnogge]

Dann wirst du wohl einen umweg über Streams machen müssen.

[nezumi]

Hallo MrKnogge,

weiß nicht genau was Du meinst, aber wenn ich eine rc Datei schreibe mit dem Inhalt

mypics BITMAP "bild1.jpeg"

oder

mypics BITMAP "bild1"

wird mir erst gar keine ".res" Datei erstellt.

Wenn ich aber schreibe [ mypics JPEG "bild1.jpeg" ] bekomme ich zwar eine ".res" Datei, aber mein Programm funzt nicht...

Wenn ich eine ".res" Datei bekomme, muss es doch irgendwie möglich sein, die so in meinem Programm zu verwursten, dass die bilder auch angezeigt werden.. (?)

[turboPASCAL]

Ein Bleistift:

Die Datei JpegImages.rc :

Code:

;ResourceName, ResourceTyp, ResourceFile
ABC JPGIMAGE "C:\Windows\ABC.jpg"
MYPIC JPGIMAGE "MyPictures.jpg"

in der *.dpr Datei:

Delphi-Quellcode:

program Test;

// Die Resourcendatei der Bilder
{$R 'JpegImages.res' 'JpegImages.rc'}

uses
  Forms,
  JPEGTestProgramm1001 in 'JPEGTestProgramm1001.pas' {Form1};

{$R *.res}

begin
  Application.Initialize;
  Application.Title := 'Test';
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

Tastenkombi. [Umschalt + F11] fügt dann die *.rc-Datei für dich hinzu, so das man sich das getippse spaart.

Delphi-Quellcode:

unit JPEGTestProgramm1001; // ;-)

interface

uses
  Windows, SysUtils, StdCtrls, Controls, ExtCtrls, Classes, Forms, JPEG;

type
  TForm1 = class(TForm)
    Image1: TImage;
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  JPGImage: TJPEGImage;
  ResStrm: TResourceStream;
begin
  // Da die Unit JPEG kein LoadFromResource unterstütz 
  // macht man einen kleinen Umweg über den ResourceStream

  ResStrm := TResourceStream.Create(hInstance, 'MYPIC', 'JPGIMAGE');

  // Ein Jpeg(Image) erstellen
  JPGImage := TJPEGImage.Create;

  // das Bild aus dem Stream laden
  JPGImage.LoadFromStream(ResStrm);

  // ... und einem TImage zuweisen und anzeigen lassen
  Image1.Picture.Assign(JPGImage);

  // Freigeben
  JPGImage.Free;
  ResStrm.Free;
end;

end.

[nezumi]

Coool, vielen Dank turboPASCAL, werd ich gleich mal ausprobieren.

Ob ich alles kapier weiß ich noch nicht...