AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi Message wenn sich die IP einer NIC ändert?
Thema durchsuchen
Ansicht
Themen-Optionen

Message wenn sich die IP einer NIC ändert?

Ein Thema von Sharky · begonnen am 28. Apr 2006 · letzter Beitrag vom 28. Apr 2006
Antwort Antwort
Benutzerbild von SirThornberry
SirThornberry
(Moderator)

Registriert seit: 23. Sep 2003
Ort: Bockwen
12.235 Beiträge
 
Delphi 2006 Professional
 
#1

Re: Message wenn sich die IP einer NIC ändert?

  Alt 28. Apr 2006, 13:21
ich hab mal nen Object gebaut welches mit Threads arbeitet:
Delphi-Quellcode:
unit uIPChanged;

interface

uses
  windows, classes, SysUtils;

type
  TIPChangedThread = class(TThread)
  private
    fChanged: TNotifyEvent;
    fRes : DWord;
    procedure FSyncProc;
  protected
    procedure Execute; override;
  public
    constructor Create(ANotifyProc: TNotifyEvent);
  end;

  TIPChanged = class(TObject)
  private
    fEnabled : Boolean;
    fOnChanged: TNotifyEvent;
    fThread : TThread;
    procedure FNotifyProc(Sender: TObject);
  public
    constructor Create;
    destructor Destroy; override;

    property Enabled: Boolean read fEnabled write fEnabled default True;
    property OnChanged: TNotifyEvent read fOnChanged write fOnChanged;
  end;

  function NotifyAddrChange(AHandle: PCardinal; AOverlapped: POverlapped): DWORD; stdcall; External 'Iphlpapi.dll';

implementation

constructor TIPChanged.Create;
begin
  inherited Create;
  fEnabled := False;
  fThread := TIPChangedThread.Create(FNotifyProc);
end;

destructor TIPChanged.Destroy;
begin
  if Assigned(fThread) then
    TerminateThread(fThread.Handle, 0);
  inherited Destroy;
end;

procedure TIPChanged.FNotifyProc(Sender: TObject);
begin
  fThread := nil;
  if Assigned(Sender) then
  begin
    if fEnabled and Assigned(fOnChanged) then
      fOnChanged(Self);
    fThread := TIPChangedThread.Create(FNotifyProc);
  end else
    raise Exception.Create('Überwachung der IP fehlgeschlagen.');
end;

constructor TIPChangedThread.Create(ANotifyProc: TNotifyEvent);
begin
  fChanged := ANotifyProc;
  inherited Create(True);
  FreeOnTerminate := True;
  Resume;
end;

procedure TIPChangedThread.Execute;
begin
  fRes := NotifyAddrChange(nil, nil);
  Synchronize(fSyncProc);
end;

procedure TIPChangedThread.FSyncProc;
begin
  if fRes = NOERROR then
    fChanged(Self)
  else
    fChanged(nil);
end;

end.
Einfach eine Instanz von TIPchanged erzeugen und das OnChanged zuweisen.
Jens
Mit Source ist es wie mit Kunst - Hauptsache der Künstler versteht's
  Mit Zitat antworten Zitat
Antwort Antwort


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:41 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz